Merge pull request #308993 from eclairevoyant/webcord-update-script

webcord{,-vencord}: move to pkgs/by-name, format with nixfmt, fixes for update scripts

pkgs/applications/networking/instant-messengers/webcord/default.nix

···
-{ lib
-, buildNpmPackage
-, fetchFromGitHub
-, copyDesktopItems
-, python3
-, xdg-utils
-, electron_29
-, makeDesktopItem
-, nix-update-script
-}:
-
-buildNpmPackage rec {
-  pname = "webcord";
-  version = "4.8.0";
-
-  src = fetchFromGitHub {
-    owner = "SpacingBat3";
-    repo = "WebCord";
-    rev = "v${version}";
-    hash = "sha256-x9Ejb8yxgQhlEfUUfoqbgSffNNtOoFeAyb3OISR+Jz4=";
-  };
-
-  npmDepsHash = "sha256-7H4I4vKygMgsPh+OvZZGhpkoQQu1a51yUTwEPJSBM18=";
-
-  nativeBuildInputs = [
-    copyDesktopItems
-    python3
-  ];
-
-  # npm install will error when electron tries to download its binary
-  # we don't need it anyways since we wrap the program with our nixpkgs electron
-  env.ELECTRON_SKIP_BINARY_DOWNLOAD = "1";
-
-  # remove husky commit hooks, errors and aren't needed for packaging
-  postPatch = ''
-    rm -rf .husky
-  '';
-
-  # override installPhase so we can copy the only folders that matter
-  installPhase =
-    let
-      binPath = lib.makeBinPath [ xdg-utils ];
-    in
-  ''
-    runHook preInstall
-
-    # Remove dev deps that aren't necessary for running the app
-    npm prune --omit=dev
-
-    mkdir -p $out/lib/node_modules/webcord
-    cp -r app node_modules sources package.json $out/lib/node_modules/webcord/
-
-    install -Dm644 sources/assets/icons/app.png $out/share/icons/hicolor/256x256/apps/webcord.png
-
-    # Add xdg-utils to path via suffix, per PR #181171
-    makeWrapper '${lib.getExe electron_29}' $out/bin/webcord \
-      --suffix PATH : "${binPath}" \
-      --add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations}}" \
-      --add-flags $out/lib/node_modules/webcord/
-
-    runHook postInstall
-  '';
-
-  desktopItems = [
-    (makeDesktopItem {
-      name = "webcord";
-      exec = "webcord";
-      icon = "webcord";
-      desktopName = "WebCord";
-      comment = meta.description;
-      categories = [ "Network" "InstantMessaging" ];
-    })
-  ];
-
-  passthru.updateScript = nix-update-script { };
-
-  meta = {
-    description = "A Discord and SpaceBar electron-based client implemented without Discord API";
-    homepage = "https://github.com/SpacingBat3/WebCord";
-    downloadPage = "https://github.com/SpacingBat3/WebCord/releases";
-    changelog = "https://github.com/SpacingBat3/WebCord/releases/tag/v${version}";
-    license = lib.licenses.mit;
-    mainProgram = "webcord";
-    maintainers = with lib.maintainers; [ eclairevoyant huantian ];
-    platforms = lib.platforms.linux;
-  };
-}

pkgs/applications/networking/instant-messengers/webcord/webcord-vencord/default.nix

···
-{ webcord
-, substituteAll
-, lib
-, vencord-web-extension
-}:
-
-webcord.overrideAttrs (old: {
-  pname = "webcord-vencord";
-
-  patches = (old.patches or [ ]) ++ [
-    (substituteAll {
-      src = ./add-extension.patch;
-      vencord = vencord-web-extension;
-    })
-  ];
-
-  meta = with lib; old.meta // {
-    description = "Webcord with Vencord web extension";
-    maintainers = with maintainers; [ FlafyDev NotAShelf ];
-  };
-})

pkgs/by-name/we/webcord-vencord/package.nix

···
+{
+  webcord,
+  substituteAll,
+  lib,
+  vencord-web-extension,
+}:
+
+# nixpkgs-update: no auto update
+webcord.overrideAttrs (old: {
+  pname = "webcord-vencord";
+
+  patches = (old.patches or [ ]) ++ [
+    (substituteAll {
+      src = ./add-extension.patch;
+      vencord = vencord-web-extension;
+    })
+  ];
+
+  meta = {
+    inherit (old.meta) license mainProgram platforms;
+
+    description = "Webcord with Vencord web extension";
+    maintainers = with lib.maintainers; [
+      FlafyDev
+      NotAShelf
+    ];
+  };
+})

