pdfmod: init at 0.9.1 (close #11417)

vcunat did some cosmetic changes, such as joining lines
because we seem to rarely use one-identifier-per-line style,
or fixing hyena description to conform to our rules.

pkgs/applications/misc/pdfmod/default.nix

···
+{ stdenv, fetchurl, fetchpatch, pkgconfig, gnome_doc_utils, intltool
+, mono, gtk-sharp, gnome-sharp, hyena
+, which, makeWrapper, glib, gnome3, poppler, wrapGAppsHook
+}:
+
+stdenv.mkDerivation rec {
+  name = "pdfmod-${version}";
+  version = "0.9.1";
+
+  src = fetchurl {
+    url = "mirror://gnome/sources/pdfmod/0.9/pdfmod-${version}.tar.bz2";
+    sha256 = "eb7c987514a053106ddf03f26544766c751c801d87762909b36415d46bc425c9";
+  };
+
+  patches = [ (fetchpatch {
+    url = "https://raw.githubusercontent.com/City-busz/Arch-Linux-Repository"
+      + "/master/gnome/pdfmod/pdfmod/pdfmod-mono-2.10.patch";
+    sha256 = "0fpz9ifr6476lqhd5rkb94dm68vlrwdq5w1aaxzgyjgdax9hxx81";
+  }) ];
+
+  buildInputs = [
+    pkgconfig gnome_doc_utils intltool mono gtk-sharp gnome-sharp
+    hyena which makeWrapper wrapGAppsHook
+  ];
+
+  preConfigure = ''
+    substituteInPlace configure --replace gmcs mcs
+    substituteInPlace lib/poppler-sharp/poppler-sharp/poppler-sharp.dll.config \
+      --replace libpoppler-glib.so.4 libpoppler-glib.so
+  '';
+
+  postInstall = ''
+    makeWrapper "${mono}/bin/mono" "$out/bin/pdfmod" \
+      --add-flags "$out/lib/pdfmod/PdfMod.exe" \
+      --prefix MONO_GAC_PREFIX : ${gtk-sharp} \
+      --prefix MONO_GAC_PREFIX : ${gnome-sharp} \
+      --prefix LD_LIBRARY_PATH : ${glib}/lib \
+      --prefix LD_LIBRARY_PATH : ${gtk-sharp}/lib \
+      --prefix LD_LIBRARY_PATH : ${gnome-sharp}/lib \
+      --prefix LD_LIBRARY_PATH : ${gtk-sharp.gtk}/lib \
+      --prefix LD_LIBRARY_PATH : ${gnome3.gconf}/lib \
+      --prefix LD_LIBRARY_PATH : ${poppler}/lib
+  '';
+
+  dontStrip = true;
+
+  meta = with stdenv.lib; {
+    homepage = "https://wiki.gnome.org/Apps/PdfMod";
+    description = "A simple application for modifying PDF documents";
+    platforms = platforms.all;
+    maintainers = with maintainers; [ obadz ];
+  };
+}

pkgs/development/libraries/hyena/default.nix

···
+{ stdenv, fetchurl, pkgconfig, mono, gtk-sharp, monoDLLFixer }:
+
+stdenv.mkDerivation rec {
+  name = "hyena-${version}";
+  version = "0.5";
+
+  src = fetchurl {
+    url = "mirror://gnome/sources/hyena/${version}/hyena-${version}.tar.bz2" ;
+    sha256 = "eb7154a42b6529bb9746c39272719f3168d6363ed4bad305a916ed7d90bc8de9";
+  };
+
+  buildInputs = [
+    pkgconfig mono gtk-sharp
+  ];
+
+  postPatch = ''
+    patchShebangs build/dll-map-makefile-verifier
+    patchShebangs build/private-icon-theme-installer
+    find -name Makefile.in | xargs -n 1 -d '\n' sed -e 's/^dnl/#/' -i
+  '';
+
+  preConfigure = ''
+    substituteInPlace configure --replace gmcs mcs
+  '';
+
+  dontStrip = true;
+
+  inherit monoDLLFixer;
+
+  meta = with stdenv.lib; {
+    homepage = https://wiki.gnome.org/Hyena;
+    description = "A C# library which contains a hodge-podge of random stuff";
+    longDescription = ''
+      Hyena is a C# library used to make awesome applications. It contains a lot of random things,
+      including useful data structures, a Sqlite-based db layer, cool widgets, a JSON library,
+      a smart job/task scheduler, a user-query/search parser, and much more. It's particularly
+      useful for Gtk# applications, though only the Hyena.Gui assembly requires Gtk#.
+    '';
+    platforms = platforms.all;
+    maintainers = with maintainers; [ obadz ];
+  };
+}

pkgs/top-level/all-packages.nix

···
 
   pdfjam = callPackage ../tools/typesetting/pdfjam { };
 
+  pdfmod = callPackage ../applications/misc/pdfmod { };
+
   jbig2enc = callPackage ../tools/graphics/jbig2enc { };
 
   pdfread = callPackage ../tools/graphics/pdfread {
···
   hwloc = callPackage ../development/libraries/hwloc {};
 
   hydraAntLogger = callPackage ../development/libraries/java/hydra-ant-logger { };
+
+  hyena = callPackage ../development/libraries/hyena { };
 
   icu = callPackage ../development/libraries/icu { };