antora: verify core functionality with a minimal working example

Link: https://github.com/NixOS/nixpkgs/pull/332341

pkgs/by-name/an/antora/package.nix

···
 {
   buildNpmPackage,
+  callPackage,
   fetchFromGitLab,
   lib,
   nix-update-script,
···
     ln -s $out/lib/node_modules/antora-build/packages/cli/bin/antora $out/bin/antora
   '';
 
-  passthru.updateScript = nix-update-script { };
+  passthru = {
+    tests.run = callPackage ./test { };
+    updateScript = nix-update-script { };
+  };
 
   meta = with lib; {
     description = "Modular documentation site generator. Designed for users of Asciidoctor";

pkgs/by-name/an/antora/test/default.nix

···
+{
+  antora,
+  antora-ui-default,
+  gitMinimal,
+  lib,
+  stdenvNoCC,
+}:
+stdenvNoCC.mkDerivation {
+  name = "${antora.pname}-test";
+  src = ./minimal_working_example;
+
+  postPatch =
+    let
+      date = lib.escapeShellArg "1/1/1970 00:00:00 +0000";
+    in
+    ''
+      # > In order to use a local content repository with Antora, even when using
+      # > the worktree (HEAD), the repository must have at least one commit.
+      # >
+      # > -- https://docs.antora.org/antora/3.1/playbook/content-source-url
+      git init &&
+        GIT_AUTHOR_DATE=${date} \
+        GIT_AUTHOR_EMAIL= \
+        GIT_AUTHOR_NAME=Nixpkgs \
+        GIT_COMMITTER_DATE=${date} \
+        GIT_COMMITTER_EMAIL= \
+        GIT_COMMITTER_NAME=Nixpkgs \
+        git commit --allow-empty --allow-empty-message --message ""
+    '';
+
+  buildPhase =
+    let
+      playbook = builtins.toFile "antora-playbook.json" (
+        builtins.toJSON {
+          content.sources = [ { url = "~+"; } ];
+          runtime.log.failure_level = "warn";
+        }
+      );
+    in
+    ''
+      # The --to-dir and --ui-bundle-url options are not included in the
+      # playbook due to Antora and Nix limitations.
+      antora ${
+        lib.cli.toGNUCommandLineShell { } {
+          cache-dir = "$(mktemp --directory)";
+          to-dir = placeholder "out";
+          ui-bundle-url = "${antora-ui-default}/ui-bundle.zip";
+        }
+      } "${playbook}"
+    '';
+
+  nativeBuildInputs = [
+    antora
+    gitMinimal
+  ];
+
+  meta = {
+    description = "Reproducible Antora test framework";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.naho ];
+    platforms = lib.platforms.all;
+  };
+}

pkgs/by-name/an/antora/test/minimal_working_example/antora.yml

···
+---
+name: Antora
+
+nav:
+  - modules/ROOT/nav.adoc
+
+version: ~

pkgs/by-name/an/antora/test/minimal_working_example/modules/ROOT/nav.adoc

···
+* xref:index.adoc[]

pkgs/by-name/an/antora/test/minimal_working_example/modules/ROOT/pages/index.adoc

···
+= Antora
+
+== Minimal Working Example