online-judge-verify-helper: init at 5.6.0

pkgs/by-name/on/online-judge-verify-helper/package.nix

···
+{
+  python3Packages,
+}:
+python3Packages.toPythonApplication python3Packages.online-judge-verify-helper

pkgs/development/python-modules/online-judge-verify-helper/default.nix

···
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  pythonOlder,
+
+  colorlog,
+  importlab,
+  online-judge-tools,
+  pyyaml,
+  setuptools,
+  toml,
+
+  pytestCheckHook,
+}:
+
+buildPythonPackage rec {
+  pname = "online-judge-verify-helper";
+  version = "5.6.0";
+  pyproject = true;
+  disabled = pythonOlder "3.12";
+
+  src = fetchFromGitHub {
+    owner = "online-judge-tools";
+    repo = "verification-helper";
+    tag = "v${version}";
+    hash = "sha256-sBR9/rf8vpDRbRD8HO2VNmxVckXPmPjUih7ogLRFaW8=";
+  };
+
+  build-system = [ setuptools ];
+
+  dependencies = [
+    colorlog
+    importlab
+    online-judge-tools
+    pyyaml
+    setuptools
+    toml
+  ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+  ];
+
+  # No additional dependencies or network access
+  disabledTestPaths = [
+    "tests/test_docs.py"
+    "tests/test_python.py"
+    "tests/test_rust.py"
+    "tests/test_stats.py"
+    "tests/test_verify.py"
+  ];
+
+  pythonImportsCheck = [
+    "onlinejudge"
+    "onlinejudge_bundle"
+    "onlinejudge_verify"
+    "onlinejudge_verify_resources"
+  ];
+
+  meta = {
+    description = "Testing framework for snippet libraries used in competitive programming";
+    mainProgram = "oj-verify";
+    homepage = "https://github.com/online-judge-tools/verification-helper";
+    changelog = "https://github.com/online-judge-tools/verification-helper/releases/tag/v${version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ toyboot4e ];
+  };
+}

pkgs/top-level/python-packages.nix

···
 
   online-judge-tools = callPackage ../development/python-modules/online-judge-tools { };
 
+  online-judge-verify-helper =
+    callPackage ../development/python-modules/online-judge-verify-helper
+      { };
+
   onlykey-solo-python = callPackage ../development/python-modules/onlykey-solo-python { };
 
   onnx = callPackage ../development/python-modules/onnx { };