contour: 0.4.3.6442 -> 0.5.1.7247

pkgs/applications/terminal-emulators/contour/default.nix

···
-{ lib
-, stdenv
-, fetchFromGitHub
-, cmake
-, pkg-config
-, boxed-cpp
-, freetype
-, fontconfig
-, libunicode
-, libutempter
-, termbench-pro
-, qtmultimedia
-, qt5compat
-, wrapQtAppsHook
-, pcre
-, boost
-, catch2
-, fmt
-, microsoft-gsl
-, range-v3
-, yaml-cpp
-, ncurses
-, file
-, utmp
-, sigtool
-, nixosTests
-, installShellFiles
-}:
-
-stdenv.mkDerivation (final: {
-  pname = "contour";
-  version = "0.4.3.6442";
-
-  src = fetchFromGitHub {
-    owner = "contour-terminal";
-    repo = "contour";
-    rev = "v${final.version}";
-    hash = "sha256-m3BEhGbyQm07+1/h2IRhooLPDewmSuhRHOMpWPDluiY=";
-  };
-
-  patches = [ ./dont-fix-app-bundle.diff ];
-
-  outputs = [ "out" "terminfo" ];
-
-  nativeBuildInputs = [
-    cmake
-    pkg-config
-    ncurses
-    file
-    wrapQtAppsHook
-    installShellFiles
-  ] ++ lib.optionals stdenv.hostPlatform.isDarwin [ sigtool ];
-
-  buildInputs = [
-    boxed-cpp
-    fontconfig
-    freetype
-    libunicode
-    termbench-pro
-    qtmultimedia
-    qt5compat
-    pcre
-    boost
-    catch2
-    fmt
-    microsoft-gsl
-    range-v3
-    yaml-cpp
-  ]
-  ++ lib.optionals stdenv.hostPlatform.isLinux [ libutempter ]
-  ++ lib.optionals stdenv.hostPlatform.isDarwin [ utmp ];
-
-  cmakeFlags = [ "-DCONTOUR_QT_VERSION=6" ];
-
-  postInstall = ''
-    mkdir -p $out/nix-support $terminfo/share
-  '' + lib.optionalString stdenv.hostPlatform.isDarwin ''
-    mkdir $out/Applications
-    installShellCompletion --zsh $out/contour.app/Contents/Resources/shell-integration/shell-integration.zsh
-    installShellCompletion --fish $out/contour.app/Contents/Resources/shell-integration/shell-integration.fish
-    cp -r $out/contour.app/Contents/Resources/terminfo $terminfo/share
-    mv $out/contour.app $out/Applications
-    ln -s $out/bin $out/Applications/contour.app/Contents/MacOS
-  '' + lib.optionalString stdenv.hostPlatform.isLinux ''
-    mv $out/share/terminfo $terminfo/share/
-    installShellCompletion --zsh $out/share/contour/shell-integration/shell-integration.zsh
-    installShellCompletion --fish $out/share/contour/shell-integration/shell-integration.fish
-  '' + ''
-    echo "$terminfo" >> $out/nix-support/propagated-user-env-packages
-  '';
-
-  passthru.tests.test = nixosTests.terminal-emulators.contour;
-
-  meta = with lib; {
-    description = "Modern C++ Terminal Emulator";
-    homepage = "https://github.com/contour-terminal/contour";
-    changelog = "https://github.com/contour-terminal/contour/raw/v${version}/Changelog.md";
-    license = licenses.asl20;
-    maintainers = with maintainers; [ moni ];
-    platforms = platforms.unix;
-    mainProgram = "contour";
-    # This was caused by boxed-cpp 1.4.2 -> 1.4.3
-    # More details in issue #345752
-    broken = true;
-  };
-})

pkgs/by-name/co/contour/package.nix

