llm-gemini: init at 0.15 (#390715)

pkgs/development/python-modules/llm-gemini/default.nix

···
+{
+  lib,
+  callPackage,
+  buildPythonPackage,
+  fetchFromGitHub,
+  setuptools,
+  llm,
+  httpx,
+  ijson,
+  pytestCheckHook,
+  pytest-recording,
+  pytest-asyncio,
+  nest-asyncio,
+  writableTmpDirAsHomeHook,
+}:
+buildPythonPackage rec {
+  pname = "llm-gemini";
+  version = "0.15";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "simonw";
+    repo = "llm-gemini";
+    tag = version;
+    hash = "sha256-NNzorEb3dVoKef+9eXzStcFAkQhnhMBVnwLBc2lA2+o=";
+  };
+
+  build-system = [
+    setuptools
+  ];
+
+  dependencies = [
+    llm
+    httpx
+    ijson
+  ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+    pytest-recording
+    pytest-asyncio
+    nest-asyncio
+    writableTmpDirAsHomeHook
+  ];
+
+  pythonImportsCheck = [ "llm_gemini" ];
+
+  passthru.tests = {
+    llm-plugin = callPackage ./tests/llm-plugin.nix { };
+  };
+
+  meta = {
+    description = "LLM plugin to access Google's Gemini family of models";
+    homepage = "https://github.com/simonw/llm-gemini";
+    changelog = "https://github.com/simonw/llm-gemini/releases/tag/${version}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ josh ];
+  };
+}

pkgs/development/python-modules/llm-gemini/tests/llm-plugin.nix

···
+{
+  runCommand,
+  python,
+  yq,
+}:
+let
+  venv = python.withPackages (ps: [
+    ps.llm
+    ps.llm-gemini
+  ]);
+in
+runCommand "llm-gemini-test-llm-plugin"
+  {
+    nativeBuildInputs = [
+      venv
+      yq
+    ];
+  }
+  ''
+    llm plugins | yq --exit-status 'any(.name == "llm-gemini")'
+    touch "$out"
+  ''

pkgs/top-level/python-packages.nix

···
 
   llm-cmd = callPackage ../development/python-modules/llm-cmd { };
 
+  llm-gemini = callPackage ../development/python-modules/llm-gemini { };
+
   llm-gguf = callPackage ../development/python-modules/llm-gguf { };
 
   llm-jq = callPackage ../development/python-modules/llm-jq { };