python3Packages.langchain-google-genai: init at 2.1.5 (#416029)

maintainers/maintainer-list.nix

···
     name = "Elis Hirwing";
     keys = [ { fingerprint = "67FE 98F2 8C44 CF22 1828  E12F D57E FA62 5C9A 925F"; } ];
   };
+  eu90h = {
+    email = "[e-mail]";
+    github = "eu90h";
+    githubId = 5161785;
+    name = "Stefan";
+  };
   euank = {
     email = "[e-mail]";
     github = "euank";

pkgs/development/python-modules/langchain-google-genai/default.nix

···
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+
+  # build-system
+  poetry-core,
+
+  # dependencies
+  filetype,
+  google-api-core,
+  google-auth,
+  google-generativeai,
+  langchain-core,
+  pydantic,
+
+  # tests
+  freezegun,
+  langchain-tests,
+  numpy,
+  pytest-asyncio,
+  pytest-mock,
+  pytestCheckHook,
+  syrupy,
+
+  # passthru
+  gitUpdater,
+}:
+
+buildPythonPackage rec {
+  pname = "langchain-google-genai";
+  version = "2.1.5";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "langchain-ai";
+    repo = "langchain-google";
+    tag = "libs/genai/v${version}";
+    hash = "sha256-NCy4PHUSChsMVSebshDRGsg/koY7S4+mvI+GlIqW4q4=";
+  };
+
+  sourceRoot = "${src.name}/libs/genai";
+
+  build-system = [ poetry-core ];
+
+  pythonRelaxDeps = [
+    # Each component release requests the exact latest core.
+    # That prevents us from updating individual components.
+    "langchain-core"
+  ];
+
+  dependencies = [
+    filetype
+    google-api-core
+    google-auth
+    google-generativeai
+    langchain-core
+    pydantic
+  ];
+
+  nativeCheckInputs = [
+    freezegun
+    langchain-tests
+    numpy
+    pytest-asyncio
+    pytest-mock
+    pytestCheckHook
+    syrupy
+  ];
+
+  pytestFlagsArray = [ "tests/unit_tests" ];
+
+  pythonImportsCheck = [ "langchain_google_genai" ];
+
+  passthru.updateScript = gitUpdater {
+    rev-prefix = "libs/genai/v";
+  };
+
+  meta = {
+    changelog = "https://github.com/langchain-ai/langchain-google/releases/tag/${src.tag}";
+    description = "LangChain integrations for Google Gemini";
+    homepage = "https://github.com/langchain-ai/langchain-google/tree/main/libs/genai";
+    license = lib.licenses.mit;
+    maintainers = [
+      lib.maintainers.eu90h
+      lib.maintainers.sarahec
+    ];
+  };
+}

pkgs/top-level/python-packages.nix

···
 
   langchain-fireworks = callPackage ../development/python-modules/langchain-fireworks { };
 
+  langchain-google-genai = callPackage ../development/python-modules/langchain-google-genai { };
+
   langchain-groq = callPackage ../development/python-modules/langchain-groq { };
 
   langchain-huggingface = callPackage ../development/python-modules/langchain-huggingface { };