Merge pull request #170259 from armeenm/bump-wmii

pkgs/applications/window-managers/wmii-hg/default.nix

···
-{ lib, stdenv, fetchurl, unzip, pkg-config, libixp_hg, txt2tags, dash, python2, which
-, libX11 , libXrender, libXext, libXinerama, libXrandr, libXft }:
-
-stdenv.mkDerivation rec {
-  rev = "2823";
-  version = "hg-2012-12-09";
-  pname = "wmii";
-
-  src = fetchurl {
-    url = "https://storage.googleapis.com/google-code-archive-source/v2/code.google.com/wmii/source-archive.zip";
-    sha256 = "1wmkq14zvmfrmydl8752xz852cy7agrx3qp4fy2cc5asb2r9abaz";
-  };
-
-  # for dlopen-ing
-  patchPhase = ''
-    substituteInPlace lib/libstuff/x11/xft.c --replace "libXft.so" "$(pkg-config --variable=libdir xft)/libXft.so.2"
-    substituteInPlace cmd/wmii.sh.sh --replace "\$(which which)" "${which}/bin/which"
-  '';
-
-  configurePhase = ''
-    for file in $(grep -lr '#!.*sh'); do
-      sed -i 's|#!.*sh|#!${dash}/bin/dash|' $file
-    done
-
-    cat <<EOF >> config.mk
-    PREFIX = $out
-    LIBIXP = ${libixp_hg}/lib/libixp.a
-    BINSH = ${dash}/bin/dash
-    EOF
-  '';
-
-  nativeBuildInputs = [ pkg-config unzip ];
-  buildInputs = [ libixp_hg txt2tags dash python2 which
-                  libX11 libXrender libXext libXinerama libXrandr libXft ];
-
-  # For some reason including mercurial in buildInputs did not help
-  makeFlags = [ "WMII_HGVERSION=hg${rev}" ];
-
-  meta = {
-    homepage = "https://suckless.org/"; # https://wmii.suckless.org/ does not exist anymore
-    description = "A small window manager controlled by a 9P filesystem";
-    maintainers = with lib.maintainers; [ kovirobi ];
-    license = lib.licenses.mit;
-    platforms = with lib.platforms; linux;
-  };
-}

pkgs/applications/window-managers/wmii/default.nix

···
+{ lib, stdenv
+, fetchFromGitHub
+, dash
+, libX11
+, libXext
+, libXft
+, libXinerama
+, libXrandr
+, libXrender
+, libixp
+, pkg-config
+, txt2tags
+, unzip
+, which
+}:
+
+stdenv.mkDerivation rec {
+  pname = "wmii";
+  version = "unstable-2022-04-04";
+
+  src = fetchFromGitHub {
+    owner = "0intro";
+    repo = "wmii";
+    rev = "ff120c7fee6e1b3a30a4a800074394327fb1da9d";
+    hash = "sha256-KEmWnobpT/5TdgT2HGPCpG1duz9Q6Z6PFSEBs2Ce+7g=";
+  };
+
+  # for dlopen-ing
+  postPatch = ''
+    substituteInPlace lib/libstuff/x11/xft.c --replace "libXft.so" "$(pkg-config --variable=libdir xft)/libXft.so.2"
+    substituteInPlace cmd/wmii.sh.sh --replace "\$(which which)" "${which}/bin/which"
+  '';
+
+  postConfigure = ''
+    for file in $(grep -lr '#!.*sh'); do
+      sed -i 's|#!.*sh|#!${dash}/bin/dash|' $file
+    done
+
+    cat <<EOF >> config.mk
+    PREFIX = $out
+    LIBIXP = ${libixp}/lib/libixp.a
+    BINSH = ${dash}/bin/dash
+    EOF
+  '';
+
+  # Remove optional python2 functionality
+  postInstall = ''
+    rm -rf $out/lib/python* $out/etc/wmii-hg/python
+  '';
+
+  nativeBuildInputs = [ pkg-config unzip ];
+  buildInputs = [
+    dash
+    libX11
+    libXext
+    libXft
+    libXinerama
+    libXrandr
+    libXrender
+    libixp
+    txt2tags
+    which
+  ];
+
+  meta = {
+    homepage = "https://github.com/0intro/wmii";
+    description = "A small, scriptable window manager, with a 9P filesystem interface and an acme-like layout";
+    maintainers = with lib.maintainers; [ kovirobi ];
+    license = lib.licenses.mit;
+    platforms = with lib.platforms; linux;
+  };
+}

