Merge pull request #14579 from elitak/factorio

factorio: 0.12.29 headless + server module

nixos/modules/misc/ids.nix

···
       mfi = 238;
       caddy = 239;
       taskd = 240;
+      factorio = 241;
 
       # When adding a uid, make sure it doesn't match an existing gid. And don't use uids above 399!
 
···
       #mfi = 238; # unused
       caddy = 239;
       taskd = 240;
+      factorio = 241;
 
       # When adding a gid, make sure it doesn't match an existing
       # uid. Users and groups with the same name should have equal

nixos/modules/module-list.nix

···
   ./services/desktops/gnome3/tracker.nix
   ./services/desktops/profile-sync-daemon.nix
   ./services/desktops/telepathy.nix
+  ./services/games/factorio.nix
   ./services/games/ghost-one.nix
   ./services/games/minecraft-server.nix
   ./services/games/minetest-server.nix

nixos/modules/services/games/factorio.nix

···
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+  cfg = config.services.factorio;
+  name = "Factorio";
+  stateDir = "/var/lib/factorio";
+  configFile = pkgs.writeText "factorio.conf" ''
+    use-system-read-write-data-directories=true
+    [path]
+    read-data=${pkgs.factorio-headless}/share/factorio/data
+    write-data=${stateDir}
+  '';
+in
+{
+  options = {
+    services.factorio = {
+      enable = mkEnableOption name;
+      port = mkOption {
+        type = types.int;
+        default = 34197;
+        description = ''
+          The port to which the service should bind.
+
+          This option will also open up the UDP port in the firewall configuration.
+        '';
+      };
+      saveName = mkOption {
+        type = types.string;
+        default = "default";
+        description = ''
+          The name of the savegame that will be used by the server.
+
+          When not present in ${stateDir}/saves, it will be generated before starting the service.
+        '';
+      };
+      # TODO Add more individual settings as nixos-options?
+      # TODO XXX The server tries to copy a newly created config file over the old one
+      #   on shutdown, but fails, because it's in the nix store. When is this needed?
+      #   Can an admin set options in-game and expect to have them persisted?
+      configFile = mkOption {
+        type = types.path;
+        default = configFile;
+        defaultText = "configFile";
+        description = ''
+          The server's configuration file.
+
+          The default file generated by this module contains lines essential to
+          the server's operation. Use its contents as a basis for any
+          customizations.
+        '';
+      };
+    };
+  };
+
+  config = mkIf cfg.enable {
+    users = {
+      users.factorio = {
+        uid             = config.ids.uids.factorio;
+        description     = "Factorio server user";
+        group           = "factorio";
+        home            = stateDir;
+        createHome      = true;
+      };
+
+      groups.factorio = {
+        gid = config.ids.gids.factorio;
+      };
+    };
+
+    systemd.services.factorio = {
+      description   = "Factorio headless server";
+      wantedBy      = [ "multi-user.target" ];
+      after         = [ "network.target" ];
+
+      preStart = ''
+          test -e ${stateDir}/saves/${cfg.saveName}.zip || ${pkgs.factorio-headless}/bin/factorio \
+            --config=${cfg.configFile} \
+            --create=${cfg.saveName}
+      '';
+
+      serviceConfig = {
+        User = "factorio";
+        Group = "factorio";
+        Restart = "always";
+        KillSignal = "SIGINT";
+        WorkingDirectory = stateDir;
+        PrivateTmp = true;
+        UMask = "0007";
+        ExecStart = toString [
+          "${pkgs.factorio-headless}/bin/factorio"
+          "--config=${cfg.configFile}"
+          "--port=${toString cfg.port}"
+          "--start-server=${cfg.saveName}"
+        ];
+      };
+    };
+
+    networking.firewall.allowedUDPPorts = [ cfg.port ];
+  };
+}

pkgs/games/factorio/default.nix

···
 # Begin download parameters
 , username ? ""
 , password ? ""
+, releaseType
 }:
 
+assert releaseType == "alpha" || releaseType == "headless";
+
+with stdenv.lib;
 let
-  version = "0.12.28";
+  version = "0.12.29";
+  isHeadless = releaseType == "headless";
+
+  arch = if stdenv.system == "x86_64-linux" then {
+    inUrl = "linux64";
+    inTar = "x64";
+  } else if stdenv.system == "i686-linux" then {
+    inUrl = "linux32";
+    inTar = "i386";
+  } else abort "Unsupported platform";
 
-  fetch = callPackage ./fetch.nix { username = username; password = password; };
-  arch = if stdenv.system == "x86_64-linux" then "x64"
-         else if stdenv.system == "i686-linux" then "x32"
-         else abort "Unsupported platform";
+  authenticatedFetch = callPackage ./fetch.nix { inherit username password; };
 
