Merge pull request #19831 from AbigailBuccaneer/gmad

gmad: init at HEAD

lib/maintainers.nix

···
   aaronschif = "Aaron Schif <[e-mail]>";
   abaldeau = "Andreas Baldeau <[e-mail]>";
   abbradar = "Nikolay Amiantov <[e-mail]>";
+  abigailbuccaneer = "Abigail Bunyan <[e-mail]>";
   aboseley = "Adam Boseley <[e-mail]>";
   abuibrahim = "Ruslan Babayev <[e-mail]>";
   acowley = "Anthony Cowley <[e-mail]>";

pkgs/development/libraries/bootil/default.nix

···
+{ stdenv, fetchFromGitHub, fetchpatch, premake4 }:
+
+stdenv.mkDerivation rec {
+  name = "bootil-unstable-2015-12-17";
+
+  meta = {
+    description = "Garry Newman's personal utility library";
+    homepage = https://github.com/garrynewman/bootil;
+    # License unsure - see https://github.com/garrynewman/bootil/issues/21
+    license = stdenv.lib.licenses.free;
+    maintainers = [ stdenv.lib.maintainers.abigailbuccaneer ];
+    platforms = stdenv.lib.platforms.all;
+  };
+
+  src = fetchFromGitHub {
+    owner = "garrynewman";
+    repo = "bootil";
+    rev = "1d3e321fc2be359e2350205b8c7f1cad2164ee0b";
+    sha256 = "03wq526r80l2px797hd0n5m224a6jibwipcbsvps6l9h740xabzg";
+  };
+
+  patches = [ (fetchpatch {
+    url = https://github.com/garrynewman/bootil/pull/22.patch;
+    name = "github-pull-request-22.patch";
+    sha256 = "1qf8wkv00pb9w1aa0dl89c8gm4rmzkxfl7hidj4gz0wpy7a24qa2";
+  })];
+
+  platform =
+    if stdenv.isLinux then "linux"
+    else if stdenv.isDarwin then "macosx"
+    else abort "unrecognized platform";
+
+  buildInputs = [ premake4 ];
+
+  configurePhase = "premake4 --file=projects/premake4.lua gmake";
+  makeFlags = "-C projects/${platform}/gmake";
+
+  installPhase = ''
+    mkdir -p $out/lib
+    cp lib/${platform}/gmake/libbootil_static.a $out/lib/
+    cp -r include $out/
+  '';
+}

pkgs/games/gmad/default.nix

···
+{ stdenv, fetchFromGitHub, premake4, bootil }:
+
+stdenv.mkDerivation rec {
+  name = "gmad-unstable-2015-04-16";
+
+  meta = {
+    description = "Garry's Mod Addon Creator and Extractor";
+    homepage = https://github.com/garrynewman/gmad;
+    license = stdenv.lib.licenses.unfree;
+    maintainers = [ stdenv.lib.maintainers.abigailbuccaneer ];
+    platforms = stdenv.lib.platforms.all;
+  };
+
+  src = fetchFromGitHub {
+    owner = "garrynewman";
+    repo = "gmad";
+    rev = "377f3458bf1ecb8a1a2217c2194773e3c2a2dea0";
+    sha256="0myi9njr100gxhxk1vrzr2sbij5kxl959sq0riiqgg01div338g0";
+  };
+
+  buildInputs = [ premake4 bootil ];
+
+  targetName =
+    if stdenv.isLinux then "gmad_linux"
+    else if stdenv.isDarwin then "gmad_osx"
+    else "gmad";
+
+  configurePhase = "premake4 --bootil_lib=${bootil}/lib --bootil_inc=${bootil}/include gmake";
+
+  installPhase = ''
+    mkdir -p $out/bin
+    cp ${targetName} $out/bin/gmad
+  '';
+}

pkgs/top-level/all-packages.nix

···
 
   gltron = callPackage ../games/gltron { };
 
+  gmad = callPackage ../games/gmad { };
+
   gnubg = callPackage ../games/gnubg { };
 
   gnuchess = callPackage ../games/gnuchess { };
···
   beep = callPackage ../misc/beep { };
 
   blackbird = callPackage ../misc/themes/blackbird { };
+
+  bootil = callPackage ../development/libraries/bootil { };
 
   brgenml1lpr = callPackage_i686 ../misc/cups/drivers/brgenml1lpr {};