cool-old-term: rename to cool-retro-term (close #6071)

The project has changed its name to cool-retro-term. The project also added a
dependency that is included as a submodule. I added this dependency as a
separate expression.

pkgs/applications/misc/cool-old-term/default.nix

···
-{ stdenv, fetchFromGitHub, qt5 }:
-
-stdenv.mkDerivation rec {
-  version = "0.9";
-  name = "cool-old-term-${version}";
-
-  src = fetchFromGitHub {
-    owner = "Swordifish90";
-    repo = "cool-old-term";
-    rev = "2494bc05228290545df8c59c05624a4b903e9068";
-    sha256 = "8462f3eded7b2219acc143258544b0dfac32d81e10cac61ff14276d426704c93";
-  };
-
-  buildInputs = [ qt5 ];
-
-  buildPhase = ''
-    pushd ./konsole-qml-plugin
-    qmake konsole-qml-plugin.pro PREFIX=$out
-    make
-    popd
-  '';
-
-  installPhase = ''
-    pushd ./konsole-qml-plugin
-    make install
-    popd
-
-    install -d $out/bin $out/lib/cool-old-term $out/share/cool-old-term
-    cp -a ./imports $out/lib/cool-old-term/
-    cp -a ./app     $out/share/cool-old-term/
-
-    cat > $out/bin/cool-old-term <<EOF
-    #!${stdenv.shell}
-    ${qt5}/bin/qmlscene -I $out/lib/cool-old-term/imports $out/share/cool-old-term/app/main.qml
-    EOF
-    chmod a+x $out/bin/cool-old-term
-  '';
-
-  enableParallelBuilding = true;
-
-  meta = {
-    description = "Terminal emulator which mimics the old cathode display";
-    longDescription = ''
-      cool-old-term is a terminal emulator which tries to mimic the look and
-      feel of the old cathode tube screens. It has been designed to be
-      eye-candy, customizable, and reasonably lightweight.
-    '';
-    homepage = "https://github.com/Swordifish90/cool-old-term";
-    licenses = with stdenv.lib.licenses; [ gpl2 gpl3 ];
-    platforms = stdenv.lib.platforms.linux;
-    maintainers = with stdenv.lib.maintainers; [ skeidel ];
-  };
-}

pkgs/applications/misc/cool-retro-term/default.nix

···
+{ stdenv, fetchgit, makeWrapper, qt5, qmltermwidget }:
+
+stdenv.mkDerivation rec {
+  version = "1.0.0";
+  name = "cool-retro-term-${version}";
+
+  src = fetchgit {
+    url = "https://github.com/Swordfish90/cool-retro-term.git";
+    rev = "refs/tags/v${version}";
+    sha256 = "042ikarg6n0c09niwrm987pkzi8xjxxdrg2nqvk9pj7lgmmkkfn1";
+    fetchSubmodules = false;
+  };
+
+  patchPhase = ''
+    sed -i -e '/qmltermwidget/d' cool-retro-term.pro 
+  '';
+
+  buildInputs = [ makeWrapper qt5 qmltermwidget ];
+
+  configurePhase = "qmake PREFIX=$out";
+
+  installPhase = "make -j $NIX_BUILD_CORES INSTALL_ROOT=$out install";
+
+  preFixup = ''
+    mv $out/usr/share $out/share
+    mv $out/usr/bin $out/bin
+    rmdir $out/usr
+
+    wrapProgram $out/bin/cool-retro-term \
+      --prefix QML2_IMPORT_PATH : "${qmltermwidget}/lib/qml/"
+  '';
+
+  enableParallelBuilding = true;
+
+  meta = {
+    description = "Terminal emulator which mimics the old cathode display";
+    longDescription = ''
+      cool-retro-term is a terminal emulator which tries to mimic the look and
+      feel of the old cathode tube screens. It has been designed to be
+      eye-candy, customizable, and reasonably lightweight.
+    '';
+    homepage = "https://github.com/Swordifish90/cool-retro-term";
+    licenses = with stdenv.lib.licenses; [ gpl2 gpl3 ];
+    platforms = stdenv.lib.platforms.linux;
+    maintainers = with stdenv.lib.maintainers; [ skeidel ];
+  };
+}

pkgs/development/libraries/qmltermwidget/default.nix

···
+{ stdenv, fetchgit, qt5 }:
+
+stdenv.mkDerivation rec {
+  version = "0.1.0";
+  name = "qmltermwidget-${version}";
+
+  src = fetchgit {
+    url = "https://github.com/Swordfish90/qmltermwidget.git";
+    rev = "refs/tags/v${version}";
+    sha256 = "19pz27jsdpa3pybj8sghmmd1zqgr73js1mp3875rhx158dav37nz";
+  };
+
+  buildInputs = [ qt5 ];
+
+  patchPhase = ''
+    substituteInPlace qmltermwidget.pro \
+      --replace '$$[QT_INSTALL_QML]' "/lib/qml/"
+  '';
+
+  configurePhase = "qmake PREFIX=$out";
+
+  installPhase=''make INSTALL_ROOT="$out" install'';
+  
+  enableParallelBuilding = true;
+
+  meta = {
+    description = "This project is a QML port of qtermwidget";
+    homepage = "https://github.com/Swordifish90/qmltermwidget";
+    licenses = with stdenv.lib.licenses; [ gpl2 ];
+    platforms = stdenv.lib.platforms.linux;
+    maintainers = with stdenv.lib.maintainers; [ skeidel ];
+  };
+}

pkgs/top-level/all-packages.nix

···
 
   convmv = callPackage ../tools/misc/convmv { };
 
-  cool-old-term = callPackage ../applications/misc/cool-old-term { };
+  cool-retro-term = callPackage ../applications/misc/cool-retro-term { };
 
   coreutils = callPackage ../tools/misc/coreutils
     {
···
   qimageblitz = callPackage ../development/libraries/qimageblitz {};
 
   qjson = callPackage ../development/libraries/qjson { };
+
+  qmltermwidget = callPackage ../development/libraries/qmltermwidget { };
 
   qoauth = callPackage ../development/libraries/qoauth { };
 
···
   sqliteInteractive = sqlite-interactive;  # added 2014-12-06
   nfsUtils = nfs-utils;  # added 2014-12-06
   buildbotSlave = buildbot-slave;  # added 2014-12-09
+  cool-old-term = cool-retro-term; # added 2015-01-31
 
   opentsdb = callPackage ../tools/misc/opentsdb {};