nginx-doc-unstable: init at 2022-05-05

Build documentation of nginx (which is maintained separately from webserver
itself) and make it available both as "nginx-doc" attribute and as "doc" output
of "nginx" derivation.

pkgs/data/documentation/nginx-doc/default.nix

···
+{ lib, stdenv, libxml2, libxslt, fetchhg }:
+
+# Upstream maintains documentation (sources of https://nginx.org) in separate
+# mercurial repository, which do not correspond to particular git commit, but at
+# least has "introduced in version X.Y" comments.
+#
+# In other words, documentation does not necessary matches capabilities of
+# $out/bin/nginx, but we have no better options.
+stdenv.mkDerivation {
+  pname = "nginx-doc-unstable";
+  version = "2022-05-05";
+  src = fetchhg {
+    url = "https://hg.nginx.org/nginx.org";
+    rev = "a3aee2697d4e";
+    sha256 = "029n4mnmjw94h01qalmjgf1c2h3h7wm798xv5knk3padxiy4m28b";
+  };
+  patches = [ ./exclude-google-analytics.patch ];
+  nativeBuildInputs = [ libxslt libxml2 ];
+
+  # Generated documentation is not local-friendly, since it assumes that link to directory
+  # is the same as link to index.html in that directory, which is not how browsers behave
+  # with local filesystem.
+  #
+  # TODO: patch all relative links that do not end with .html.
+
+  # /en subdirectory must exist, relative links expect it.
+  installPhase = ''
+    mkdir -p $out/share/doc/nginx
+    mv libxslt/en $out/share/doc/nginx
+  '';
+
+  meta = with lib; {
+    description = "A reverse proxy and lightweight webserver (documentation)";
+    homepage    = "https://nginx.org/";
+    license     = licenses.bsd2;
+    platforms   = platforms.all;
+    priority    = 6;
+    maintainers = with maintainers; [ kaction ];
+  };
+}

pkgs/servers/http/nginx/generic.nix

···
-{ lib, stdenv, fetchurl, fetchpatch, openssl, zlib, pcre, libxml2, libxslt
-, fetchhg
+outer@{ lib, stdenv, fetchurl, fetchpatch, openssl, zlib, pcre, libxml2, libxslt
+, nginx-doc
 
 , nixosTests
 , substituteAll, gd, geoip, perl
···
 , nginxVersion ? version
 , src ? null # defaults to upstream nginx ${version}
 , sha256 ? null # when not specifying src
-
-# Upstream maintains documentation (sources of https://nginx.org) in separate
-# mercurial repository, which do not correspond to particular git commit, but at
-# least has "introduced in version X.Y" comments.
-#
-# In other words, documentation does not necessary matches capabilities of
-# $out/bin/nginx, but we have no better options.
-, srcDoc ? fetchhg {
-    url = "https://hg.nginx.org/nginx.org";
-    sha256 = "029n4mnmjw94h01qalmjgf1c2h3h7wm798xv5knk3padxiy4m28b";
-    rev = "a3aee2697d4e";
-  }
-, extraPatchesDoc ? [ ./nginx-doc.patch ]
 , configureFlags ? []
 , buildInputs ? []
 , extraPatches ? []
···
       in
         if supports nginxVersion then mod.${attrPath} or []
         else throw "Module at ${toString mod.src} does not support nginx version ${nginxVersion}!");
-
-  # Output of this derivation is copied into $doc of resulting nginx to save on
-  # building time, since we have multiple nginx versions, but only one version
-  # of documentation.
-  #
-  # As such, this derivation never appears in user profile, so its name and
-  # compliance to conventions is not important.
-  documentation = stdenv.mkDerivation {
-    name = "nginx-doc";
-    src = srcDoc;
-    patches = extraPatchesDoc;
-    nativeBuildInputs = [ libxslt libxml2 ];
-
-    # Generated documentation is not local-friendly, since it assumes that link to directory
-    # is the same as link to index.html in that directory, which is not how browsers behave
-    # with local filesystem.
-    #
-    # TODO: patch all relative links that do not end with .html.
-
-    # /en subdirectory must exist, relative links expect it.
-    installPhase = ''
-      mkdir -p $out/share/doc/nginx
-      mv libxslt/en $out/share/doc/nginx
-    '';
-  };
 
 in
 
···
 
   preInstall = ''
     mkdir -p $doc
-    cp -r ${documentation}/* $doc
+    cp -r ${nginx-doc}/* $doc
   '';
 
   postInstall = if postInstall != null then postInstall else ''

pkgs/top-level/all-packages.nix

···
 
   nginx = nginxStable;
 
+  nginx-doc = callPackage ../data/documentation/nginx-doc { };
+
   nginxQuic = callPackage ../servers/http/nginx/quic.nix {
     zlib = zlib-ng.override { withZlibCompat = true; };
     withPerl = false;