pkgs/by-name/we/webcord/package.nix

···
+{
+  lib,
+  buildNpmPackage,
+  fetchFromGitHub,
+  copyDesktopItems,
+  python3,
+  xdg-utils,
+  electron,
+  makeDesktopItem,
+}:
+
+buildNpmPackage rec {
+  pname = "webcord";
+  version = "4.8.0";
+
+  src = fetchFromGitHub {
+    owner = "SpacingBat3";
+    repo = "WebCord";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-x9Ejb8yxgQhlEfUUfoqbgSffNNtOoFeAyb3OISR+Jz4=";
+  };
+
+  npmDepsHash = "sha256-7H4I4vKygMgsPh+OvZZGhpkoQQu1a51yUTwEPJSBM18=";
+
+  nativeBuildInputs = [
+    copyDesktopItems
+    python3
+  ];
+
+  # npm install will error when electron tries to download its binary
+  # we don't need it anyways since we wrap the program with our nixpkgs electron
+  env.ELECTRON_SKIP_BINARY_DOWNLOAD = "1";
+
+  # remove husky commit hooks, errors and aren't needed for packaging
+  postPatch = ''
+    rm -rf .husky
+  '';
+
+  # override installPhase so we can copy the only folders that matter
+  installPhase =
+    let
+      binPath = lib.makeBinPath [ xdg-utils ];
+    in
+    ''
+      runHook preInstall
+
+      # Remove dev deps that aren't necessary for running the app
+      npm prune --omit=dev
+
+      mkdir -p $out/lib/node_modules/webcord
+      cp -r app node_modules sources package.json $out/lib/node_modules/webcord/
+
+      install -Dm644 sources/assets/icons/app.png $out/share/icons/hicolor/256x256/apps/webcord.png
+
+      # Add xdg-utils to path via suffix, per PR #181171
+      makeWrapper '${lib.getExe electron}' $out/bin/webcord \
+        --suffix PATH : "${binPath}" \
+        --add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations}}" \
+        --add-flags $out/lib/node_modules/webcord/
+
+      runHook postInstall
+    '';
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "webcord";
+      exec = "webcord";
+      icon = "webcord";
+      desktopName = "WebCord";
+      comment = meta.description;
+      categories = [
+        "Network"
+        "InstantMessaging"
+      ];
+    })
+  ];
+
+  passthru.updateScript = ./update.sh;
+
+  meta = {
+    description = "A Discord and SpaceBar electron-based client implemented without Discord API";
+    homepage = "https://github.com/SpacingBat3/WebCord";
+    downloadPage = "https://github.com/SpacingBat3/WebCord/releases";
+    changelog = "https://github.com/SpacingBat3/WebCord/releases/tag/v${version}";
+    license = lib.licenses.mit;
+    mainProgram = "webcord";
+    maintainers = with lib.maintainers; [
+      eclairevoyant
+      huantian
+    ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/by-name/we/webcord/update.sh

···
+#! /usr/bin/env nix-shell
+#! nix-shell -i bash -p curl jq nix-update
+
+set -ex
+
+curl_github() {
+    curl -L ${GITHUB_TOKEN:+" -u \":$GITHUB_TOKEN\""} "$@"
+}
+
+latestTag=$(curl_github https://api.github.com/repos/SpacingBat3/Webcord/releases/latest | jq -r ".tag_name")
+latestVersion="$(expr "$latestTag" : 'v\(.*\)')"
+
+nix-update --version "$latestVersion" webcord
+electronVersion=$(curl_github "https://raw.githubusercontent.com/SpacingBat3/WebCord/v$latestVersion/package.json" | jq -r ".devDependencies.electron" | sed -r 's|^\^([0-9]+).*|\1|')
+sed -r "/webcord = / s|(electron_)[0-9]+|\1$electronVersion|" -i pkgs/top-level/all-packages.nix

pkgs/top-level/all-packages.nix

···
 
   webcamoid = libsForQt5.callPackage ../applications/video/webcamoid { };
 
-  webcord = callPackage ../applications/networking/instant-messengers/webcord { };
-
-  webcord-vencord = callPackage ../applications/networking/instant-messengers/webcord/webcord-vencord { };
+  webcord = callPackage ../by-name/we/webcord/package.nix { electron = electron_29; };
 
   webex = callPackage ../applications/networking/instant-messengers/webex { };