python3Packages.pyoprf: init at 0.7.1 (#432855)

pkgs/development/python-modules/pyoprf/default.nix

···
+{
+  lib,
+  stdenv,
+  buildPythonPackage,
+  liboprf,
+  setuptools,
+  pysodium,
+  securestring,
+  pytestCheckHook,
+}:
+
+buildPythonPackage rec {
+  pname = "pyoprf";
+  pyproject = true;
+
+  inherit (liboprf)
+    version
+    src
+    ;
+
+  postPatch =
+    let
+      soext = stdenv.hostPlatform.extensions.sharedLibrary;
+    in
+    ''
+      substituteInPlace ./pyoprf/__init__.py --replace-fail \
+        "ctypes.util.find_library('oprf') or ctypes.util.find_library('liboprf')" "'${lib.getLib liboprf}/lib/liboprf${soext}'"
+    '';
+
+  sourceRoot = "${src.name}/python";
+
+  build-system = [ setuptools ];
+
+  dependencies = [
+    pysodium
+    securestring
+  ];
+
+  pythonImportsCheck = [ "pyoprf" ];
+
+  nativeCheckInputs = [ pytestCheckHook ];
+
+  pytestFlagsArray = [ "tests/test.py" ];
+
+  meta = {
+    inherit (liboprf.meta)
+      description
+      homepage
+      changelog
+      license
+      teams
+      ;
+  };
+}

pkgs/development/python-modules/pysodium/default.nix

···
+{
+  lib,
+  stdenv,
+  buildPythonPackage,
+  fetchFromGitHub,
+  setuptools,
+  libsodium,
+  pytestCheckHook,
+}:
+
+buildPythonPackage rec {
+  pname = "pysodium";
+  version = "0.7.18";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "stef";
+    repo = "pysodium";
+    tag = "v${version}";
+    hash = "sha256-F2215AAI8UIvn6UbaJ/YxI4ZolCzlwY6nS5IafTs+i4=";
+  };
+
+  postPatch =
+    let
+      soext = stdenv.hostPlatform.extensions.sharedLibrary;
+    in
+    ''
+      substituteInPlace ./pysodium/__init__.py --replace-fail \
+        "ctypes.util.find_library('sodium') or ctypes.util.find_library('libsodium')" "'${libsodium}/lib/libsodium${soext}'"
+    '';
+
+  build-system = [ setuptools ];
+
+  buildInputs = [ libsodium ];
+
+  nativeCheckInputs = [ pytestCheckHook ];
+
+  pythonImportsCheck = [ "pysodium" ];
+
+  meta = {
+    description = "Wrapper for libsodium providing high level crypto primitives";
+    homepage = "https://github.com/stef/pysodium";
+    changelog = "https://github.com/stef/pysodium/releases/tag/v${version}";
+    maintainers = [ lib.maintainers.ethancedwards8 ];
+    license = lib.licenses.bsd2;
+  };
+}

pkgs/development/python-modules/securestring/default.nix

···
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  setuptools,
+  openssl,
+}:
+
+buildPythonPackage rec {
+  pname = "securestring";
+  version = "0.2";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "dnet";
+    repo = "pysecstr";
+    tag = "v${version}";
+    hash = "sha256-FV5NUPberA5nqHad8IwkQLMldT1DPqTGpqOwgQ2zSdI=";
+  };
+
+  build-system = [ setuptools ];
+
+  buildInputs = [ openssl ];
+
+  pythonImportsCheck = [ "SecureString" ];
+
+  # no upstream tests exist
+  doCheck = false;
+
+  meta = {
+    description = "Clears the contents of strings containing cryptographic material";
+    homepage = "https://github.com/dnet/pysecstr";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.ethancedwards8 ];
+  };
+}

pkgs/top-level/python-packages.nix

···
 
   pyoppleio-legacy = callPackage ../development/python-modules/pyoppleio-legacy { };
 
+  pyoprf = callPackage ../development/python-modules/pyoprf { };
+
   pyorc = callPackage ../development/python-modules/pyorc { };
 
   pyorthanc = callPackage ../development/python-modules/pyorthanc { };
···
   pysnow = callPackage ../development/python-modules/pysnow { };
 
   pysocks = callPackage ../development/python-modules/pysocks { };
+
+  pysodium = callPackage ../development/python-modules/pysodium { };
 
   pysol-cards = callPackage ../development/python-modules/pysol-cards { };
 
···
   sectxt = callPackage ../development/python-modules/sectxt { };
 
   secure = callPackage ../development/python-modules/secure { };
+
+  securestring = callPackage ../development/python-modules/securestring { };
 
   securesystemslib = callPackage ../development/python-modules/securesystemslib { };