bili-live-tool: init at 0.3.9 (#433889)

pkgs/by-name/bi/bili-live-tool/package.nix

···
+{
+  lib,
+  python3Packages,
+  fetchFromGitHub,
+  nix-update-script,
+}:
+
+let
+  version = "0.3.9";
+in
+python3Packages.buildPythonApplication {
+  pname = "bili-live-tool";
+  inherit version;
+
+  src = fetchFromGitHub {
+    owner = "chenxi-Eumenides";
+    repo = "bilibili_live_tool";
+    tag = "v${version}";
+    hash = "sha256-gNzR9cDy4sixQOSWAXeX5qOoGkaFOjBU//+iHvG0lG8=";
+  };
+
+  postPatch = ''
+    tee >> pyproject.toml <<TOML
+    [tool.setuptools]
+    packages = ["src"]
+    TOML
+  '';
+
+  pyproject = true;
+  build-system = with python3Packages; [ setuptools ];
+
+  dependencies = with python3Packages; [
+    image
+    pypinyin
+    qrcode
+    requests
+  ];
+
+  preInstall = ''
+    mkdir -p $out/bin
+    { echo '#!/bin/python'; cat main_cli.py; } > $out/bin/bili-live-tool
+    chmod +x $out/bin/bili-live-tool
+  '';
+
+  nativeCheckInputs = with python3Packages; [ unittestCheckHook ];
+  unittestFlags = [
+    "-s"
+    "unittest"
+    "-v"
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Tool to start and stop streaming and getting streaming codes for Bilibili live";
+    homepage = "https://github.com/chenxi-Eumenides/bilibili_live_tool";
+    license = lib.licenses.mpl20;
+    maintainers = with lib.maintainers; [ ulysseszhan ];
+    mainProgram = "bili-live-tool";
+  };
+}

pkgs/development/python-modules/image/default.nix

···
+{
+  lib,
+  buildPythonPackage,
+  fetchPypi,
+  setuptools,
+  pillow,
+  django,
+  six,
+}:
+
+let
+  pname = "image";
+  version = "1.5.33";
+in
+buildPythonPackage rec {
+  inherit pname version;
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-uqLgkXgnfapQ8i/W0dUex48ZwSaIkhy5q1gIdD8JcSY=";
+  };
+
+  pyproject = true;
+  build-system = [ setuptools ];
+
+  dependencies = [
+    pillow
+    django
+    six
+  ];
+
+  pythonImportsCheck = [ "image" ];
+
+  meta = {
+    description = "Django application for image and video processing";
+    homepage = "https://github.com/francescortiz/image";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ ulysseszhan ];
+  };
+}

pkgs/top-level/python-packages.nix

···
 
   ilua = callPackage ../development/python-modules/ilua { };
 
+  image = callPackage ../development/python-modules/image { };
+
   image-diff = callPackage ../development/python-modules/image-diff { };
 
   image-go-nord = callPackage ../development/python-modules/image-go-nord { };