hotspot: Use Qt 6, move to by-name, add kgraphviewer and qcustomplot dependencies (#412125)

pkgs/by-name/ho/hotspot/package.nix

···
+{
+  lib,
+  stdenv,
+  binutils,
+  cmake,
+  patchelfUnstable,
+  elfutils,
+  fetchFromGitHub,
+  fetchpatch,
+  kddockwidgets,
+  kdePackages,
+  libelf,
+  linuxPackages,
+  qt6,
+  rustc-demangle,
+  zstd,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "hotspot";
+  version = "1.5.1";
+
+  src = fetchFromGitHub {
+    owner = "KDAB";
+    repo = "hotspot";
+    tag = "v${version}";
+    hash = "sha256-O2wp19scyHIwIY2AzKmPmorGXDH249/OhSg+KtzOYhI=";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [
+    cmake
+    kdePackages.extra-cmake-modules
+    # stable patchelf corrupts the binary
+    patchelfUnstable
+    qt6.wrapQtAppsHook
+  ];
+
+  patches = [
+    # Fix build issue with Qt 6.9, can be removed in next release
+    (fetchpatch {
+      url = "https://github.com/KDAB/hotspot/pull/694/commits/5ef04c1dd60846b0d1746132e7e63289ee25f259.patch";
+      hash = "sha256-WYMM1/CY05fztSiRNZQ2Q16n5erjY+AE6gSQgSlb3HA=";
+    })
+  ];
+
+  cmakeFlags = [ (lib.strings.cmakeBool "QT6_BUILD" true) ];
+
+  buildInputs =
+    [
+      (elfutils.override { enableDebuginfod = true; }) # perfparser needs to find debuginfod.h
+      kddockwidgets
+      libelf
+      qt6.qtbase
+      qt6.qtsvg
+      rustc-demangle
+      zstd
+    ]
+    ++ (with kdePackages; [
+      kconfig
+      kconfigwidgets
+      kgraphviewer
+      ki18n
+      kio
+      kitemmodels
+      kitemviews
+      konsole
+      kparts
+      kwindowsystem
+      qcustomplot
+      syntax-highlighting
+      threadweaver
+    ]);
+
+  qtWrapperArgs = [
+    "--suffix PATH : ${
+      lib.makeBinPath [
+        linuxPackages.perf
+        binutils
+      ]
+    }"
+  ];
+
+  preFixup = ''
+    patchelf \
+      --add-rpath ${lib.makeLibraryPath [ rustc-demangle ]} \
+      --add-needed librustc_demangle.so \
+      $out/libexec/hotspot-perfparser
+  '';
+
+  meta = with lib; {
+    description = "GUI for Linux perf";
+    mainProgram = "hotspot";
+    longDescription = ''
+      hotspot is a GUI replacement for `perf report`.
+      It takes a perf.data file, parses and evaluates its contents and
+      then displays the result in a graphical way.
+    '';
+    homepage = "https://github.com/KDAB/hotspot";
+    changelog = "https://github.com/KDAB/hotspot/releases/tag/v${version}";
+    license = with licenses; [
+      gpl2Only
+      gpl3Only
+    ];
+    platforms = platforms.linux;
+    maintainers = with maintainers; [
+      nh2
+      tmarkus
+    ];
+  };
+}

pkgs/development/libraries/kddockwidgets/default.nix pkgs/by-name/kd/kddockwidgets/package.nix

···
   stdenv,
   fetchFromGitHub,
   cmake,
-  qtbase,
-  qtdeclarative,
-  qtquickcontrols2,
-  qtx11extras,
+  qt6,
   spdlog,
   fmt,
   nlohmann_json,
···
     fmt
     nlohmann_json
   ];
-  propagatedBuildInputs = [
+  propagatedBuildInputs = with qt6; [
     qtbase
     qtdeclarative
-    qtquickcontrols2
-    qtx11extras
   ];
+
+  cmakeFlags = [ (lib.strings.cmakeBool "KDDockWidgets_QT6" true) ];
 
   dontWrapQtApps = true;
 
···
       gpl2Only
       gpl3Only
     ];
