Merge pull request #302057 from msanft/pwndbg/2024.02.14

pwndbg: 2022.12.19 -> 2024.02.14

pkgs/by-name/pw/pwndbg/package.nix

···
+{ lib
+, stdenv
+, python3
+, fetchFromGitHub
+, makeWrapper
+, gdb
+}:
+
+let
+  pwndbg-py = python3.pkgs.pwndbg;
+
+  pythonPath = python3.pkgs.makePythonPath [ pwndbg-py ];
+
+  binPath = lib.makeBinPath ([
+    python3.pkgs.pwntools # ref: https://github.com/pwndbg/pwndbg/blob/2022.12.19/pwndbg/wrappers/checksec.py#L8
+  ] ++ lib.optionals stdenv.isLinux [
+    python3.pkgs.ropper # ref: https://github.com/pwndbg/pwndbg/blob/2022.12.19/pwndbg/commands/ropper.py#L30
+    python3.pkgs.ropgadget # ref: https://github.com/pwndbg/pwndbg/blob/2022.12.19/pwndbg/commands/rop.py#L32
+  ]);
+in
+stdenv.mkDerivation rec {
+  pname = "pwndbg";
+  version = lib.getVersion pwndbg-py;
+  format = "other";
+
+  inherit (pwndbg-py) src;
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/share/pwndbg
+    cp gdbinit.py $out/share/pwndbg
+    chmod +x $out/share/pwndbg/gdbinit.py
+
+    # Don't require an in-package venv
+    touch $out/share/pwndbg/.skip-venv
+
+    makeWrapper ${gdb}/bin/gdb $out/bin/pwndbg \
+      --add-flags "-q -x $out/share/pwndbg/gdbinit.py" \
+      --prefix PATH : ${binPath} \
+      --set PYTHONPATH ${pythonPath} \
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Exploit Development and Reverse Engineering with GDB Made Easy";
+    mainProgram = "pwndbg";
+    homepage = "https://github.com/pwndbg/pwndbg";
+    license = licenses.mit;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ mic92 patryk4815 msanft ];
+    # not supported on aarch64-darwin see: https://inbox.sourceware.org/gdb/3185c3b8-8a91-4beb-a5d5-9db6afb93713@Spark/
+    broken = stdenv.isDarwin && stdenv.isAarch64;
+  };
+}

pkgs/development/python-modules/gdb-pt-dump/default.nix

···
+{ lib
+, buildPythonPackage
+, fetchFromGitHub
+, poetry-core
+}:
+
+buildPythonPackage rec {
+  pname = "gdb-pt-dump";
+  version = "0-unstable-2024-04-01";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "martinradev";
+    repo = "gdb-pt-dump";
+    rev = "50227bda0b6332e94027f811a15879588de6d5cb";
+    hash = "sha256-yiP3KY1oDwhy9DmNQEht/ryys9vpgkFS+EJcSA6R+cI=";
+  };
+
+  build-system = [ poetry-core ];
+
+  pythonImportsCheck = [ "pt" ];
+
+  meta = with lib; {
+    description = "GDB script to enhance debugging of a QEMU-based virtual machine";
+    homepage = "https://github.com/martinradev/gdb-pt-dump";
+    license = licenses.mit;
+    maintainers = with maintainers; [ msanft ];
+  };
+}

pkgs/development/python-modules/pwndbg/default.nix

···
+{ lib
+, stdenv
+, buildPythonPackage
+, fetchFromGitHub
+, capstone
+, future
+, ipython
+, psutil
+, pwntools
+, pycparser
+, pyelftools
+, pygments
+, requests
+, rpyc
+, sortedcontainers
+, tabulate
+, typing-extensions
+, unicorn
+, gdb-pt-dump
+, poetry-core
+, pythonRelaxDepsHook
+}:
+let
+  # The newest gdb-pt-dump is incompatible with pwndbg 2024.02.14.
+  # See https://github.com/martinradev/gdb-pt-dump/issues/29
+  gdb-pt-dump' = gdb-pt-dump.overrideAttrs (oldAttrs: {
+    version = "0-unstable-2023-11-11";
+
+    src = fetchFromGitHub {
+      inherit (oldAttrs.src) owner repo;
+      rev = "89ea252f6efc5d75eacca16fc17ff8966a389690";
+      hash = "sha256-i+SAcZ/kgfKstJnkyCVMh/lWtrJJOHTYoJH4tVfYHrE=";
+    };
+
+    # This revision relies on the package being imported from within GDB, which
+    # won't work with pythonImportsCheck.
+    pythonImportsCheck = [ ];
+  });
+in
+buildPythonPackage rec {
+  pname = "pwndbg";
+  version = "2024.02.14";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "pwndbg";
+    repo = "pwndbg";
+    rev = version;
+    hash = "sha256-/pDo2J5EtpWWCurD7H34AlTlQi7WziIRRxHxGm3K2yk=";
+  };
+
+  nativeBuildInputs = [ poetry-core pythonRelaxDepsHook ];
+  pythonRelaxDeps = true;
+
+  propagatedBuildInputs = [
+    capstone
+    future
+    ipython
+    psutil
+    pwntools
+    pycparser
+    pyelftools
+    pygments
+    requests
+    rpyc
+    sortedcontainers
+    tabulate
+    typing-extensions
+    unicorn
+    gdb-pt-dump'
+  ];
+
+  meta = {
+    description = "Exploit Development and Reverse Engineering with GDB Made Easy";
+    homepage = "https://pwndbg.re";
+    changelog = "https://github.com/pwndbg/pwndbg/releases/tag/${version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ msanft ];
+  };
+}

