Merge pull request #111000 from AndersonTorres/new-commander-x16

Commander X16 emulator

pkgs/development/compilers/cc65/default.nix

···
     '';
     license = licenses.zlib;
     maintainers = with maintainers; [ AndersonTorres ];
+    platforms = with platforms; unix;
   };
 }

pkgs/misc/emulators/commander-x16/emulator.nix

···
+{ stdenv
+, lib
+, fetchFromGitHub
+, SDL2
+}:
+
+stdenv.mkDerivation rec {
+  pname = "x16-emulator";
+  version = "38";
+
+  src = fetchFromGitHub {
+    owner = "commanderx16";
+    repo = pname;
+    rev = "r${version}";
+    sha256 = "WNRq/m97NpOBWIk6mtxBAKmkxCGWacWjXeOvIhBrkYE=";
+  };
+
+  dontConfigure = true;
+
+  buildInputs = [ SDL2 ];
+
+  installPhase = ''
+    runHook preInstall
+    install -D --mode 755 --target-directory $out/bin/ x16emu
+    install -D --mode 444 --target-directory $out/share/doc/${pname} README.md
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    homepage = "https://www.commanderx16.com/forum/index.php?/home/";
+    description = "The official emulator of CommanderX16 8-bit computer";
+    license = licenses.bsd2;
+    maintainers = with maintainers; [ AndersonTorres ];
+    platforms = SDL2.meta.platforms;
+  };
+
+  passthru = {
+    # upstream project recommends emulator and rom synchronized;
+    # passing through the version is useful to ensure this
+    inherit version;
+  };
+}

pkgs/misc/emulators/commander-x16/rom.nix

···
+{ stdenv
+, lib
+, fetchFromGitHub
+, cc65
+}:
+
+stdenv.mkDerivation rec {
+  pname = "x16-rom";
+  version = "38";
+
+  src = fetchFromGitHub {
+    owner = "commanderx16";
+    repo = pname;
+    rev = "r${version}";
+    sha256 = "xaqF0ppB7I7ST8Uh3jPbC14uRAb/WH21tHlNeTvYpoI=";
+  };
+
+  nativeBuildInputs = [ cc65 ];
+
+  postPatch = ''
+    patchShebangs scripts/
+  '';
+
+  dontConfigure = true;
+
+  installPhase = ''
+    runHook preInstall
+    install -D --mode 444 --target-directory $out/share/${pname} build/x16/rom.bin
+    install -D --mode 444 --target-directory $out/share/doc/${pname} README.md
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    homepage = "https://www.commanderx16.com/forum/index.php?/home/";
+    description = "ROM file for CommanderX16 8-bit computer";
+    license = licenses.bsd2;
+    maintainers = with maintainers; [ AndersonTorres ];
+    platforms = cc65.meta.platforms;
+  };
+
+  passthru = {
+    # upstream project recommends emulator and rom synchronized;
+    # passing through the version is useful to ensure this
+    inherit version;
+  };
+}

pkgs/top-level/all-packages.nix

···
     inherit (darwin.apple_sdk.frameworks) Carbon Cocoa OpenGL OpenAL;
   };
 
+  x16-emulator = callPackage ../misc/emulators/commander-x16/emulator.nix { };
+  x16-rom = callPackage ../misc/emulators/commander-x16/rom.nix { };
+
   bullet = callPackage ../development/libraries/bullet {
     inherit (darwin.apple_sdk.frameworks) Cocoa OpenGL;
   };