-    maintainers = with maintainers; [ _1000teslas ];
+    maintainers = with maintainers; [
+      _1000teslas
+      tmarkus
+    ];
   };
 }

pkgs/development/tools/analysis/hotspot/default.nix

···
-{
-  lib,
-  stdenv,
-  binutils,
-  cmake,
-  extra-cmake-modules,
-  patchelfUnstable,
-  wrapQtAppsHook,
-  elfutils,
-  fetchFromGitHub,
-  kconfigwidgets,
-  kddockwidgets,
-  ki18n,
-  kio,
-  kitemmodels,
-  kitemviews,
-  konsole,
-  kparts,
-  kwindowsystem,
-  libelf,
-  linuxPackages,
-  qtbase,
-  qtsvg,
-  rustc-demangle,
-  syntax-highlighting,
-  threadweaver,
-  zstd,
-}:
-
-stdenv.mkDerivation rec {
-  pname = "hotspot";
-  version = "1.5.1";
-
-  src = fetchFromGitHub {
-    owner = "KDAB";
-    repo = "hotspot";
-    tag = "v${version}";
-    hash = "sha256-O2wp19scyHIwIY2AzKmPmorGXDH249/OhSg+KtzOYhI=";
-    fetchSubmodules = true;
-  };
-
-  nativeBuildInputs = [
-    cmake
-    extra-cmake-modules
-    # stable patchelf corrupts the binary
-    patchelfUnstable
-    wrapQtAppsHook
-  ];
-
-  buildInputs = [
-    (elfutils.override { enableDebuginfod = true; }) # perfparser needs to find debuginfod.h
-    kconfigwidgets
-    kddockwidgets
-    ki18n
-    kio
-    kitemmodels
-    kitemviews
-    konsole
-    kparts
-    kwindowsystem
-    libelf
-    qtbase
-    qtsvg
-    rustc-demangle
-    syntax-highlighting
-    threadweaver
-    zstd
-  ];
-
-  qtWrapperArgs = [
-    "--suffix PATH : ${
-      lib.makeBinPath [
-        linuxPackages.perf
-        binutils
-      ]
-    }"
-  ];
-
-  preFixup = ''
-    patchelf \
-      --add-rpath ${lib.makeLibraryPath [ rustc-demangle ]} \
-      --add-needed librustc_demangle.so \
-      $out/libexec/hotspot-perfparser
-  '';
-
-  meta = with lib; {
-    description = "GUI for Linux perf";
-    mainProgram = "hotspot";
-    longDescription = ''
-      hotspot is a GUI replacement for `perf report`.
-      It takes a perf.data file, parses and evaluates its contents and
-      then displays the result in a graphical way.
-    '';
-    homepage = "https://github.com/KDAB/hotspot";
-    changelog = "https://github.com/KDAB/hotspot/releases/tag/v${version}";
-    license = with licenses; [
-      gpl2Only
-      gpl3Only
-    ];
-    platforms = platforms.linux;
-    maintainers = with maintainers; [ nh2 ];
-  };
-}

pkgs/top-level/all-packages.nix

···
 
   hotdoc = python3Packages.callPackage ../development/tools/hotdoc { };
 
-  hotspot = libsForQt5.callPackage ../development/tools/analysis/hotspot { };
-
   hpccm = with python3Packages; toPythonApplication hpccm;
 
   hqplayer-desktop = qt6Packages.callPackage ../applications/audio/hqplayer-desktop { };
···
   rust-jemalloc-sys-unprefixed = rust-jemalloc-sys.override { unprefixed = true; };
 
   json2yaml = haskell.lib.compose.justStaticExecutables haskellPackages.json2yaml;
-
-  kddockwidgets = libsForQt5.callPackage ../development/libraries/kddockwidgets { };
 
   keybinder = callPackage ../development/libraries/keybinder {
     automake = automake111x;