pdfposter: move out of python-modules

pdfposter is primarily designed as a CLI application

pkgs/applications/misc/pdfposter/default.nix

···
+{ lib, python3, fetchPypi }:
+let
+  localPython = python3.override {
+    self = localPython;
+    packageOverrides = self: super: {
+      # Can be removed once this is merged
+      # https://gitlab.com/pdftools/pdfposter/-/merge_requests/7
+      pypdf2 = super.pypdf2.overridePythonAttrs (oldAttrs: rec {
+        version = "2.11.1";
+        format = "setuptools";
+        src = fetchPypi {
+          pname = "PyPDF2";
+          inherit version;
+          hash = "sha256-PHut1RLCFxHrF4nC6tv5YnkonA+URS7lSoZHO/vv1zI=";
+        };
+      });
+    };
+  };
+in
+with localPython.pkgs; buildPythonApplication rec {
+  pname = "pdfposter";
+  version = "0.8.1";
+  format = "setuptools";
+
+  propagatedBuildInputs = [ pypdf2 ];
+
+  src = fetchPypi {
+    pname = "pdftools.pdfposter";
+    inherit version;
+    hash = "sha256-yWFtHgVKAWs4dRlSk8t8cB2KBJeBOa0Frh3BLR9txS0=";
+  };
+
+  pythonImportsCheck = [
+    "pdftools.pdfposter"
+    "pdftools.pdfposter.cmd"
+  ];
+
+  meta = with lib; {
+    description = "Split large pages of a PDF into smaller ones for poster printing";
+    homepage = "https://pdfposter.readthedocs.io";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ wamserma ];
+  };
+}

pkgs/development/python-modules/pdfposter/default.nix

···
-{ lib, buildPythonPackage, fetchPypi, pypdf2 }:
-
-buildPythonPackage rec {
-  pname = "pdftools.pdfposter";
-  version = "0.8.1";
-  format = "setuptools";
-
-  propagatedBuildInputs = [ pypdf2 ];
-
-  src = fetchPypi {
-    inherit pname version;
-    hash = "sha256-yWFtHgVKAWs4dRlSk8t8cB2KBJeBOa0Frh3BLR9txS0=";
-  };
-
-  pythonImportsCheck = [
-    "pdftools.pdfposter"
-    "pdftools.pdfposter.cmd"
-  ];
-
-  meta = with lib; {
-    description = "Split large pages of a PDF into smaller ones for poster printing";
-    homepage = "https://pdfposter.readthedocs.io";
-    license = licenses.gpl3Plus;
-    maintainers = with maintainers; [ wamserma ];
-  };
-}

pkgs/top-level/all-packages.nix

···
 
   pdfcrack = callPackage ../tools/security/pdfcrack { };
 
+  pdfposter = callPackage ../applications/misc/pdfposter { };
+
   pdfsandwich = callPackage ../tools/typesetting/pdfsandwich { };
 
   pdftag = callPackage ../tools/graphics/pdftag { };

pkgs/top-level/python-aliases.nix

···
   pam = python-pam; # added 2020-09-07.
   PasteDeploy = pastedeploy; # added 2021-10-07
   pathpy = path; # added 2022-04-12
+  pdfposter = throw "pdfposter was promoted to a top-level attribute"; # Added 2023-06-29
   pdfminer = pdfminer-six; # added 2022-05-25
   pep257 = pydocstyle; # added 2022-04-12
   poetry = throw "poetry was promoted to a top-level attribute, use poetry-core to build Python packages"; # added 2023-01-09

pkgs/top-level/python-packages.nix

···
 
   pdfminer-six = callPackage ../development/python-modules/pdfminer-six { };
 
-  pdfposter = callPackage ../development/python-modules/pdfposter { };
-
   pdfrw = callPackage ../development/python-modules/pdfrw { };
 
   pdftotext = callPackage ../development/python-modules/pdftotext { };