zfs-replicate: patch path to lz4 binary (#370241)

pkgs/by-name/zf/zfs-replicate/package.nix

···
+{
+  lib,
+  stdenv,
+  python3Packages,
+  fetchFromGitHub,
+  lz4,
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "zfs_replicate";
+  version = "4.0.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "alunduil";
+    repo = "zfs-replicate";
+    tag = "v${version}";
+    hash = "sha256-VajMSoFZ4SQXpuF1Lo6S9IhxvspCfUwpNw5zg16uA3M=";
+  };
+
+  # For compression to work, both local and remote systems must have lz4 installed.
+  # This hard codes the path to the lz4 when running it on the local system.
+  postPatch = ''
+    substituteInPlace zfs/replicate/compress/command.py \
+      --replace-fail \
+        '("/usr/bin/env - lz4 | ", "/usr/bin/env - lz4 -d | ")' \
+        '("${lib.getExe lz4}  | ", "/usr/bin/env - lz4 -d | ")'
+  '';
+
+  build-system = with python3Packages; [
+    poetry-core
+  ];
+
+  dependencies = with python3Packages; [
+    click
+    stringcase
+  ];
+
+  nativeCheckInputs = with python3Packages; [
+    pytestCheckHook
+    hypothesis
+    pytest-cov-stub
+  ];
+
+  doCheck = true;
+
+  disabledTestPaths = lib.optionals stdenv.isDarwin [
+    # AssertionError: Expected SystemExit or FileNotFoundError
+    "zfs_test/replicate_test/cli_test/main_test.py"
+  ];
+
+  meta = {
+    description = "ZFS Snapshot Replication";
+    homepage = "https://github.com/alunduil/zfs-replicate";
+    changelog = "https://github.com/alunduil/zfs-replicate/blob/v${version}/CHANGELOG.md";
+    mainProgram = "zfs-replicate";
+    license = lib.licenses.bsd2;
+    maintainers = with lib.maintainers; [ alunduil ];
+  };
+}

pkgs/tools/backup/zfs-replicate/default.nix

···
-{
-  buildPythonApplication,
-  click,
-  fetchPypi,
-  hypothesis,
-  lib,
-  poetry-core,
-  pytest-cov-stub,
-  pytestCheckHook,
-  stringcase,
-}:
-
-buildPythonApplication rec {
-  pname = "zfs_replicate";
-  version = "4.0.0";
-  pyproject = true;
-
-  src = fetchPypi {
-    inherit pname version;
-    hash = "sha256-9WD2IW7GRxMF7hOa8HTI/+cuOjVaYMT4OnrYU/xFgME=";
-  };
-
-  nativeBuildInputs = [
-    poetry-core
-  ];
-
-  nativeCheckInputs = [
-    pytestCheckHook
-    hypothesis
-    pytest-cov-stub
-  ];
-
-  propagatedBuildInputs = [
-    click
-    stringcase
-  ];
-
-  doCheck = true;
-
-  meta = with lib; {
-    homepage = "https://github.com/alunduil/zfs-replicate";
-    description = "ZFS Snapshot Replication";
-    mainProgram = "zfs-replicate";
-    license = licenses.bsd2;
-    maintainers = with maintainers; [ alunduil ];
-  };
-}

pkgs/top-level/all-packages.nix

···
 
   wfuzz = with python3Packages; toPythonApplication wfuzz;
 
-  zfs-replicate = python3Packages.callPackage ../tools/backup/zfs-replicate { };
-
   kodelife = callPackage ../applications/graphics/kodelife {
     inherit (gst_all_1) gstreamer gst-plugins-base;
   };