Merge pull request #239153 from NickCao/msgpack

msgpack-{c,cxx}: init at 6.0.0

pkgs/applications/editors/neovim/default.nix

···
-{ lib, stdenv, fetchFromGitHub, cmake, gettext, msgpack, libtermkey, libiconv
+{ lib, stdenv, fetchFromGitHub, cmake, gettext, msgpack-c, libtermkey, libiconv
 , libuv, lua, ncurses, pkg-config
 , unibilium, gperf
 , libvterm-neovim
···
       # https://github.com/luarocks/luarocks/issues/1402#issuecomment-1080616570
       # and it's definition at: pkgs/development/lua-modules/overrides.nix
       lua.pkgs.libluv
-      msgpack
+      msgpack-c
       ncurses
       neovimLuaEnv
       tree-sitter

pkgs/applications/networking/instant-messengers/jami/default.nix

···
 , libpulseaudio
 , libupnp
 , yaml-cpp
-, msgpack
+, msgpack-cxx
 , openssl
 , restinio
 , secp256k1
···
       libpulseaudio
       libupnp
       yaml-cpp
-      msgpack
+      msgpack-cxx
       opendht-jami
       openssl
       pjsip-jami

pkgs/development/libraries/msgpack-c/default.nix

···
+{ lib
+, stdenv
+, fetchFromGitHub
+, cmake
+, gtest
+, zlib
+}:
+
+stdenv.mkDerivation rec {
+  pname = "msgpack-c";
+  version = "6.0.0";
+
+  src = fetchFromGitHub {
+    owner = "msgpack";
+    repo = "msgpack-c";
+    rev = "refs/tags/c-${version}";
+    hash = "sha256-TfC37QKwqvHxsLPgsEqJYkb7mpRQekbntbBPV4v4FO8=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  cmakeFlags = [
+    "-DMSGPACK_BUILD_EXAMPLES=OFF" # examples are not installed even if built
+  ] ++ lib.optional (!doCheck) "-DMSGPACK_BUILD_TESTS=OFF";
+
+  checkInputs = [
+    gtest
+    zlib
+  ];
+
+  doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
+
+  meta = with lib; {
+    description = "MessagePack implementation for C";
+    homepage = "https://github.com/msgpack/msgpack-c";
+    changelog = "https://github.com/msgpack/msgpack-c/blob/${src.rev}/CHANGELOG.md";
+    license = licenses.boost;
+    maintainers = with maintainers; [ nickcao ];
+  };
+}

pkgs/development/libraries/msgpack-cxx/default.nix

···
+{ lib
+, stdenv
+, fetchFromGitHub
+, cmake
+, boost
+, zlib
+}:
+
+stdenv.mkDerivation rec {
+  pname = "msgpack-cxx";
+  version = "6.0.0";
+
+  src = fetchFromGitHub {
+    owner = "msgpack";
+    repo = "msgpack-c";
+    rev = "refs/tags/cpp-${version}";
+    hash = "sha256-p0eLd0fHhsgnRomubYadumMNiC2itdePJC9B55m49LI=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  buildInputs = [
+    boost
+  ];
+
+  cmakeFlags = [
+    "-DMSGPACK_BUILD_DOCS=OFF" # docs are not installed even if built
+  ] ++ lib.optional doCheck "-DMSGPACK_BUILD_TESTS=ON";
+
+  checkInputs = [
+    zlib
+  ];
+
+  doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
+
+  meta = with lib; {
+    description = "MessagePack implementation for C++";
+    homepage = "https://github.com/msgpack/msgpack-c";
+    changelog = "https://github.com/msgpack/msgpack-c/blob/${src.rev}/CHANGELOG.md";
+    license = licenses.boost;
+    maintainers = with maintainers; [ nickcao ];
+  };
+}

pkgs/top-level/all-packages.nix

···
 
   msgpack = callPackage ../development/libraries/msgpack { };
 
+  msgpack-c = callPackage ../development/libraries/msgpack-c { };
+
+  msgpack-cxx = callPackage ../development/libraries/msgpack-cxx { };
+
   msoffcrypto-tool = with python3.pkgs; toPythonApplication msoffcrypto-tool;
 
   msilbc = callPackage ../development/libraries/msilbc { };