···
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  pkg-config,
+  boxed-cpp,
+  freetype,
+  fontconfig,
+  libunicode,
+  libutempter,
+  termbench-pro,
+  qt6,
+  pcre,
+  boost,
+  catch2_3,
+  fmt,
+  microsoft-gsl,
+  range-v3,
+  yaml-cpp,
+  ncurses,
+  file,
+  apple-sdk_11,
+  libutil,
+  sigtool,
+  nixosTests,
+  installShellFiles,
+}:
+
+stdenv.mkDerivation (final: {
+  pname = "contour";
+  version = "0.5.1.7247";
+
+  src = fetchFromGitHub {
+    owner = "contour-terminal";
+    repo = "contour";
+    rev = "v${final.version}";
+    hash = "sha256-/vpbyaULemyM3elwaoofvbeeID7jNrmu8X8HlZxWGCk";
+  };
+
+  patches = [ ./dont-fix-app-bundle.diff ];
+
+  outputs = [
+    "out"
+    "terminfo"
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    ncurses
+    file
+    qt6.wrapQtAppsHook
+    installShellFiles
+  ] ++ lib.optionals stdenv.hostPlatform.isDarwin [ sigtool ];
+
+  buildInputs =
+    [
+      boxed-cpp
+      fontconfig
+      freetype
+      libunicode
+      termbench-pro
+      qt6.qtmultimedia
+      qt6.qt5compat
+      pcre
+      boost
+      catch2_3
+      fmt
+      microsoft-gsl
+      range-v3
+      yaml-cpp
+    ]
+    ++ lib.optionals stdenv.hostPlatform.isLinux [ libutempter ]
+    ++ lib.optionals stdenv.hostPlatform.isDarwin [
+      apple-sdk_11
+      libutil
+    ];
+
+  cmakeFlags = [ "-DCONTOUR_QT_VERSION=6" ];
+
+  postInstall =
+    ''
+      mkdir -p $out/nix-support $terminfo/share
+    ''
+    + lib.optionalString stdenv.hostPlatform.isDarwin ''
+      mkdir $out/Applications
+      installShellCompletion --zsh $out/contour.app/Contents/Resources/shell-integration/shell-integration.zsh
+      installShellCompletion --fish $out/contour.app/Contents/Resources/shell-integration/shell-integration.fish
+      cp -r $out/contour.app/Contents/Resources/terminfo $terminfo/share
+      mv $out/contour.app $out/Applications
+      ln -s $out/bin $out/Applications/contour.app/Contents/MacOS
+    ''
+    + lib.optionalString stdenv.hostPlatform.isLinux ''
+      mv $out/share/terminfo $terminfo/share/
+      installShellCompletion --zsh $out/share/contour/shell-integration/shell-integration.zsh
+      installShellCompletion --fish $out/share/contour/shell-integration/shell-integration.fish
+    ''
+    + ''
+      echo "$terminfo" >> $out/nix-support/propagated-user-env-packages
+    '';
+
+  passthru.tests.test = nixosTests.terminal-emulators.contour;
+
+  meta = with lib; {
+    description = "Modern C++ Terminal Emulator";
+    homepage = "https://github.com/contour-terminal/contour";
+    changelog = "https://github.com/contour-terminal/contour/raw/v${version}/Changelog.md";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ moni ];
+    platforms = platforms.unix;
+    mainProgram = "contour";
+  };
+})

pkgs/by-name/gl/glaze/package.nix

···
   stdenv,
   fetchFromGitHub,
   cmake,
-  avx2 ? false,
+  enableAvx2 ? false,
 }:
 
 stdenv.mkDerivation (final: {
···
   };
 
   nativeBuildInputs = [ cmake ];
-  cmakeFlags = [ "-Dglaze_ENABLE_AVX2=${if avx2 then "ON" else "OFF"}" ];
+  cmakeFlags = [ (lib.cmakeBool "glaze_ENABLE_AVX2" enableAvx2) ];
 
   meta = with lib; {
     description = "Extremely fast, in memory, JSON and interface library for modern C++";

pkgs/top-level/all-packages.nix

···
 
   ### APPLICATIONS/TERMINAL-EMULATORS
 
-  contour = qt6.callPackage ../applications/terminal-emulators/contour {
-    inherit (darwin.apple_sdk_11_0.libs) utmp;
-    inherit (darwin) sigtool;
-    stdenv = if stdenv.hostPlatform.isDarwin then darwin.apple_sdk_11_0.stdenv else stdenv;
-    catch2 = catch2_3;
-    fmt = fmt_9;
+  contour = callPackage ../by-name/co/contour/package.nix {
+    inherit (darwin) libutil sigtool;
+    stdenv = if stdenv.hostPlatform.isDarwin then llvmPackages_17.stdenv else stdenv;
   };
 
   cool-retro-term = libsForQt5.callPackage ../applications/terminal-emulators/cool-retro-term { };
···
   libunicode = callPackage ../by-name/li/libunicode/package.nix {
     stdenv = if stdenv.hostPlatform.isDarwin then llvmPackages_17.stdenv else stdenv;
   };
-
-  libusbgx = callPackage ../development/libraries/libusbgx { };
-
-  libusbsio = callPackage ../development/libraries/libusbsio { };
-
-  libucontext = callPackage ../development/libraries/libucontext { };
-
-  libutempter = callPackage ../development/libraries/libutempter { };
-
-  libuldaq = callPackage ../development/libraries/libuldaq { };
 
   libunwind =
     # Use the system unwinder in the SDK but provide a compatibility package to: