mpc-qt: migrate to by-name

pkgs/applications/video/mpc-qt/default.nix

···
-{
-  lib,
-  stdenv,
-  fetchFromGitHub,
-  pkg-config,
-  qmake,
-  qttools,
-  qtbase,
-  mpv,
-  wrapQtAppsHook,
-  gitUpdater,
-}:
-
-stdenv.mkDerivation rec {
-  pname = "mpc-qt";
-  version = "24.12.1-flatpak";
-
-  src = fetchFromGitHub {
-    owner = "mpc-qt";
-    repo = "mpc-qt";
-    rev = "v${version}";
-    hash = "sha256-gn94kVs3Lbd+ggj4jTacHpmnVO2lH/QDhFk+hJC1N/c=";
-  };
-
-  nativeBuildInputs = [
-    pkg-config
-    qmake
-    qttools
-    wrapQtAppsHook
-  ];
-
-  buildInputs = [
-    mpv
-  ];
-
-  postPatch = ''
-    substituteInPlace lconvert.pri --replace "qtPrepareTool(LCONVERT, lconvert)" "qtPrepareTool(LCONVERT, lconvert, , , ${qttools}/bin)"
-  '';
-
-  postConfigure = ''
-    substituteInPlace Makefile --replace ${qtbase}/bin/lrelease ${qttools.dev}/bin/lrelease
-  '';
-
-  qmakeFlags = [
-    "MPCQT_VERSION=${version}"
-  ];
-
-  passthru.updateScript = gitUpdater { rev-prefix = "v"; };
-
-  meta = with lib; {
-    description = "Media Player Classic Qute Theater";
-    homepage = "https://mpc-qt.github.io";
-    license = licenses.gpl2;
-    platforms = platforms.unix;
-    broken = stdenv.hostPlatform.isDarwin;
-    maintainers = with maintainers; [ romildo ];
-    mainProgram = "mpc-qt";
-  };
-}

pkgs/by-name/mp/mpc-qt/package.nix

···
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+  qt6Packages,
+  mpv,
+  gitUpdater,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "mpc-qt";
+  version = "24.12.1-flatpak";
+
+  src = fetchFromGitHub {
+    owner = "mpc-qt";
+    repo = "mpc-qt";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-gn94kVs3Lbd+ggj4jTacHpmnVO2lH/QDhFk+hJC1N/c=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+    qt6Packages.qmake
+    qt6Packages.qttools
+    qt6Packages.wrapQtAppsHook
+  ];
+
+  buildInputs = [
+    mpv
+  ];
+
+  postPatch = ''
+    substituteInPlace lconvert.pri --replace "qtPrepareTool(LCONVERT, lconvert)" "qtPrepareTool(LCONVERT, lconvert, , , ${qt6Packages.qttools}/bin)"
+  '';
+
+  postConfigure = ''
+    substituteInPlace Makefile --replace ${qt6Packages.qtbase}/bin/lrelease ${qt6Packages.qttools.dev}/bin/lrelease
+  '';
+
+  qmakeFlags = [
+    "MPCQT_VERSION=${finalAttrs.version}"
+  ];
+
+  passthru.updateScript = gitUpdater { rev-prefix = "v"; };
+
+  meta = {
+    description = "Media Player Classic Qute Theater";
+    homepage = "https://mpc-qt.github.io";
+    license = lib.licenses.gpl2;
+    platforms = lib.platforms.unix;
+    broken = stdenv.hostPlatform.isDarwin;
+    maintainers = with lib.maintainers; [ romildo ];
+    mainProgram = "mpc-qt";
+  };
+})

pkgs/top-level/all-packages.nix

···
   # a somewhat more maintained fork of ympd
   memento = qt6Packages.callPackage ../applications/video/memento { };
 
-  mpc-qt = qt6Packages.callPackage ../applications/video/mpc-qt { };
-
   mplayer = callPackage ../applications/video/mplayer (
     {
       libdvdnav = libdvdnav_4_2_1;