Add amdapp-sdk: accelerated parallel processing sdk with OpenCL support

pkgs/development/misc/amdapp-sdk/01-remove-aparapi-samples.patch

···
+--- samples/Makefile	2012-11-29 05:58:48.000000000 +0100
++++ samples/Makefile	2012-12-30 20:13:30.926576277 +0100
+@@ -3,7 +3,6 @@
+ include $(DEPTH)/make/openclsdkdefs.mk 
+ 
+ SUBDIRS = opencl 
+-SUBDIRS += aparapi 
+ ifneq ($(OS), lnx)
+ SUBDIRS += C++Amp
+ ifeq ($(BITS), 64)

pkgs/development/misc/amdapp-sdk/default.nix

···
+{ stdenv, fetchurl, makeWrapper, perl, mesa, xorg,
+  version? "2.8", # What version
+  samples? false # Should samples be installed
+}:
+
+let
+
+  src_hashes = {
+    "2.6" = {
+      x86 = "99610737f21b2f035e0eac4c9e776446cc4378a614c7667de03a82904ab2d356";
+      x86_64 = "1fj55358s4blxq9bp77k07gqi22n5nfkzwjkbdc62gmy1zxxlhih";
+    };
+
+    "2.7" = {
+      x86 = "99610737f21b2f035e0eac4c9e776446cc4378a614c7667de03a82904ab2d356";
+      x86_64 = "08bi43bgnsxb47vbirh09qy02w7zxymqlqr8iikk9aavfxjlmch1";
+    };
+
+    "2.8" = {
+      x86 = "99610737f21b2f035e0eac4c9e776446cc4378a614c7667de03a82904ab2d356";
+      x86_64 = "d9c120367225bb1cd21abbcf77cb0a69cfb4bb6932d0572990104c566aab9681";
+    };
+  };
+
+  bits = if stdenv.system == "x86_64-linux" then "64"
+         else "32";
+
+  arch = if stdenv.system == "x86_64-linux" then "x86_64"
+         else "x86";
+
+in stdenv.mkDerivation rec {
+  name = "amdapp-sdk-${version}";
+
+  src = if stdenv.system == "x86_64-linux" then fetchurl {
+    url = "http://developer.amd.com/wordpress/media/2012/11/AMD-APP-SDK-v${version}-lnx64.tgz";
+    sha256 = (builtins.getAttr version src_hashes).x86_64;
+  } else if stdenv.system == "i686-linux" then fetchurl {
+    url = "http://developer.amd.com/wordpress/media/2012/11/AMD-APP-SDK-v${version}-lnx32.tgz";
+    sha256 = (builtins.getAttr version src_hashes).x86;
+  } else
+    throw "System not supported";
+
+  # TODO: Add support for aparapi, java parallel api
+  patches = [ ./01-remove-aparapi-samples.patch ];
+
+  patchFlags = "-p0";
+  buildInputs = [ makeWrapper perl mesa xorg.libX11 xorg.libXext xorg.libXaw xorg.libXi xorg.libXxf86vm ];
+  propagatedBuildInputs = [ stdenv.gcc ];
+  NIX_LDFLAGS = "-lX11 -lXext -lXmu -lXi -lXxf86vm";
+  doCheck = false;
+
+  unpackPhase = ''
+    tar xvzf $src
+    tar xf AMD-APP-SDK-v${version}-RC-lnx${bits}.tgz
+    cd AMD-APP-SDK-v${version}-RC-lnx${bits}
+  '';
+
+  buildPhase = if !samples then ''echo "nothing to build"'' else null;
+
+  installPhase = ''
+    # Install SDK
+    mkdir -p $out
+    cp -r {docs,include} "$out/"
+    mkdir -p "$out/"{bin,lib,samples/opencl/bin}
+    cp -r "./bin/${arch}/clinfo" "$out/bin/clinfo"
+    cp -r "./lib/${arch}/"* "$out/lib/"
+
+    # Register ICD
+    mkdir -p "$out/etc/OpenCL/vendors"
+    echo "$out/lib/libamdocl${bits}.so" > "$out/etc/OpenCL/vendors/amd.icd"
+    # The OpenCL ICD specifications: http://www.khronos.org/registry/cl/extensions/khr/cl_khr_icd.txt
+
+    # Install includes
+    mkdir -p "$out/usr/include/"{CAL,OpenVideo}
+    install -m644 './include/OpenVideo/'{OVDecode.h,OVDecodeTypes.h} "$out/usr/include/OpenVideo/"
+
+    ${ if samples then ''
+      # Install samples
+      find ./samples/opencl/ -mindepth 1 -maxdepth 1 -type d -not -name bin -exec cp -r {} "$out/samples/opencl" \;
+      cp -r "./samples/opencl/bin/${arch}/"* "$out/samples/opencl/bin"
+      for f in $(find "$out/samples/opencl/bin/" -type f -not -name "*.*");
+      do
+        wrapProgram "$f" --prefix PATH ":" "${stdenv.gcc}/bin"
+      done'' else ""
+    }
+
+    # Create wrappers
+    patchelf --set-interpreter "$(cat $NIX_GCC/nix-support/dynamic-linker)" $out/bin/clinfo
+    patchelf --set-rpath ${stdenv.gcc.gcc}/lib64:${stdenv.gcc.gcc}/lib $out/bin/clinfo
+
+    # Fix modes
+    find "$out/" -type f -exec chmod 644 {} \;
+    chmod -R 755 "$out/bin/"
+    find "$out/samples/opencl/bin/" -type f -name ".*" -exec chmod 755 {} \;
+    find "$out/samples/opencl/bin/" -type f -not -name "*.*" -exec chmod 755 {} \;
+  '';
+
+  meta = with stdenv.lib; {
+    description = "AMD Accelerated Parallel Processing (APP) SDK, with OpenCL 1.2 support";
+    homepage = http://developer.amd.com/tools/heterogeneous-computing/amd-accelerated-parallel-processing-app-sdk/;
+    license = licenses.amd;
+    maintainers = [ maintainers.offline ];
+    platforms = [ "i686-linux" "x86_64-linux" ];
+ };
+}

pkgs/lib/licenses.nix

···
     url = https://www.gnu.org/licenses/agpl.html;
   };
 
+  amd = {
+    shortName = "amd";
+    fullName = "AMD License Agreement";
+    url = "http://developer.amd.com/amd-license-agreement/";
+  };
+
   asl20 = {
     shortName = "ASL2.0";
     fullName = "Apache Software License 2.0";

pkgs/top-level/all-packages.nix

···
 
   ### DEVELOPMENT / MISC
 
+  amdappsdk26 = callPackage ../development/misc/amdapp-sdk {
+    version = "2.6";
+  };
+
+  amdappsdk27 = callPackage ../development/misc/amdapp-sdk {
+    version = "2.7";
+  };
+
+  amdappsdk28 = callPackage ../development/misc/amdapp-sdk {
+    version = "2.8";
+  };
+
+  amdappsdk = amdappsdk28;
+
+  amdappsdkFull = callPackage ../development/misc/amdapp-sdk {
+    version = "2.8";
+    samples = true;
+  };
+
   avrgcclibc = callPackage ../development/misc/avr-gcc-with-avr-libc {};
 
   avr8burnomat = callPackage ../development/misc/avr8-burn-omat { };