pkgs/development/tools/misc/pwndbg/default.nix

···
-{ lib
-, stdenv
-, python3
-, fetchFromGitHub
-, makeWrapper
-, gdb
-}:
-
-let
-  pythonPath = with python3.pkgs; makePythonPath [
-    capstone
-    future
-    psutil
-    pwntools
-    pycparser
-    pyelftools
-    pygments
-    unicorn
-    rpyc
-  ];
-  binPath = lib.makeBinPath ([
-    python3.pkgs.pwntools   # ref: https://github.com/pwndbg/pwndbg/blob/2022.12.19/pwndbg/wrappers/checksec.py#L8
-  ] ++ lib.optionals stdenv.isLinux [
-    python3.pkgs.ropper     # ref: https://github.com/pwndbg/pwndbg/blob/2022.12.19/pwndbg/commands/ropper.py#L30
-    python3.pkgs.ropgadget  # ref: https://github.com/pwndbg/pwndbg/blob/2022.12.19/pwndbg/commands/rop.py#L32
-  ]);
-
-in stdenv.mkDerivation rec {
-  pname = "pwndbg";
-  version = "2022.12.19";
-  format = "other";
-
-  src = fetchFromGitHub {
-    owner = "pwndbg";
-    repo = "pwndbg";
-    rev = version;
-    sha256 = "sha256-pyY2bMasd6GaJZZjLF48SvkKUBw3XfVa0g3Q0LiEi4k=";
-    fetchSubmodules = true;
-  };
-
-  nativeBuildInputs = [ makeWrapper ];
-
-  installPhase = ''
-    mkdir -p $out/share/pwndbg
-    cp -r *.py pwndbg gdb-pt-dump $out/share/pwndbg
-    chmod +x $out/share/pwndbg/gdbinit.py
-    makeWrapper ${gdb}/bin/gdb $out/bin/pwndbg \
-      --add-flags "-q -x $out/share/pwndbg/gdbinit.py" \
-      --prefix PATH : ${binPath} \
-      --set NIX_PYTHONPATH ${pythonPath}
-  '';
-
-  meta = with lib; {
-    description = "Exploit Development and Reverse Engineering with GDB Made Easy";
-    mainProgram = "pwndbg";
-    homepage = "https://github.com/pwndbg/pwndbg";
-    license = licenses.mit;
-    platforms = platforms.all;
-    maintainers = with maintainers; [ mic92 patryk4815 ];
-    # not supported on aarch64-darwin see: https://inbox.sourceware.org/gdb/3185c3b8-8a91-4beb-a5d5-9db6afb93713@Spark/
-    broken = stdenv.isDarwin && stdenv.isAarch64;
-  };
-}

pkgs/top-level/all-packages.nix

···
 
   pwnat = callPackage ../tools/networking/pwnat { };
 
-  pwndbg = callPackage ../development/tools/misc/pwndbg { };
-
   pwninit = callPackage ../development/tools/misc/pwninit {
     inherit (darwin.apple_sdk.frameworks) Security;
   };

pkgs/top-level/python-packages.nix

···
 
   gdata = callPackage ../development/python-modules/gdata { };
 
+  gdb-pt-dump = callPackage ../development/python-modules/gdb-pt-dump { };
+
   gdcm = toPythonModule (pkgs.gdcm.override {
     inherit (self) python;
     enablePython = true;
···
   pweave = callPackage ../development/python-modules/pweave { };
 
   pwlf = callPackage ../development/python-modules/pwlf { };
+
+  pwndbg = callPackage ../development/python-modules/pwndbg { };
 
   pwntools = callPackage ../development/python-modules/pwntools {
     debugger = pkgs.gdb;