heroic-unwrapped: Add missing dependencies

- comet-gog.dummy-service
- epic-integration

pkgs/by-name/he/heroic-unwrapped/epic-integration.nix

···
+{
+  lib,
+  stdenv,
+  gitUpdater,
+  fetchFromGitHub,
+  cmake,
+  pkgsCross,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "heroic-epic-integration";
+  version = "0.3";
+
+  src = fetchFromGitHub {
+    owner = "Etaash-mathamsetty";
+    repo = "heroic-epic-integration";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-Zn0MsaQd8Ro6eu8IQkMcLNGLVTUukwajkn8PRLfB+Yw=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkgsCross.mingwW64.buildPackages.gcc
+  ];
+
+  cmakeFlags = [ (lib.cmakeFeature "CMAKE_TOOLCHAIN_FILE" "../windows.cmake") ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir $out
+    cp heroic-epic-integration.exe $out/EpicGamesLauncher.exe
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Wrapper process for games launched through Heroic Games Launcher";
+    longDescription = ''
+      This is a Windows executable that pretends to be EpicGamesLauncher.exe for
+      games that expect it to be their parent process.
+    '';
+    homepage = "https://github.com/Etaash-mathamsetty/heroic-epic-integration";
+    changelog = "https://github.com/Etaash-mathamsetty/heroic-epic-integration/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ aidalgol ];
+  };
+
+  passthru.updateScript = gitUpdater { };
+})

pkgs/by-name/he/heroic-unwrapped/package.nix

···
 {
   lib,
+  callPackage,
   stdenv,
   fetchFromGitHub,
   # Pinned, because our FODs are not guaranteed to be stable between major versions.
···
 }:
 
 let
+  epic-integration = callPackage ./epic-integration.nix { };
   electron = electron_36;
 in
 stdenv.mkDerivation (finalAttrs: {
···
 
     cp -r public "$out/opt/heroic/resources/app.asar.unpacked/build"
     rm -rf "$out/opt/heroic/resources/app.asar.unpacked/build/bin"
-    mkdir -p "$out/opt/heroic/resources/app.asar.unpacked/build/bin/x64/linux"
+    mkdir -p \
+      "$out/opt/heroic/resources/app.asar.unpacked/build/bin/x64/linux" \
+      "$out/opt/heroic/resources/app.asar.unpacked/build/bin/x64/win32"
     ln -s \
       "${lib.getExe gogdl}" \
       "${lib.getExe legendary-heroic}" \
···
       "${lib.getExe comet-gog}" \
       "${lib.getExe vulkan-helper}" \
       "$out/opt/heroic/resources/app.asar.unpacked/build/bin/x64/linux"
+    # Don't symlink these so we don't confuse Windows applications under Wine/Proton.
+    cp \
+      "${comet-gog.dummy-service}/GalaxyCommunication.exe" \
+      "${epic-integration}/EpicGamesLauncher.exe" \
+      "$out/opt/heroic/resources/app.asar.unpacked/build/bin/x64/win32"
 
     makeWrapper "${electron}/bin/electron" "$out/bin/heroic" \
       --inherit-argv0 \
···
 
     runHook postInstall
   '';
+
+  passthru.epic-integration = epic-integration;
 
   meta = with lib; {
     description = "Native GOG, Epic, and Amazon Games Launcher for Linux, Windows and Mac";