Clean up Nix a bit, expose home-manager module

flake.nix

···
   };
 
   outputs = { self, nixpkgs, flake-utils, pnpm2nix }:
-    let
-      mkMoonlight = { pkgs, mkPnpmPackage }:
-        mkPnpmPackage rec {
-          workspace = ./.;
-          src = ./.;
-          components = [
-            "packages/core"
-            "packages/core-extensions"
-            "packages/injector"
-            "packages/node-preload"
-            "packages/types"
-            "packages/web-preload"
-          ];
-          distDirs = [ "dist" ];
-
-          copyNodeModules = true;
-          buildPhase = "pnpm run build";
-          installPhase = "cp -r dist $out";
-
-          meta = with pkgs.lib; {
-            description = "Yet another Discord mod";
-            homepage = "https://moonlight-mod.github.io/";
-            license = licenses.lgpl3;
-            maintainers = with maintainers; [ notnite ];
-          };
-        };
-
-      nameTable = {
-        discord = "Discord";
-        discord-ptb = "DiscordPTB";
-        discord-canary = "DiscordCanary";
-        discord-development = "DiscordDevelopment";
-      };
-
-      darwinNameTable = {
-        discord = "Discord";
-        discord-ptb = "Discord PTB";
-        discord-canary = "Discord Canary";
-        discord-development = "Discord Development";
-      };
-
-      mkOverride = prev: moonlight: name:
-        let discord = prev.${name};
-        in discord.overrideAttrs (old: {
-          installPhase = let
-            folderName = nameTable.${name};
-            darwinFolderName = darwinNameTable.${name};
-
-            injected = ''
-              require("${moonlight}/injector").inject(
-                require("path").join(__dirname, "../_app.asar")
-              );
-            '';
-
-            packageJson = ''
-              {"name":"discord","main":"./injector.js","private":true}
-            '';
-
-          in old.installPhase + "\n" + ''
-            resources="$out/opt/${folderName}/resources"
-            if [ ! -d "$resources" ]; then
-              resources="$out/Applications/${darwinFolderName}.app/Contents/Resources"
-            fi
-
-            mv "$resources/app.asar" "$resources/_app.asar"
-            mkdir -p "$resources/app"
-
-            cat > "$resources/app/injector.js" <<EOF
-            ${injected}
-            EOF
-
-            echo '${packageJson}' > "$resources/app/package.json"
-          '';
-        });
-
-      overlay = final: prev: rec {
-        moonlight-mod = mkMoonlight {
-          pkgs = final;
-          mkPnpmPackage = pnpm2nix.packages.${final.system}.mkPnpmPackage;
-        };
-        discord = mkOverride prev moonlight-mod "discord";
-        discord-ptb = mkOverride prev moonlight-mod "discord-ptb";
-        discord-canary = mkOverride prev moonlight-mod "discord-canary";
-        discord-development =
-          mkOverride prev moonlight-mod "discord-development";
-      };
+    let overlay = import ./nix/overlay.nix { inherit pnpm2nix; };
     in flake-utils.lib.eachDefaultSystem (system:
       let
         pkgs = import nixpkgs {
···
           overlays = [ overlay ];
         };
       in {
+        # Don't use these unless you're testing things
         packages.default = pkgs.moonlight-mod;
         packages.moonlight-mod = pkgs.moonlight-mod;
 
···
         packages.discord-development = pkgs.discord-development;
       }) // {
         overlays.default = overlay;
+        homeModules.default = ./nix/home-manager.nix;
       };
 }

nix/default.nix

···
+{ pkgs, mkPnpmPackage }:
+
+mkPnpmPackage rec {
+  workspace = ./..;
+  src = ./..;
+
+  # Work around a bug with how it expects dist
+  components = [
+    "packages/core"
+    "packages/core-extensions"
+    "packages/injector"
+    "packages/node-preload"
+    "packages/types"
+    "packages/web-preload"
+  ];
+  distDirs = [ "dist" ];
+
+  copyNodeModules = true;
+  buildPhase = "pnpm run build";
+  installPhase = "cp -r dist $out";
+
+  meta = with pkgs.lib; {
+    description = "Yet another Discord mod";
+    homepage = "https://moonlight-mod.github.io/";
+    license = licenses.lgpl3;
+    maintainers = with maintainers; [ notnite ];
+  };
+}

