roundcubePlugins: init

This meta-package is supposed to contain third-party roundcube plugins
such as `persistent_login` that will be linked into the roundcube
derivation.

pkgs/servers/roundcube/plugins/default.nix

···
+{ newScope, pkgs }:
+
+let
+
+  callPackage = newScope (pkgs // plugins);
+
+  plugins = import ./plugins.nix { inherit callPackage; };
+
+in
+
+  plugins

pkgs/servers/roundcube/plugins/persistent_login/default.nix

···
+{ roundcubePlugin, fetchFromGitHub }:
+
+roundcubePlugin rec {
+  pname = "persistent_login";
+  version = "5.1.0";
+
+  src = fetchFromGitHub {
+    owner = "mfreiholz";
+    repo = pname;
+    rev = "version-${version}";
+    sha256 = "1k2jgbshwig8q5l440y59pgwbfbc0pdrjbpihba834a4pm0y6anl";
+  };
+}

pkgs/servers/roundcube/plugins/plugins.nix

···
+{ callPackage }:
+
+{
+  inherit callPackage;
+
+  roundcubePlugin = callPackage ./roundcube-plugin.nix { };
+
+  persistent_login = callPackage ./persistent_login { };
+}

pkgs/servers/roundcube/plugins/roundcube-plugin.nix

···
+{ runCommand }:
+{ pname, version, src }:
+
+runCommand "roundcube-plugin-${pname}-${version}" { } ''
+  mkdir -p $out/plugins/
+  cp -r ${src} $out/plugins/${pname}
+''

pkgs/top-level/all-packages.nix

···
 
   roundcube = callPackage ../servers/roundcube { };
 
+  roundcubePlugins = callPackage ../servers/roundcube/plugins { };
+
   rsbep = callPackage ../tools/backup/rsbep { };
 
   rsyslog = callPackage ../tools/system/rsyslog {