feat: add tags and perTag options to flake-module

This works like `class` and `perClass`, but allows for setting multiple
of them, this way you can do something like:

```nix
{
easy-hosts.hosts.lemon = {
class = "nixos";
tags = ["laptop" "gaming" "work"];
};
easy-hosts.perTag =
let
tagModule = {
gaming = ./modules/gaming;
laptop = ./modules/laptop;
work = ./modules/work;
};
in
tag: {
modules = [tagModule.${tag}];
};
}
```

README.md

···
   - `modules`: A list of modules that will be included in all the hosts of the given class.
   - `specialArgs`: A list of special arguments that will be passed to all the hosts of the given class.
 
+- `easy-hosts.perTag`: This provides you with the `tag` argument such that you can specify what tags get which modules.
+  - `modules`: A list of modules that will be included in all the hosts with the given tag.
+  - `specialArgs`: A list of special arguments that will be passed to all the hosts with the given tag.
+
 - `easy-hosts.additionalClasses`: This is an attrset of strings with mappings to any of [ "nixos", "darwin", "iso" ]. The intention here to provide a nicer api for `perClass` to operate, you may find yourself including `wsl` as a class because of this.
 
 - `easy-hosts.hosts.<host>`: The options for the given host.
···
   - `arch`: The architecture of the host.
   - `modules`: A list of modules that will be included in the host.
   - `class`: the class of the host, this can be one of [ "nixos", "darwin", "iso" ] or anything defined by `easy-hosts.additionalClasses`.
+  - `tags`: tags that apply to the host, you can use this like `class`, but it allows for multiple of them to be present.
   - `specialArgs`: A list of special arguments that will be passed to the host.
   - `deployable`: this was added for people who may want to consume a deploy-rs or colmena flakeModule.
 

examples/multi/flake.nix

···
       easy-hosts = {
         autoConstruct = true;
         path = ./hosts;
+
+        # Reduce size of the image
+        hosts.test3.tags = [ "minimal" ];
+
+        perTag =
+          let
+            tags = {
+              minimal =
+                { modulesPath, ... }:
+                {
+                  imports = [ "${modulesPath}/profiles/minimal.nix" ];
+                };
+            };
+          in
+          tag: {
+            modules = [ tags.${tag} ];
+          };
       };
     };
 }

flake-module.nix

···
         description = "Per class settings";
       };
 
+      perTag = mkOption {
+        default = _: {
+          modules = [ ];
+          specialArgs = { };
+        };
+        defaultText = ''
+          tag: {
+            modules = [ ];
+            specialArgs = { };
+          };
+        '';
+
+        type = types.functionTo (
+          types.submodule {
+            options = mkBasicParams "Per tag";
+          }
+        );
+
+        example = literalExpression ''
+          let
+            tagModule = {
+              laptop = ./modules/laptop;
+              gaming = ./modules/gaming;
+            };
+          in
+          tag: {
+            modules = [ tagModule.''${tag} ];
+
+            specialArgs = { };
+          }
+        '';
+
+        description = "Per tag settings";
+      };
+
       additionalClasses = mkOption {
         default = { };
         type = types.attrsOf types.str;
···
                   default = "nixos";
                   example = "darwin";
                   description = "The class of the host";
+                };
+
+                tags = mkOption {
+                  type = types.listOf types.str;
+                  default = [ ];
+                  example = [ "laptop" ];
+                  description = "Extra tags for the host";
                 };
 
                 system = mkOption {

lib.nix

···
         let
           # memoize the class and perClass values so we don't have to recompute them
           perClass = easyHostsConfig.perClass hostConfig.class;
+          perTag = builtins.map (easyHostsConfig.perTag) hostConfig.tags;
           class = redefineClass easyHostsConfig.additionalClasses hostConfig.class;
         in
         toHostOutput {
···
               nix-darwin
               ;
 
-            modules = concatLists [
-              hostConfig.modules
-              easyHostsConfig.shared.modules
-              perClass.modules
-            ];
+            modules = concatLists (
+              [
+                hostConfig.modules
+                easyHostsConfig.shared.modules
+                perClass.modules
+              ]
+              ++ (builtins.map ({ modules, ... }: modules) perTag)
+            );
 
-            specialArgs = foldAttrsMergeRec [
-              hostConfig.specialArgs
-              easyHostsConfig.shared.specialArgs
-              perClass.specialArgs
-            ];
+            specialArgs = foldAttrsMergeRec (
+              [
+                hostConfig.specialArgs
+                easyHostsConfig.shared.specialArgs
+                perClass.specialArgs
+              ]
+              ++ (builtins.map ({ specialArgs, ... }: specialArgs) perTag)
+            );
           };
         }
       ))