treewide: migrate qcsxcad/appcsxcad to qt6 and pkgs/by-name (#440165)

pkgs/applications/science/electronics/appcsxcad/default.nix

···
-{
-  lib,
-  mkDerivation,
-  fetchFromGitHub,
-  cmake,
-  csxcad,
-  qcsxcad,
-  hdf5,
-  vtkWithQt5,
-  qtbase,
-  fparser,
-  tinyxml,
-  cgal,
-  boost,
-}:
-
-mkDerivation {
-  pname = "appcsxcad";
-  version = "unstable-2023-01-06";
-
-  src = fetchFromGitHub {
-    owner = "thliebig";
-    repo = "AppCSXCAD";
-    rev = "379ede4b8e00c11e8d0fb724c35547991b30c423";
-    hash = "sha256-L0ZEyovnfMzM7JuITBuhb4tJ2Aqgw52IiKEfEGq7Yo0=";
-  };
-
-  nativeBuildInputs = [
-    cmake
-  ];
-
-  buildInputs = [
-    csxcad
-    qcsxcad
-    hdf5
-    vtkWithQt5
-    qtbase
-    fparser
-    tinyxml
-    cgal
-    boost
-  ];
-
-  postFixup = ''
-    rm $out/bin/AppCSXCAD.sh
-  '';
-
-  meta = with lib; {
-    description = "Minimal Application using the QCSXCAD library";
-    mainProgram = "AppCSXCAD";
-    homepage = "https://github.com/thliebig/AppCSXCAD";
-    license = licenses.gpl3;
-    maintainers = with maintainers; [ matthuszagh ];
-    platforms = platforms.linux;
-  };
-}

pkgs/by-name/ap/appcsxcad/package.nix

···
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  csxcad,
+  qcsxcad,
+  hdf5,
+  vtkWithQt6,
+  qt6,
+  fparser,
+  tinyxml,
+  cgal,
+  boost,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "appcsxcad";
+  version = "0.2.3";
+
+  src = fetchFromGitHub {
+    owner = "thliebig";
+    repo = "AppCSXCAD";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-KrsnCnRZRTbkgEH3hOETrYhseg5mCHPqhAbYyHlS3sk=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    qt6.wrapQtAppsHook
+  ];
+
+  buildInputs = [
+    csxcad
+    qcsxcad
+    hdf5
+    vtkWithQt6
+    qt6.qtbase
+    qt6.qtwayland
+    fparser
+    tinyxml
+    cgal
+    boost
+  ];
+
+  postFixup = ''
+    rm $out/bin/AppCSXCAD.sh
+  '';
+
+  meta = {
+    description = "Minimal Application using the QCSXCAD library";
+    mainProgram = "AppCSXCAD";
+    homepage = "https://github.com/thliebig/AppCSXCAD";
+    license = lib.licenses.gpl3;
+    maintainers = with lib.maintainers; [ matthuszagh ];
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/by-name/qc/qcsxcad/package.nix

···
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  csxcad,
+  tinyxml,
+  vtkWithQt6,
+  qt6,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "qcsxcad";
+  version = "0.6.3";
+
+  src = fetchFromGitHub {
+    owner = "thliebig";
+    repo = "QCSXCAD";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-bX6e3ugHJynU9tP70BV8TadnoGg1VO7SAYJueMkMAyo=";
+  };
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "ENABLE_RPATH" false)
+  ];
+
+  buildInputs = [
+    csxcad
+    tinyxml
+    vtkWithQt6
+    qt6.qtbase
+    qt6.qt5compat
+    qt6.qtwayland
+  ];
+
+  dontWrapQtApps = true;
+
+  meta = {
+    description = "Qt library for CSXCAD";
+    homepage = "https://github.com/thliebig/QCSXCAD";
+    license = lib.licenses.gpl3;
+    maintainers = with lib.maintainers; [ matthuszagh ];
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/development/libraries/science/electronics/qcsxcad/default.nix

···
-{
-  lib,
-  mkDerivation,
-  fetchFromGitHub,
-  cmake,
-  csxcad,
-  tinyxml,
-  vtkWithQt5,
-  qtbase,
-}:
-
-mkDerivation {
-  pname = "qcsxcad";
-  version = "unstable-2023-01-06";
-
-  src = fetchFromGitHub {
-    owner = "thliebig";
-    repo = "QCSXCAD";
-    rev = "1cde9d560a5000f4c24c249d2dd5ccda12de38b6";
-    hash = "sha256-kc9Vnx6jGiQC2K88ZH00b61D/DbWxAIZZwYCsINqtrY=";
-  };
-
-  outputs = [
-    "out"
-    "dev"
-  ];
-
-  nativeBuildInputs = [
-    cmake
-  ];
-
-  cmakeFlags = [
-    "-DCSXCAD_ROOT_DIR=${csxcad}"
-    "-DENABLE_RPATH=OFF"
-  ];
-
-  buildInputs = [
-    csxcad
-    tinyxml
-    vtkWithQt5
-    qtbase
-  ];
-
-  meta = with lib; {
-    description = "Qt library for CSXCAD";
-    homepage = "https://github.com/thliebig/QCSXCAD";
-    license = licenses.gpl3;
-    maintainers = with maintainers; [ matthuszagh ];
-    platforms = platforms.linux;
-  };
-}

pkgs/top-level/aliases.nix

···
 
   qbittorrent-qt5 = throw "'qbittorrent-qt5' has been removed as qBittorrent 5 dropped support for Qt 5. Please use 'qbittorrent'"; # Added 2024-09-30
   qcachegrind = throw "'qcachegrind' has been removed, as it depends on KDE Gear 5, which has reached EOL"; # Added 2025-08-20
-  qcsxcad = throw "'qcsxcad' has been renamed to/replaced by 'libsForQt5.qcsxcad'"; # Converted to throw 2024-10-17
   qflipper = qFlipper; # Added 2022-02-11
   qnial = throw "'qnial' has been removed due to failing to build and being unmaintained"; # Added 2025-06-26
   qscintilla = libsForQt5.qscintilla; # Added 2023-09-20

pkgs/top-level/all-packages.nix

···
 
   ### SCIENCE / ELECTRONICS
 
-  appcsxcad = libsForQt5.callPackage ../applications/science/electronics/appcsxcad { };
-
   simulide_0_4_15 = callPackage ../by-name/si/simulide/package.nix { versionNum = "0.4.15"; };
   simulide_1_0_0 = callPackage ../by-name/si/simulide/package.nix { versionNum = "1.0.0"; };
   simulide_1_1_0 = callPackage ../by-name/si/simulide/package.nix { versionNum = "1.1.0"; };
···
     withNgshared = false;
   };
 
-  openems = callPackage ../applications/science/electronics/openems {
-    qcsxcad = libsForQt5.qcsxcad;
-  };
+  openems = callPackage ../applications/science/electronics/openems { };
 
   xyce-parallel = callPackage ../by-name/xy/xyce/package.nix {
     withMPI = true;

pkgs/top-level/qt5-packages.nix

···
 
         qcoro = callPackage ../development/libraries/qcoro { };
 
-        qcsxcad = callPackage ../development/libraries/science/electronics/qcsxcad { };
-
         qcustomplot = callPackage ../development/libraries/qcustomplot { };
 
         qjson = callPackage ../development/libraries/qjson { };