pkgs/development/libraries/libixp-hg/default.nix

···
-{ lib, stdenv, fetchurl, unzip, txt2tags }:
-
-stdenv.mkDerivation rec {
-  rev = "148";
-  version = "hg-2012-12-02";
-  pname = "libixp";
-
-  src = fetchurl {
-    url = "https://storage.googleapis.com/google-code-archive-source/v2/code.google.com/libixp/source-archive.zip";
-    sha256 = "0kcdvdcrkw6q39v563ncis6d7ini64xbgn5fd3b4aa95fp9sj3is";
-  };
-
-  configurePhase = ''
-   sed -i -e "s|^PREFIX.*=.*$|PREFIX = $out|" config.mk
-  '';
-
-  nativeBuildInputs = [ unzip ];
-  buildInputs = [ txt2tags ];
-
-  meta = {
-    homepage = "http://repo.cat-v.org/libixp/"; # see also https://libs.suckless.org/deprecated/libixp
-    description = "Portable, simple C-language 9P client and server libary";
-    maintainers = with lib.maintainers; [ kovirobi ];
-    license = lib.licenses.mit;
-    platforms = with lib.platforms; unix;
-  };
-}

pkgs/development/libraries/libixp/default.nix

···
+{ lib, stdenv, fetchFromGitHub, unzip, txt2tags }:
+
+stdenv.mkDerivation rec {
+  pname = "libixp";
+  version = "unstable-2022-04-04";
+
+  src = fetchFromGitHub {
+    owner = "0intro";
+    repo = "libixp";
+    rev = "ca2acb2988e4f040022f0e2094c69ab65fa6ec53";
+    hash = "sha256-S25DmXJ7fN0gXLV0IzUdz8hXPTYEHmaSG7Mnli6GQVc=";
+  };
+
+  postConfigure = ''
+   sed -i -e "s|^PREFIX.*=.*$|PREFIX = $out|" config.mk
+  '';
+
+  nativeBuildInputs = [ unzip ];
+  buildInputs = [ txt2tags ];
+
+  meta = {
+    homepage = "https://github.com/0intro/libixp";
+    description = "Portable, simple C-language 9P client and server libary";
+    maintainers = with lib.maintainers; [ kovirobi ];
+    license = lib.licenses.mit;
+    platforms = with lib.platforms; unix;
+  };
+}

pkgs/top-level/aliases.nix

···
   libgroove = throw "libgroove has been removed, because it depends on an outdated and insecure version of ffmpeg"; # Added 2022-01-21
   libgumbo = throw "'libgumbo' has been renamed to/replaced by 'gumbo'"; # Converted to throw 2022-02-22
   libintlOrEmpty = lib.optional (!stdenv.isLinux || stdenv.hostPlatform.libc != "glibc") gettext; # Added 2018-03-14
+  libixp_hg = libixp;
   libjpeg_drop = libjpeg_original; # Added 2020-06-05
   libjson_rpc_cpp = throw "'libjson_rpc_cpp' has been renamed to/replaced by 'libjson-rpc-cpp'"; # Converted to throw 2022-02-22
   libkml = throw "libkml has been removed from nixpkgs, as it's abandoned and no package needed it"; # Added 2021-11-09
···
   winpdb = throw "winpdb has been removed: abandoned by upstream"; # Added 2022-04-22
   winusb = throw "'winusb' has been renamed to/replaced by 'woeusb'"; # Converted to throw 2022-02-22
   wireguard = throw "'wireguard' has been renamed to/replaced by 'wireguard-tools'"; # Converted to throw 2022-02-22
+  wmii_hg = wmii;
   wxmupen64plus = throw "wxmupen64plus was removed because the upstream disappeared"; # Added 2022-01-31
 
   ### X ###

pkgs/top-level/all-packages.nix

···
 
   libxsmm = callPackage ../development/libraries/libxsmm { };
 
-  libixp_hg = callPackage ../development/libraries/libixp-hg { };
+  libixp = callPackage ../development/libraries/libixp { };
 
   libwpe = callPackage ../development/libraries/libwpe { };
 
···
 
   wmderlandc = callPackage ../applications/window-managers/wmderlandc { };
 
-  wmii_hg = callPackage ../applications/window-managers/wmii-hg { };
+  wmii = callPackage ../applications/window-managers/wmii { };
 
   wofi = callPackage ../applications/misc/wofi { };