Add commands for managing runtime dependencies

Closes #5

Signed-off-by: Shiloh Fen <[e-mail]>

src/atomic-xr/envision.nu

···
 const envision_config_path = "~/.config/envision/envision.json" | path expand
 
 use std log
-
-const runtime_deps = {
-    xr: [openxr-libs openvr-api]
-    monado: [
-        # TODO: Is there a way to build monado that doesn't require all of these at runtime?
-        libuvc
-        openhmd
-        opencv
-        onnxruntime
-        librealsense
-        opencv-video
-    ]
-}
+use runtime.nu
 
 export def install [
     --no-monado (-m) # Don't install runtime deps for Monado
 ] {
-    let deps = $runtime_deps.xr | if not $no_monado {
-        append $runtime_deps.monado
-    } else {$in}
-
-    ensure-host-packages $deps
+    runtime install xr (if not $no_monado {"monado"})
 
     distrobox create envision --no-entry -Y -i registry.fedoraproject.org/fedora-toolbox:latest
     distrobox enter envision -- sudo dnf install -y nu
···
 
 export def uninstall [] {
     try {distrobox rm -f envision}
-    rpm-ostree uninstall ...($runtime_deps | transpose k v | get v | flatten) --idempotent
     rm -f ~/.local/bin/envision ~/.local/share/applications/org.gabmus.envision.Devel.desktop ~/.local/share/applications/org.gabmus.envision.Devel.desktop  ~/.local/share/bin/envision
     log info "Successfully uninstalled Envision"
-}
-
-def ensure-host-packages [
-    packages: list<string>
-] {
-    let missing_packages = $packages
-    | each {|package|
-        if (rpm -q $package | complete | get exit_code) != 0 {
-            $package
-        }
-    }
-
-    if ($missing_packages | is-not-empty) {
-        rpm-ostree install ...$missing_packages
-        job spawn {
-            match (notify-send -u critical "Package(s) installed" "Please reboot or use `rpm-ostree ex apply-live` before attempting to launch Envision." -A reboot="Reboot" -A live="Apply Changes Live") {
-                "reboot" => (systemctl reboot)
-                "live" => (pkexec rpm-ostree ex apply-live)
-            }
-        }
-        null
-    }
 }
 
 export def upgrade [] {

src/atomic-xr/mod.nu

···
 export use flatpak.nu
 export use homebrew.nu
 export use steamvr-lh.nu
+export use runtime.nu

src/atomic-xr/runtime.nu

···
+# SPDX-License-Identifier: AGPL-3.0-only
+# Copyright (c) 2025 Shiloh Fen <[e-mail]>
+
+use std log
+
+const runtime_deps = {
+    xr: [openxr-libs openvr-api]
+    monado: [
+        libuvc
+        openhmd
+        opencv
+        onnxruntime
+        librealsense
+        opencv-video
+    ]
+}
+
+# Install runtime dependencies
+export def install [
+    ...groups: string # Package groups to install
+] {
+    ensure-installed (get-packages $groups)
+}
+
+# Uninstall runtime dependencies
+export def uninstall [
+    ...groups: string # Package groups to install
+] {
+    ensure-not-installed (get-packages $groups)
+}
+
+def get-packages [
+    groups: list<string>
+] {
+    if ($groups | is-empty) {
+        $runtime_deps
+        | transpose group packages
+    } else {
+        validate $groups
+
+        $runtime_deps
+        | transpose group packages
+        | where group in $groups
+    }
+    | get packages
+    | flatten
+}
+
+def validate [
+    groups: list<string>
+] {
+    let avaliable_groups = $runtime_deps
+    | transpose group packages
+    | get group
+
+    $groups
+    | each {|group|
+        if $group not-in $avaliable_groups {
+            error make {
+                msg: "Unknown package group"
+                label: {
+                    span: (metadata $group).span
+                    text: $"Unknown package group: ($group)"
+                }
+                help: $"Avaliable groups: ($avaliable_groups | str join ', ')"
+            }
+        }
+    }
+}
+
+def ensure-installed [
+    packages: list<string>
+] {
+    let missing_packages = $packages
+    | each {|package|
+        if (rpm -q $package | complete | get exit_code) != 0 {
+            $package
+        }
+    }
+
+    if ($missing_packages | is-not-empty) {
+        rpm-ostree install ...$missing_packages
+        job spawn {
+            match (notify-send -u critical "Package(s) installed" "Please reboot or use `rpm-ostree ex apply-live` to apply changes." -A reboot="Reboot" -A live="Apply Changes Live") {
+                "reboot" => (systemctl reboot)
+                "live" => (pkexec rpm-ostree ex apply-live)
+            }
+        }
+        null
+    }
+}
+
+def ensure-not-installed [
+    packages: list<string>
+] {
+    let installed_packages = $packages
+    | each {|package|
+        if (rpm -q $package | complete | get exit_code) == 0 {
+            $package
+        }
+    }
+
+    if ($installed_packages | is-not-empty) {
+        rpm-ostree remove ...$installed_packages
+        job spawn {
+            match (notify-send -u critical "Package(s) removed" "Please reboot or use `rpm-ostree ex apply-live` to apply changes." -A reboot="Reboot" -A live="Apply Changes Live") {
+                "reboot" => (systemctl reboot)
+                "live" => (pkexec rpm-ostree ex apply-live --allow-replacement)
+            }
+        }
+        null
+    }
+}