Merge staging-next into staging

pkgs/applications/graphics/fluxus/default.nix

···
 , ode
 , openal
 , openssl
-, racket
+, racket_7_9
 , sconsPackages
 , zlib
 }:
···
     openssl
     zlib
   ];
+  racket = racket_7_9;
 in
 stdenv.mkDerivation rec {
   pname = "fluxus";
···
     ode
     openal
     openssl.dev
-    racket
+    racket_7_9
   ];
   nativeBuildInputs = [ sconsPackages.scons_3_1_2 ];
 

pkgs/applications/science/math/R/default.nix

···
 
   # Test of the examples for package 'tcltk' fails in Darwin sandbox. See:
   # https://github.com/NixOS/nixpkgs/issues/146131
-  prePatch = lib.optionalString stdenv.isDarwin ''
+  postPatch = lib.optionalString stdenv.isDarwin ''
     substituteInPlace configure \
       --replace "-install_name libRblas.dylib" "-install_name $out/lib/R/lib/libRblas.dylib" \
       --replace "-install_name libRlapack.dylib" "-install_name $out/lib/R/lib/libRlapack.dylib" \

pkgs/applications/video/makemkv/default.nix

···
 , fetchurl
 , autoPatchelfHook
 , pkg-config
+, curl
 , ffmpeg
 , openssl
 , qtbase
···
   nativeBuildInputs = [ autoPatchelfHook pkg-config ];
 
   buildInputs = [ ffmpeg openssl qtbase zlib ];
+
+  runtimeDependencies = [ (lib.getLib curl) ];
 
   qtWrapperArgs =
     let

pkgs/development/interpreters/racket/racket_7_9.nix

···
+{ lib, stdenv, fetchurl, makeFontsConf
+, cacert
+, cairo, coreutils, fontconfig, freefont_ttf
+, glib, gmp
+, gtk3
+, libedit, libffi
+, libiconv
+, libGL
+, libGLU
+, libjpeg
+, libpng, libtool, mpfr, openssl, pango, poppler
+, readline, sqlite
+, disableDocs ? false
+, CoreFoundation
+, gsettings-desktop-schemas
+, wrapGAppsHook
+}:
+
+let
+
+  fontsConf = makeFontsConf {
+    fontDirectories = [ freefont_ttf ];
+  };
+
+  libPath = lib.makeLibraryPath [
+    cairo
+    fontconfig
+    glib
+    gmp
+    gtk3
+    gsettings-desktop-schemas
+    libedit
+    libGL
+    libGLU
+    libjpeg
+    libpng
+    mpfr
+    openssl
+    pango
+    poppler
+    readline
+    sqlite
+  ];
+
+in
+
+stdenv.mkDerivation rec {
+  pname = "racket";
+  version = "7.9"; # always change at once with ./minimal.nix
+
+  src = (lib.makeOverridable ({ name, sha256 }:
+    fetchurl {
+      url = "https://mirror.racket-lang.org/installers/${version}/${name}-src.tgz";
+      inherit sha256;
+    }
+  )) {
+    name = "${pname}-${version}";
+    sha256 = "0gmp2ahmfd97nn9bwpfx9lznjmjkd042slnrrbdmyh59cqh98y2m";
+  };
+
+  FONTCONFIG_FILE = fontsConf;
+  LD_LIBRARY_PATH = libPath;
+  NIX_LDFLAGS = lib.concatStringsSep " " [
+    (lib.optionalString (stdenv.cc.isGNU && ! stdenv.isDarwin) "-lgcc_s")
+    (lib.optionalString stdenv.isDarwin "-framework CoreFoundation")
+  ];
+
+  nativeBuildInputs = [ cacert wrapGAppsHook ];
+
+  buildInputs = [ fontconfig libffi libtool sqlite gsettings-desktop-schemas gtk3 ]
+    ++ lib.optionals stdenv.isDarwin [ libiconv CoreFoundation ];
+
+  preConfigure = ''
+    unset AR
+    for f in src/lt/configure src/cs/c/configure src/bc/src/string.c; do
+      substituteInPlace "$f" --replace /usr/bin/uname ${coreutils}/bin/uname
+    done
+    mkdir src/build
+    cd src/build
+
+    gappsWrapperArgs+=("--prefix" "LD_LIBRARY_PATH" ":" ${LD_LIBRARY_PATH})
+  '';
+
+  shared = if stdenv.isDarwin then "dylib" else "shared";
+  configureFlags = [ "--enable-${shared}"  "--enable-lt=${libtool}/bin/libtool" ]
+                   ++ lib.optional disableDocs [ "--disable-docs" ]
+                   ++ lib.optional stdenv.isDarwin [ "--enable-xonx" ];
+
+  configureScript = "../configure";
+
+  enableParallelBuilding = false;
+
+
+  meta = with lib; {
+    description = "A programmable programming language";
+    longDescription = ''
+      Racket is a full-spectrum programming language. It goes beyond
+      Lisp and Scheme with dialects that support objects, types,
+      laziness, and more. Racket enables programmers to link
+      components written in different dialects, and it empowers
+      programmers to create new, project-specific dialects. Racket's
+      libraries support applications from web servers and databases to
+      GUIs and charts.
+    '';
+    homepage = "https://racket-lang.org/";
+    license = with licenses; [ asl20 /* or */ mit ];
+    maintainers = with maintainers; [ kkallio henrytill vrthra ];
+    platforms = [ "x86_64-darwin" "x86_64-linux" "aarch64-linux" ];
+    broken = stdenv.isDarwin; # No support yet for setting FFI lookup path
+  };
+}