-  variants = {
+  fetch = rec {
+    url = "https://www.factorio.com/get-download/${version}/${releaseType}/${arch.inUrl}";
+    name = "factorio_${releaseType}_${arch.inTar}-${version}.tar.gz"; # TODO take this from 302 redirection somehow? fetchurl doesn't help.
     x64 = {
-      url = "https://www.factorio.com/get-download/${version}/alpha/linux64";
-      sha256 = "01si5n9hb2h0c5q8k3hr3nphsakp9kki84qyp70dgddwqsn8wfjl";
+      headless = fetchurl        { inherit name url; sha256 = "1hr5dhpfagknjjd47qw3fa3ap8ikjc9hvxavrg4mpslbr0iqww8v"; };
+      alpha = authenticatedFetch { inherit      url; sha256 = "0vngfrjjib99k6czhg32rikfi36i3p3adx4mxc1z8bi5n70dbwqb"; };
     };
-
-    x32 = {
-      url = "https://www.factorio.com/get-download/${version}/alpha/linux32";
-      sha256 = "13h013ixyhv4rpvh0jv5jry3mrwv65v57nqn16bjh3hr8ip70lkq";
+    i386 = {
+      headless = abort "Factorio 32-bit headless binaries are not available for download.";
+      alpha = authenticatedFetch { inherit      url; sha256 = "10135rd9103x79i89p6fh5ssmw612012yyx3yyhb3nzl554zqzbm"; };
     };
   };
+
+  configBaseCfg = ''
+    use-system-read-write-data-directories=false
+    [path]
+    read-data=$out/share/factorio/data/
+  '';
+
+  updateConfigSh = ''
+    #! $SHELL
+    if [[ -e ~/.factorio/config.cfg ]]; then
+      # Config file exists, but may have wrong path.
+      # Try to edit it. I'm sure this is perfectly safe and will never go wrong.
+      sed -i 's|^read-data=.*|read-data=$out/share/factorio/data/|' ~/.factorio/config.cfg
+    else
+      # Config file does not exist. Phew.
+      install -D $out/share/factorio/config-base.cfg ~/.factorio/config.cfg
+    fi
+  '';
+
 in
 
 stdenv.mkDerivation rec {
-  name = "factorio-${version}";
+  name = "factorio-${releaseType}-${version}";
 
-  src = fetch variants.${arch};
+  src = fetch.${arch.inTar}.${releaseType};
 
-  libPath = stdenv.lib.makeLibraryPath [
-    alsaLib
-    libX11
-    libXcursor
-    libXinerama
-    libXrandr
-    libXi
-    mesa_noglu
-  ];
+  libPath = stdenv.lib.makeLibraryPath (
+    optionals (! isHeadless) [
+      alsaLib
+      libX11
+      libXcursor
+      libXinerama
+      libXrandr
+      libXi
+      mesa_noglu
+    ]
+  );
 
   buildInputs = [ makeWrapper ];
 
+  dontBuild = true;
+
+  # TODO detangle headless/normal mode wrapping, libs, etc.  test all urls 32/64/headless/gfx
   installPhase = ''
     mkdir -p $out/{bin,share/factorio}
-    cp -a bin/${arch}/factorio $out/bin/factorio.${arch}
-    cp -a doc-html data $out/share/factorio/
-
-    # Fortunately, Factorio already supports system-wide installs.
-    # Unfortunately it's a bit inconvenient to set the paths.
-    cat > $out/share/factorio/config-base.cfg <<EOF
-use-system-read-write-data-directories=false
-[path]
-read-data=$out/share/factorio/data/
-EOF
-
-    cat > $out/share/factorio/update-config.sh <<EOF
-if [[ -e ~/.factorio/config.cfg ]]; then
-  # Config file exists, but may have wrong path.
-  # Try to edit it. I'm sure this is perfectly safe and will never go wrong.
-  sed -i 's|^read-data=.*|read-data=$out/share/factorio/data/|' ~/.factorio/config.cfg
-else
-  # Config file does not exist. Phew.
-  install -D $out/share/factorio/config-base.cfg ~/.factorio/config.cfg
-fi
-EOF
-    chmod a+x $out/share/factorio/update-config.sh
-
+    cp -a data $out/share/factorio
+    cp -a bin/${arch.inTar}/factorio $out/bin/factorio
     patchelf \
       --set-interpreter $(cat $NIX_CC/nix-support/dynamic-linker) \
-      $out/bin/factorio.${arch}
+      $out/bin/factorio
 
-    makeWrapper $out/bin/factorio.${arch} $out/bin/factorio \
+  '' + optionalString (! isHeadless) (''
+    mv $out/bin/factorio $out/bin/factorio.${arch.inTar}
+    makeWrapper $out/bin/factorio.${arch.inTar} $out/bin/factorio \
       --prefix LD_LIBRARY_PATH : /run/opengl-driver/lib:$libPath \
       --run "$out/share/factorio/update-config.sh" \
       --add-flags "-c \$HOME/.factorio/config.cfg"
-  '';
+    # Fortunately, Factorio already supports system-wide installs.
+    # Unfortunately it's a bit inconvenient to set the paths.
+    install -m0644 <(cat << EOF
+  '' + configBaseCfg + ''
+    EOF
+    ) $out/share/factorio/config-base.cfg
+
+    install -m0755 <(cat << EOF
+  '' + updateConfigSh + ''
+    EOF
+    ) $out/share/factorio/update-config.sh
+    cp -a doc-html $out/share/factorio
+  '');
+
+  preferLocalBuild = true;
 
   meta = {
     description = "A game in which you build and maintain factories";
···
     '';
     homepage = https://www.factorio.com/;
     license = stdenv.lib.licenses.unfree;
-    maintainers = [ stdenv.lib.maintainers.Baughn ];
+    maintainers = with stdenv.maintainers; [ Baughn elitak ];
     platforms = [ "i686-linux" "x86_64-linux" ];
   };
 }

pkgs/top-level/all-packages.nix

···
 
   exult = callPackage ../games/exult { };
 
-  factorio = callPackage ../games/factorio {};
+  factorio = callPackage ../games/factorio { releaseType = "alpha"; };
+
+  factorio-headless = callPackage ../games/factorio { releaseType = "headless"; };
 
   fairymax = callPackage ../games/fairymax {};