nix/home-manager.nix

···
+{ config, lib, pkgs, ... }:
+
+let cfg = config.programs.moonlight-mod;
+in {
+  options.programs.moonlight-mod = {
+    enable = lib.mkEnableOption "Yet another Discord mod";
+
+    configs = let
+      # TODO: type this
+      type = lib.types.nullOr (lib.types.attrs);
+      default = null;
+    in {
+      stable = lib.mkOption {
+        inherit type default;
+        description = "Configuration for Discord Stable";
+      };
+
+      ptb = lib.mkOption {
+        inherit type default;
+        description = "Configuration for Discord PTB";
+      };
+
+      canary = lib.mkOption {
+        inherit type default;
+        description = "Configuration for Discord Canary";
+      };
+
+      development = lib.mkOption {
+        inherit type default;
+        description = "Configuration for Discord Development";
+      };
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    xdg.configFile."moonlight-mod/stable.json" =
+      lib.mkIf (cfg.configs.stable != null) {
+        text = builtins.toJSON cfg.configs.stable;
+      };
+
+    xdg.configFile."moonlight-mod/ptb.json" =
+      lib.mkIf (cfg.configs.ptb != null) {
+        text = builtins.toJSON cfg.configs.ptb;
+      };
+
+    xdg.configFile."moonlight-mod/canary.json" =
+      lib.mkIf (cfg.configs.canary != null) {
+        text = builtins.toJSON cfg.configs.canary;
+      };
+
+    xdg.configFile."moonlight-mod/development.json" =
+      lib.mkIf (cfg.configs.development != null) {
+        text = builtins.toJSON cfg.configs.development;
+      };
+  };
+}

nix/overlay.nix

···
+{ pnpm2nix }:
+
+let
+  nameTable = {
+    discord = "Discord";
+    discord-ptb = "DiscordPTB";
+    discord-canary = "DiscordCanary";
+    discord-development = "DiscordDevelopment";
+  };
+
+  darwinNameTable = {
+    discord = "Discord";
+    discord-ptb = "Discord PTB";
+    discord-canary = "Discord Canary";
+    discord-development = "Discord Development";
+  };
+
+  mkOverride = prev: moonlight: name:
+    let discord = prev.${name};
+    in discord.overrideAttrs (old: {
+      installPhase = let
+        folderName = nameTable.${name};
+        darwinFolderName = darwinNameTable.${name};
+
+        injected = ''
+          require("${moonlight}/injector").inject(
+            require("path").join(__dirname, "../_app.asar")
+          );
+        '';
+
+        packageJson = ''
+          {"name":"discord","main":"./injector.js","private":true}
+        '';
+
+      in old.installPhase + "\n" + ''
+        resources="$out/opt/${folderName}/resources"
+        if [ ! -d "$resources" ]; then
+          resources="$out/Applications/${darwinFolderName}.app/Contents/Resources"
+        fi
+
+        mv "$resources/app.asar" "$resources/_app.asar"
+        mkdir -p "$resources/app"
+
+        cat > "$resources/app/injector.js" <<EOF
+        ${injected}
+        EOF
+
+        echo '${packageJson}' > "$resources/app/package.json"
+      '';
+    });
+in final: prev: rec {
+  moonlight-mod = final.callPackage ./default.nix {
+    pkgs = final;
+    mkPnpmPackage = pnpm2nix.packages.${final.system}.mkPnpmPackage;
+  };
+  discord = mkOverride prev moonlight-mod "discord";
+  discord-ptb = mkOverride prev moonlight-mod "discord-ptb";
+  discord-canary = mkOverride prev moonlight-mod "discord-canary";
+  discord-development = mkOverride prev moonlight-mod "discord-development";
+}