pkgs/development/libraries/isl/0.11.1.nix

···
-{ lib, stdenv, fetchurl, gmp }:
-
-stdenv.mkDerivation {
-  name = "isl-0.11.1"; # CLooG 0.16.3 fails to build with ISL 0.08.
-
-  src = fetchurl {
-    url = "https://src.fedoraproject.org/repo/pkgs/gcc/isl-0.11.1.tar.bz2/bce1586384d8635a76d2f017fb067cd2/isl-0.11.1.tar.bz2";
-    sha256 = "13d9cqa5rzhbjq0xf0b2dyxag7pqa72xj9dhsa03m8ccr1a4npq9";
-  };
-
-  buildInputs = [ gmp ];
+import ./generic.nix {
+  version = "0.11.1";
+  urls = [
+    "https://src.fedoraproject.org/repo/pkgs/gcc/isl-0.11.1.tar.bz2/bce1586384d8635a76d2f017fb067cd2/isl-0.11.1.tar.bz2"
+  ];
+  sha256 = "13d9cqa5rzhbjq0xf0b2dyxag7pqa72xj9dhsa03m8ccr1a4npq9";
   patches = [ ./fix-gcc-build.diff ];
-
-  enableParallelBuilding = true;
-
-  meta = {
-    homepage = "https://www.kotnet.org/~skimo/isl/";
-    license = lib.licenses.lgpl21;
-    description = "A library for manipulating sets and relations of integer points bounded by linear constraints";
-    platforms = lib.platforms.all;
-  };
 }

pkgs/development/libraries/isl/0.14.1.nix

···
-{ lib, stdenv, fetchurl, gmp }:
-
-stdenv.mkDerivation rec {
-  name = "isl-0.14.1";
-
-  src = fetchurl {
-    urls = [
-      "mirror://sourceforge/libisl/${name}.tar.xz"
-      "https://libisl.sourceforge.io/${name}.tar.xz"
-    ];
-    sha256 = "0xa6xagah5rywkywn19rzvbvhfvkmylhcxr6z9z7bz29cpiwk0l8";
-  };
-
-  buildInputs = [ gmp ];
-
-  enableParallelBuilding = true;
-
-  meta = {
-    homepage = "https://www.kotnet.org/~skimo/isl/";
-    license = lib.licenses.lgpl21;
-    description = "A library for manipulating sets and relations of integer points bounded by linear constraints";
-    platforms = lib.platforms.all;
-  };
+import ./generic.nix rec {
+  version = "0.14.1";
+  urls = [
+    "mirror://sourceforge/libisl/isl-${version}.tar.xz"
+    "https://libisl.sourceforge.io/isl-${version}.tar.xz"
+  ];
+  sha256 = "0xa6xagah5rywkywn19rzvbvhfvkmylhcxr6z9z7bz29cpiwk0l8";
 }

pkgs/development/libraries/isl/0.17.1.nix

···
-{ lib, stdenv, fetchurl, gmp }:
-
-stdenv.mkDerivation rec {
-  name = "isl-0.17.1";
-
-  src = fetchurl {
-    urls = [
-      "mirror://sourceforge/libisl/${name}.tar.xz"
-      "https://libisl.sourceforge.io/${name}.tar.xz"
-    ];
-    sha256 = "be152e5c816b477594f4c6194b5666d8129f3a27702756ae9ff60346a8731647";
-  };
-
-  buildInputs = [ gmp ];
-
-  enableParallelBuilding = true;
-
-  meta = {
-    homepage = "https://www.kotnet.org/~skimo/isl/";
-    license = lib.licenses.lgpl21;
-    description = "A library for manipulating sets and relations of integer points bounded by linear constraints";
-    platforms = lib.platforms.all;
-  };
+import ./generic.nix rec {
+  version = "0.17.1";
+  urls = [
+    "mirror://sourceforge/libisl/isl-${version}.tar.xz"
+    "https://libisl.sourceforge.io/isl-${version}.tar.xz"
+  ];
+  sha256 = "be152e5c816b477594f4c6194b5666d8129f3a27702756ae9ff60346a8731647";
 }

pkgs/development/libraries/isl/0.20.0.nix

···
-{ lib, stdenv, fetchurl, gmp }:
-
-stdenv.mkDerivation rec {
-  name = "isl-0.20";
-
-  src = fetchurl {
-    urls = [
-      "mirror://sourceforge/libisl/${name}.tar.xz"
-      "https://libisl.sourceforge.io/${name}.tar.xz"
-    ];
-
-    sha256 = "1akpgq0rbqbah5517blg2zlnfvjxfcl9cjrfc75nbcx5p2gnlnd5";
-  };
-
-  buildInputs = [ gmp ];
-
+import ./generic.nix rec {
+  version = "0.20";
+  urls = [
+    "mirror://sourceforge/libisl/isl-${version}.tar.xz"
+    "https://libisl.sourceforge.io/isl-${version}.tar.xz"
+  ];
+  sha256 = "1akpgq0rbqbah5517blg2zlnfvjxfcl9cjrfc75nbcx5p2gnlnd5";
   configureFlags = [
     "--with-gcc-arch=generic" # don't guess -march=/mtune=
   ];
-
-  enableParallelBuilding = true;
-
-  meta = {
-    homepage = "http://isl.gforge.inria.fr/";
-    license = lib.licenses.lgpl21;
-    description = "A library for manipulating sets and relations of integer points bounded by linear constraints";
-    platforms = lib.platforms.all;
-  };
 }

pkgs/development/libraries/isl/0.24.0.nix

···
+import ./generic.nix rec {
+  version = "0.24";
+  urls = [
+    "mirror://sourceforge/libisl/isl-${version}.tar.xz"
+    "https://libisl.sourceforge.io/isl-${version}.tar.xz"
+  ];
+  sha256 = "1bgbk6n93qqn7w8v21kxf4x6dc3z0ypqrzvgfd46nhagak60ac84";
+  configureFlags = [
+    "--with-gcc-arch=generic" # don't guess -march=/mtune=
+  ];
+}

pkgs/development/libraries/isl/generic.nix

···
+{ version
+, urls
+, sha256
+, configureFlags ? []
+, patches ? []
+}:
+
+{ lib, stdenv, fetchurl, gmp
+}:
+
+stdenv.mkDerivation {
+  name = "isl-${version}";
+
+  src = fetchurl {
+    inherit urls sha256;
+  };
+
+  inherit patches;
+
+  buildInputs = [ gmp ];
+
+  inherit configureFlags;
+
+  enableParallelBuilding = true;
+
+  meta = {
+    homepage = "https://libisl.sourceforge.io/";
+    license = lib.licenses.lgpl21;
+    description = "A library for manipulating sets and relations of integer points bounded by linear constraints";
+    platforms = lib.platforms.all;
+  };
+}

pkgs/development/libraries/java/gwt-dragdrop/builder.sh

···
-source $stdenv/setup
-
-mkdir -p $out/share/java
-cp $src $out/share/java/$name.jar

pkgs/development/libraries/java/gwt-dragdrop/default.nix

···
-{lib, stdenv, fetchurl}:
+{ lib, stdenv, fetchurl }:
 
-stdenv.mkDerivation {
-  name = "gwt-dnd-2.6.5";
-  builder = ./builder.sh;
+stdenv.mkDerivation rec {
+  pname = "gwt-dnd";
+  version = "2.6.5";
 
   src = fetchurl {
-    url = "http://gwt-dnd.googlecode.com/files/gwt-dnd-2.6.5.jar";
+    url = "http://gwt-dnd.googlecode.com/files/gwt-dnd-${version}.jar";
     sha256 = "07zdlr8afs499asnw0dcjmw1cnjc646v91lflx5dv4qj374c97fw";
   };
+
+  dontUnpack = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/share/java
+    cp $src $out/share/java/$name.jar
+
+    runHook postInstall
+  '';
 
   meta = with lib; {
     platforms = platforms.unix;

pkgs/development/libraries/java/gwt-widgets/builder.sh

···
-source $stdenv/setup
-
-tar xfvz $src
-cd gwt-widgets-*
-mkdir -p $out/share/java
-cp gwt-widgets-*.jar $out/share/java

pkgs/development/libraries/java/gwt-widgets/default.nix

···
-{lib, stdenv, fetchurl}:
+{ lib, stdenv, fetchurl }:
 
-stdenv.mkDerivation {
-  name = "gwt-widgets-0.2.0";
-  builder = ./builder.sh;
+stdenv.mkDerivation rec {
+  pname = "gwt-widgets";
+  version = "0.2.0";
 
   src = fetchurl {
-    url = "mirror://sourceforge/gwt-widget/gwt-widgets-0.2.0-bin.tar.gz";
+    url = "mirror://sourceforge/gwt-widget/gwt-widgets-${version}-bin.tar.gz";
     sha256 = "09isj4j6842rj13nv8264irkjjhvmgihmi170ciabc98911bakxb";
   };
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/share/java
+    cp gwt-widgets-*.jar $out/share/java
+
+    runHook postInstall
+  '';
 
   meta = with lib; {
     platforms = platforms.unix;

pkgs/servers/rippled/default.nix

···
   };
 in stdenv.mkDerivation rec {
   pname = "rippled";
-  version = "1.7.0";
+  version = "1.7.3";
 
   src = fetchgit {
     url = "https://github.com/ripple/rippled.git";
     rev = version;
-    sha256 = "1rr5kxks9hsxyxrz90dw259b6fs9lywdlqv0bj2g21a6f7g60v2v";
+    sha256 = "008qzb138r2pi0cqj4d6d5f0grlb2gm87m8j0dj8b0giya22xv6s";
     leaveDotGit = true;
     fetchSubmodules = true;
   };

pkgs/tools/security/fprintd/tod.nix

···
+{ fetchFromGitLab
+, fprintd
+, libfprint-tod
+}:
+
+(fprintd.override { libfprint = libfprint-tod; }).overrideAttrs (oldAttrs:
+  let
+    pname = "fprintd-tod";
+    version = "1.90.9";
+  in
+  {
+    inherit pname version;
+
+    src = fetchFromGitLab {
+      domain = "gitlab.freedesktop.org";
+      owner = "libfprint";
+      repo = "${oldAttrs.pname}";
+      rev = "v${version}";
+      sha256 = "sha256-rOTVThHOY/Q2IIu2RGiv26UE2V/JFfWWnfKZQfKl5Mg=";
+    };
+  })

pkgs/top-level/all-packages.nix

···
 
   fprintd = callPackage ../tools/security/fprintd { };
 
-  fprintd-tod = callPackage ../tools/security/fprintd {
-    libfprint = libfprint-tod;
-  };
+  fprintd-tod = callPackage ../tools/security/fprintd/tod.nix { };
 
   ferdi = callPackage ../applications/networking/instant-messengers/ferdi {
     mkFranzDerivation = callPackage ../applications/networking/instant-messengers/franz/generic.nix { };
···
   isl_0_14 = callPackage ../development/libraries/isl/0.14.1.nix { };
   isl_0_17 = callPackage ../development/libraries/isl/0.17.1.nix { };
   isl_0_20 = callPackage ../development/libraries/isl/0.20.0.nix { };
+  isl_0_24 = callPackage ../development/libraries/isl/0.24.0.nix { };
 
   ispike = callPackage ../development/libraries/science/robotics/ispike { };
 
···
     # racket 6.11 doesn't build with gcc6 + recent glibc:
     # https://github.com/racket/racket/pull/1886
     # https://github.com/NixOS/nixpkgs/pull/31017#issuecomment-343574769
+    stdenv = if stdenv.isDarwin then stdenv else gcc7Stdenv;
+    inherit (darwin.apple_sdk.frameworks) CoreFoundation;
+  };
+  racket_7_9 = callPackage ../development/interpreters/racket/racket_7_9.nix {
     stdenv = if stdenv.isDarwin then stdenv else gcc7Stdenv;
     inherit (darwin.apple_sdk.frameworks) CoreFoundation;
   };