planner: init at 0.14.91

Co-authored-by: Anderson Torres <[e-mail]>

pkgs/applications/office/planner/default.nix

···
+{ lib
+, stdenv
+, fetchFromGitLab
+, desktop-file-utils
+, gsettings-desktop-schemas
+, glib
+, gtk3
+, libgda
+, libxml2
+, libxslt
+, makeWrapper
+, meson
+, ninja
+, pkg-config
+, shared-mime-info
+}:
+
+stdenv.mkDerivation rec {
+  pname = "planner";
+  version = "0.14.91";
+
+  src = fetchFromGitLab {
+    domain = "gitlab.gnome.org";
+    owner = "World";
+    repo = "planner";
+    rev = version;
+    hash = "sha256-LxctZv/CKolJ1I4Hql20E+/+p+ZoJLR1eZe34HPMqvY=";
+  };
+
+  postPatch = ''
+    patchShebangs \
+      meson_post_install.sh \
+      tools/strip_trailing_white_space.sh \
+      tests/python/task-test.py
+  '';
+
+  nativeBuildInputs = [
+    desktop-file-utils
+    makeWrapper
+    meson
+    ninja
+    pkg-config
+    shared-mime-info
+  ];
+
+  buildInputs = [
+    libgda
+    libxml2
+    libxslt
+    glib
+    gsettings-desktop-schemas
+    gtk3
+  ];
+
+  postInstall = ''
+    wrapProgram $out/bin/planner \
+      --prefix XDG_DATA_DIRS : "$GSETTINGS_SCHEMAS_PATH:$out/share/gsettings-schemas/planner-${version}"
+  '';
+
+  meta = {
+    description = "Project management tool for the GNOME desktop";
+    homepage = "https://wiki.gnome.org/Apps/Planner";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [ amiloradovsky ];
+    platforms = lib.platforms.unix;
+  };
+}

pkgs/top-level/aliases.nix

···
   pixie = throw "pixie has been removed: abandoned by upstream"; # Added 2022-04-21
   pkgconfig = pkg-config; # Added 2018-02-02, moved to aliases.nix 2021-01-18
   pkgconfigUpstream = throw "'pkgconfigUpstream' has been renamed to/replaced by 'pkg-configUpstream'"; # Converted to throw 2022-02-22
-  planner = throw "planner has been removed from nixpkgs, as it is no longer developed and still uses python2/PyGTK"; # Added 2021-02-02
   pleroma-otp = pleroma; # Added 2021-07-10
   plexpy = throw "'plexpy' has been renamed to/replaced by 'tautulli'"; # Converted to throw 2022-02-22
   pltScheme = racket; # just to be sure

pkgs/top-level/all-packages.nix

···
 
   pixinsight = libsForQt5.callPackage ../applications/graphics/pixinsight { };
 
+  planner = callPackage ../applications/office/planner { };
+
   please-cli = callPackage ../applications/misc/please-cli { };
 
   protonup-qt = python3Packages.callPackage ../applications/misc/protonup-qt { };