Merge pull request #192649 from ners/apacheds

maintainers/maintainer-list.nix

···
     githubId = 23743547;
     name = "Akshay Oppiliappan";
   };
+  ners = {
+    name = "ners";
+    email = "[e-mail]";
+    matrix = "@ners:ners.ch";
+    github = "ners";
+    githubId = 50560955;
+  };
   nessdoor = {
     name = "Tomas Antonio Lopez";
     email = "[e-mail]";

pkgs/servers/apache-directory-server/default.nix

···
+{ lib, stdenv, fetchzip, jdk11, makeWrapper }:
+
+stdenv.mkDerivation rec {
+  pname = "apache-directory-server";
+  version = "2.0.0.AM26";
+
+  src = fetchzip {
+    url = "https://dlcdn.apache.org//directory/apacheds/dist/${version}/apacheds-${version}.zip";
+    sha256 = "sha256-36kDvfSy5rt/3+nivEFTepnIKf6sX0NTgPRm28M+1v4=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    mkdir -p $out/bin $out/share/apacheds
+    install -D $src/lib/*.jar $out/share/apacheds
+    classpath=$(jars=($out/share/apacheds/*.jar); IFS=:; echo "''${jars[*]}")
+    makeWrapper ${jdk11}/bin/java $out/bin/apache-directory-server \
+      --add-flags "-classpath $classpath org.apache.directory.server.UberjarMain"
+  '';
+
+  meta = with lib; {
+    description = "An extensible and embeddable directory server";
+    homepage = "https://directory.apache.org/apacheds/";
+    license = licenses.asl20;
+    platforms = platforms.unix;
+    maintainers = [ maintainers.ners ];
+  };
+}

pkgs/servers/nosql/janusgraph/default.nix

···
+{ lib, stdenv, fetchzip, jdk11, makeWrapper }:
+
+stdenv.mkDerivation rec {
+  pname = "janusgraph";
+  version = "0.6.2";
+
+  src = fetchzip {
+    url = "https://github.com/JanusGraph/janusgraph/releases/download/v${version}/janusgraph-${version}.zip";
+    sha256 = "sha256-8TMYk8gGyL71zcFk0Lgo7Isvm4k3eh/H6PjfVePpkI4=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    mkdir -p $out/bin $out/share/janusgraph
+    install -D $src/lib/*.jar $out/share/janusgraph
+    cd $src
+    find conf scripts -type f -exec install -D {} $out/share/janusgraph/{} \;
+
+    JANUSGRAPH_LIB=$out/share/janusgraph
+    classpath=""
+    # Add the slf4j-log4j12 binding
+    classpath="$classpath":$(find -L $JANUSGRAPH_LIB -name 'slf4j-log4j12*.jar' | sort | tr '\n' ':')
+    # Add the jars in $JANUSGRAPH_LIB that start with "janusgraph"
+    classpath="$classpath":$(find -L $JANUSGRAPH_LIB -name 'janusgraph*.jar' | sort | tr '\n' ':')
+    # Add the remaining jars in $JANUSGRAPH_LIB.
+    classpath="$classpath":$(find -L $JANUSGRAPH_LIB -name '*.jar' \
+                    \! -name 'janusgraph*' \
+                    \! -name 'slf4j-log4j12*.jar' | sort | tr '\n' ':')
+
+    makeWrapper ${jdk11}/bin/java $out/bin/janusgraph-server \
+      --add-flags "-classpath $classpath org.janusgraph.graphdb.server.JanusGraphServer"
+  '';
+
+  meta = with lib; {
+    description = "An open-source, distributed graph database";
+    homepage = "https://janusgraph.org/";
+    mainProgram = "janusgraph-server";
+    license = licenses.asl20;
+    platforms = platforms.unix;
+    maintainers = [ maintainers.ners ];
+  };
+}
+

pkgs/top-level/all-packages.nix

···
 
   janus-gateway = callPackage ../servers/janus-gateway { };
 
+  janusgraph = callPackage ../servers/nosql/janusgraph { };
+
   jboss = callPackage ../servers/http/jboss { };
 
   jboss_mysql_jdbc = callPackage ../servers/http/jboss/jdbc/mysql { };
···
   anytype = callPackage ../applications/misc/anytype { };
 
   ao = libfive;
+
+  apache-directory-server = callPackage ../servers/apache-directory-server {};
 
   apache-directory-studio = callPackage ../applications/networking/apache-directory-studio {};