xbitmaps: refactor and move to pkgs/by-name from xorg namespace

pkgs/by-name/xb/xbitmaps/package.nix

···
+{
+  lib,
+  stdenv,
+  fetchurl,
+  pkg-config,
+  testers,
+  writeScript,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "xbitmaps";
+  version = "1.1.3";
+
+  src = fetchurl {
+    url = "mirror://xorg/individual/data/xbitmaps-${finalAttrs.version}.tar.xz";
+    hash = "sha256-rWytVIh4MqF9hsLM/F5Sod+rCQ+DB7FSx4sOFSnND3o=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs = [ pkg-config ];
+
+  passthru = {
+    tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+    updateScript = writeScript "update-${finalAttrs.pname}" ''
+      #!/usr/bin/env nix-shell
+      #!nix-shell -i bash -p common-updater-scripts
+      version="$(list-directory-versions --pname ${finalAttrs.pname} \
+        --url https://xorg.freedesktop.org/releases/individual/data/ \
+        | sort -V | tail -n1)"
+      update-source-version ${finalAttrs.pname} "$version"
+    '';
+  };
+
+  meta = {
+    homepage = "https://gitlab.freedesktop.org/xorg/data/bitmaps";
+    description = "X BitMap (XBM) format bitmaps commonly used in X.Org applications";
+    license = with lib.licenses; [
+      icu
+      smlnj
+    ];
+    maintainers = [ ];
+    pkgConfigModules = [ "xbitmaps" ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/servers/x11/xorg/default.nix

···
   makedepend,
   pixman,
   util-macros,
+  xbitmaps,
 }:
 
 self: with self; {
···
     luit
     makedepend
     pixman
+    xbitmaps
     ;
   fontalias = font-alias;
   fontutil = font-util;
···
       passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
       meta = {
         pkgConfigModules = [ ];
-        platforms = lib.platforms.unix;
-      };
-    })
-  ) { };
-
-  # THIS IS A GENERATED FILE.  DO NOT EDIT!
-  xbitmaps = callPackage (
-    {
-      stdenv,
-      pkg-config,
-      fetchurl,
-      testers,
-    }:
-    stdenv.mkDerivation (finalAttrs: {
-      pname = "xbitmaps";
-      version = "1.1.3";
-      builder = ./builder.sh;
-      src = fetchurl {
-        url = "mirror://xorg/individual/data/xbitmaps-1.1.3.tar.xz";
-        sha256 = "0yhgrllia3lbqx9b21w31w4sppx1a9ggrk62hrys2ckqi1aasv5d";
-      };
-      hardeningDisable = [
-        "bindnow"
-        "relro"
-      ];
-      strictDeps = true;
-      nativeBuildInputs = [ pkg-config ];
-      buildInputs = [ ];
-      passthru.tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
-      meta = {
-        pkgConfigModules = [ "xbitmaps" ];
         platforms = lib.platforms.unix;
       };
     })

pkgs/servers/x11/xorg/generate-expr-from-tarballs.pl

···
 $pcMap{"fontutil"} = "fontutil";
 $pcMap{"pciaccess"} = "libpciaccess";
 $pcMap{"pthread-stubs"} = "libpthreadstubs";
+$pcMap{"xbitmaps"} = "xbitmaps";
 $pcMap{"\$PIXMAN"} = "pixman";
 $pcMap{"\$RENDERPROTO"} = "xorgproto";
 $pcMap{"\$DRI3PROTO"} = "xorgproto";
···
   makedepend,
   pixman,
   util-macros,
+  xbitmaps,
 }:
 
 self: with self; {
···
     luit
     makedepend
     pixman
+    xbitmaps
     ;
   fontalias = font-alias;
   fontutil = font-util;

pkgs/servers/x11/xorg/tarballs.list

···
 mirror://xorg/individual/app/xwd-1.0.9.tar.xz
 mirror://xorg/individual/app/xwininfo-1.1.6.tar.xz
 mirror://xorg/individual/app/xwud-1.0.7.tar.xz
-mirror://xorg/individual/data/xbitmaps-1.1.3.tar.xz
 mirror://xorg/individual/data/xcursor-themes-1.0.7.tar.xz
 mirror://xorg/individual/data/xkeyboard-config/xkeyboard-config-2.44.tar.xz
 mirror://xorg/individual/doc/xorg-docs-1.7.3.tar.xz