feat: dedicated store for oauth sessions

.formatter.exs

···
 # Used by "mix format"
 [
-  inputs: ["{mix,.formatter,.credo}.exs", "{config,examples,lib,test}/**/*.{ex,exs}"],
+  inputs:
+    Enum.flat_map(
+      ["{mix,.formatter,.credo}.exs", "{config,examples,lib,test}/**/*.{ex,exs}"],
+      &Path.wildcard(&1, match_dot: true)
+    ) -- Path.wildcard("lib/atproto/**/*.ex"),
   import_deps: [:typedstruct, :peri, :plug],
-  excludes: ["lib/atproto/**/*"],
+  # excludes: ["lib/atproto/**/*.ex"],
   export: [
     locals_without_parens: [deflexicon: 1]
   ]

CHANGELOG.md

···
 
 ### Added
 
+- `Atex.OAuth.SessionStore` behaviour and `Atex.OAuth.Session` struct for
+  managing OAuth sessions with pluggable storage backends.
+  - `Atex.OAuth.SessionStore.ETS` - in-memory session store implementation.
+  - `Atex.OAuth.SessionStore.DETS` - persistent disk-based session store
+    implementation.
 - `Atex.OAuth.Plug` now requires a `:callback` option that is a MFA tuple
   (Module, Function, Args), denoting a callback function to be invoked by after
   a successful OAuth login. See [the OAuth example](./examples/oauth.ex) for a

lib/atex/application.ex

···
   def start(_type, _args) do
     children = [
       Atex.IdentityResolver.Cache,
-      Atex.OAuth.Cache
+      Atex.OAuth.Cache,
+      Atex.OAuth.SessionStore,
+      {Mutex, name: Atex.SessionMutex}
     ]
 
     Supervisor.start_link(children, strategy: :one_for_one)

lib/atex/oauth/error.ex

···
   - `:token_validation_failed` - Failed to validate the authorization code or
     token
   - `:issuer_mismatch` - OAuth issuer does not match PDS authorization server
+  - `:session_store_failed` - OAuth succeeded but failed to store the session
   """
 
   defexception [:message, :reason]

lib/atex/oauth/plug.ex

···
   alias Atex.{IdentityResolver, IdentityResolver.DIDDocument}
 
   @oauth_cookie_opts [path: "/", http_only: true, secure: true, same_site: "lax", max_age: 600]
+  @session_name :atex_session
 
   def init(opts) do
     callback = Keyword.get(opts, :callback, nil)
···
          pds <- DIDDocument.get_pds_endpoint(identity.document),
          {:ok, authz_server} <- OAuth.get_authorization_server(pds),
          true <- authz_server == stored_issuer do
-      conn =
-        conn
-        |> delete_resp_cookie("state", @oauth_cookie_opts)
-        |> delete_resp_cookie("code_verifier", @oauth_cookie_opts)
-        |> delete_resp_cookie("issuer", @oauth_cookie_opts)
-        |> put_session(:atex_oauth, %{
-          access_token: tokens.access_token,
-          refresh_token: tokens.refresh_token,
-          did: tokens.did,
-          pds: pds,
-          expires_at: tokens.expires_at,
-          dpop_nonce: nonce,
-          dpop_key: dpop_key
-        })
+      session = %OAuth.Session{
+        iss: authz_server,
+        aud: pds,
+        sub: tokens.did,
+        access_token: tokens.access_token,
+        refresh_token: tokens.refresh_token,
+        expires_at: tokens.expires_at,
+        dpop_key: dpop_key,
+        dpop_nonce: nonce
+      }
+
+      case OAuth.SessionStore.insert(session) do
+        :ok ->
+          conn =
+            conn
+            |> delete_resp_cookie("state", @oauth_cookie_opts)
+            |> delete_resp_cookie("code_verifier", @oauth_cookie_opts)
+            |> delete_resp_cookie("issuer", @oauth_cookie_opts)
+            |> put_session(@session_name, tokens.did)
+
+          {mod, func, args} = callback
+          apply(mod, func, [conn | args])
 
-      {mod, func, args} = callback
-      apply(mod, func, [conn | args])
+        {:error, reason} ->
+          raise Atex.OAuth.Error,
+            message: "Failed to store OAuth session, reason: #{reason}",
+            reason: :session_store_failed
+      end
     else
       false ->
         raise Atex.OAuth.Error,
···
           reason: :token_validation_failed
     end
   end
+
+  # TODO: logout route
 end

lib/atex/oauth/session.ex

···
+defmodule Atex.OAuth.Session do
+  @moduledoc """
+  Struct representing an active OAuth session for an AT Protocol user.
+
+  Contains all the necessary credentials and metadata to make authenticated
+  requests to a user's PDS using OAuth with DPoP.
+
+  ## Fields
+
+  - `:iss` - Authorization server issuer URL
+  - `:aud` - PDS endpoint URL (audience)
+  - `:sub` - User's DID (subject), used as the session key
+  - `:access_token` - OAuth access token for authenticating requests
+  - `:refresh_token` - OAuth refresh token for obtaining new access tokens
+  - `:expires_at` - When the current access token expires (NaiveDateTime in UTC)
+  - `:dpop_key` - DPoP signing key (Demonstrating Proof-of-Possession)
+  - `:dpop_nonce` - Server-provided nonce for DPoP proofs (optional, updated per-request)
+
+  ## Usage
+
+  Sessions are typically created during the OAuth flow and stored in a `SessionStore`.
+  They should not be created manually in most cases.
+
+      session = %Atex.OAuth.Session{
+        iss: "https://bsky.social",
+        aud: "https://puffball.us-east.host.bsky.network",
+        sub: "did:plc:abc123",
+        access_token: "...",
+        refresh_token: "...",
+        expires_at: ~N[2026-01-04 12:00:00],
+        dpop_key: dpop_key,
+        dpop_nonce: "server-nonce"
+      }
+  """
+  use TypedStruct
+
+  typedstruct enforce: true do
+    # Authz server issuer
+    field :iss, String.t()
+    # PDS endpoint
+    field :aud, String.t()
+    # User's DID
+    field :sub, String.t()
+    field :access_token, String.t()
+    field :refresh_token, String.t()
+    field :expires_at, NaiveDateTime.t()
+    field :dpop_key, JOSE.JWK.t()
+    field :dpop_nonce, String.t() | nil, enforce: false
+  end
+end

lib/atex/oauth/session_store.ex

···
+defmodule Atex.OAuth.SessionStore do
+  @moduledoc """
+  Storage interface for OAuth sessions.
+
+  Provides a behaviour for implementing session storage backends, and functions
+  to operate the backend using `Atex.OAuth.Session`
+
+  ## Configuration
+
+  The default implementation for the store is `Atex.OAuth.SessionStore.DETS`;
+  this can be changed to a custom implementation in your config.exs:
+
+      config :atex, :session_store, Atex.OAuth.SessionStore.ETS
+
+  DETS is the default implementation as it provides simple, on-disk storage for
+  sessions so they don't get discarded on an application restart, but a regular
+  ETS implementation is also provided out-of-the-box for testing or other
+  circumstances.
+
+  For multi-node deployments, you can write your own implementation using a
+  custom backend, such as Redis, by implementing the behaviour callbacks.
+
+  ## Usage
+
+  Sessions are keyed by the user's DID (`sub` field).
+
+      session = %Atex.OAuth.Session{
+        iss: "https://bsky.social",
+        aud: "https://puffball.us-east.host.bsky.network",
+        sub: "did:plc:abc123",
+        access_token: "...",
+        refresh_token: "...",
+        expires_at: ~N[2026-01-04 12:00:00],
+        dpop_key: dpop_key,
+        dpop_nonce: "server-nonce"
+      }
+
+      # Insert a new session
+      :ok = Atex.OAuth.SessionStore.insert(session)
+
+      # Retrieve a session
+      {:ok, session} = Atex.OAuth.SessionStore.get("did:plc:abc123")
+
+      # Update an existing session (e.g., after token refresh)
+      updated_session = %{session | access_token: new_token}
+      :ok = Atex.OAuth.SessionStore.update(updated_session)
+
+      # Delete a session
+      Atex.OAuth.SessionStore.delete(session)
+  """
+
+  @store Application.compile_env(:atex, :session_store, Atex.OAuth.SessionStore.DETS)
+
+  @doc """
+  Retrieve a session by DID.
+
+  Returns `{:ok, session}` if found, `{:error, :not_found}` otherwise.
+  """
+  @callback get(key :: String.t()) :: {:ok, Atex.OAuth.Session.t()} | {:error, atom()}
+
+  @doc """
+  Insert a new session.
+
+  The key is the user's DID (`session.sub`). Returns `:ok` on success.
+  """
+  @callback insert(key :: String.t(), session :: Atex.OAuth.Session.t()) ::
+              :ok | {:error, atom()}
+
+  @doc """
+  Update an existing session.
+
+  Replaces the existing session data for the given key. Returns `:ok` on success.
+  """
+  @callback update(key :: String.t(), session :: Atex.OAuth.Session.t()) ::
+              :ok | {:error, atom()}
+
+  @doc """
+  Delete a session.
+
+  Returns `:ok` if deleted, `:noop` if the session didn't exist, :error if it failed.
+  """
+  @callback delete(key :: String.t()) :: :ok | :error | :noop
+
+  @callback child_spec(any()) :: Supervisor.child_spec()
+
+  defdelegate child_spec(opts), to: @store
+
+  @doc """
+  Retrieve a session by DID.
+  """
+  @spec get(String.t()) :: {:ok, Atex.OAuth.Session.t()} | {:error, atom()}
+  def get(key) do
+    @store.get(key)
+  end
+
+  @doc """
+  Insert a new session.
+  """
+  @spec insert(Atex.OAuth.Session.t()) :: :ok | {:error, atom()}
+  def insert(session) do
+    @store.insert(session.sub, session)
+  end
+
+  @doc """
+  Update an existing session.
+  """
+  @spec update(Atex.OAuth.Session.t()) :: :ok | {:error, atom()}
+  def update(session) do
+    @store.update(session.sub, session)
+  end
+
+  @doc """
+  Delete a session.
+  """
+  @callback delete(Atex.OAuth.Session.t()) :: :ok | :error | :noop
+  def delete(session) do
+    @store.delete(session.sub)
+  end
+end

lib/atex/oauth/session_store/dets.ex

···
+defmodule Atex.OAuth.SessionStore.DETS do
+  @moduledoc """
+  DETS implementation for `Atex.OAuth.SessionStore`.
+
+  This is recommended for single-node production deployments, as sessions will
+  persist on disk between application restarts. For more complex, multi-node
+  deployments, consider making a custom implementation using Redis or some other
+  distributed store.
+
+  ## Configuration
+
+  By default the DETS file is stored at `priv/dets/atex_oauth_sessions.dets`
+  relative to where your application is running. You can configure the file path
+  in your `config.exs`:
+
+      config :atex, Atex.OAuth.SessionStore.DETS,
+        file_path: "/var/lib/myapp/sessions.dets"
+
+  Parent directories will be created as necessary if possible.
+  """
+
+  alias Atex.OAuth.Session
+  require Logger
+  use Supervisor
+
+  @behaviour Atex.OAuth.SessionStore
+  @table :atex_oauth_sessions
+  @default_file "priv/dets/atex_oauth_sessions.dets"
+
+  def start_link(opts) do
+    Supervisor.start_link(__MODULE__, opts)
+  end
+
+  @impl Supervisor
+  def init(_opts) do
+    dets_file =
+      case Application.get_env(:atex, __MODULE__, [])[:file_path] do
+        nil ->
+          @default_file
+
+        path ->
+          path
+      end
+
+    # Ensure parent directory exists
+    dets_file
+    |> Path.dirname()
+    |> File.mkdir_p!()
+
+    case :dets.open_file(@table, file: String.to_charlist(dets_file), type: :set) do
+      {:ok, @table} ->
+        Logger.info("DETS session store opened: #{dets_file}")
+        Supervisor.init([], strategy: :one_for_one)
+
+      {:error, reason} ->
+        Logger.error("Failed to open DETS file: #{inspect(reason)}")
+        raise "Failed to initialize DETS session store: #{inspect(reason)}"
+    end
+  end
+
+  @doc """
+  Insert a session into the DETS table.
+
+  Returns `:ok` on success, `{:error, reason}` if an unexpected error occurs.
+  """
+  @impl Atex.OAuth.SessionStore
+  @spec insert(String.t(), Session.t()) :: :ok | {:error, atom()}
+  def insert(key, session) do
+    case :dets.insert(@table, {key, session}) do
+      :ok ->
+        :ok
+
+      {:error, reason} ->
+        Logger.error("DETS insert failed: #{inspect(reason)}")
+        {:error, reason}
+    end
+  end
+
+  @doc """
+  Update a session in the DETS table.
+
+  In DETS, this is the same as insert - it replaces the existing entry.
+  """
+  @impl Atex.OAuth.SessionStore
+  @spec update(String.t(), Session.t()) :: :ok | {:error, atom()}
+  def update(key, session) do
+    insert(key, session)
+  end
+
+  @doc """
+  Retrieve a session from the DETS table.
+
+  Returns `{:ok, session}` if found, `{:error, :not_found}` otherwise.
+  """
+  @impl Atex.OAuth.SessionStore
+  @spec get(String.t()) :: {:ok, Session.t()} | {:error, atom()}
+  def get(key) do
+    case :dets.lookup(@table, key) do
+      [{_key, session}] -> {:ok, session}
+      [] -> {:error, :not_found}
+    end
+  end
+
+  @doc """
+  Delete a session from the DETS table.
+
+  Returns `:ok` if deleted, `:noop` if the session didn't exist.
+  """
+  @impl Atex.OAuth.SessionStore
+  @spec delete(String.t()) :: :ok | :error | :noop
+  def delete(key) do
+    case get(key) do
+      {:ok, _session} ->
+        :dets.delete(@table, key)
+        :ok
+
+      {:error, :not_found} ->
+        :noop
+    end
+  end
+end

lib/atex/oauth/session_store/ets.ex

···
+defmodule Atex.OAuth.SessionStore.ETS do
+  @moduledoc """
+  In-memory, ETS implementation for `Atex.OAuth.SessionStore`.
+
+  This is moreso intended for testing or some occasion where you want the
+  session store to be volatile for some reason. It's recommended you use
+  `Atex.OAuth.SessionStore.DETS` for single-node production deployments.
+  """
+
+  alias Atex.OAuth.Session
+  require Logger
+  use Supervisor
+
+  @behaviour Atex.OAuth.SessionStore
+  @table :atex_oauth_sessions
+
+  def start_link(opts) do
+    Supervisor.start_link(__MODULE__, opts)
+  end
+
+  @impl Supervisor
+  def init(_opts) do
+    :ets.new(@table, [:set, :public, :named_table])
+    Supervisor.init([], strategy: :one_for_one)
+  end
+
+  @doc """
+  Insert a session into the ETS table.
+
+  Returns `:ok` on success, `{:error, :ets}` if an unexpected error occurs.
+  """
+  @impl Atex.OAuth.SessionStore
+  @spec insert(String.t(), Session.t()) :: :ok | {:error, atom()}
+  def insert(key, session) do
+    try do
+      :ets.insert(@table, {key, session})
+      :ok
+    rescue
+      # Freak accidents can occur
+      e ->
+        Logger.error(Exception.format(:error, e, __STACKTRACE__))
+        {:error, :ets}
+    end
+  end
+
+  @doc """
+  Update a session in the ETS table.
+
+  In ETS, this is the same as insert - it replaces the existing entry.
+  """
+  @impl Atex.OAuth.SessionStore
+  @spec update(String.t(), Session.t()) :: :ok | {:error, atom()}
+  def update(key, session) do
+    insert(key, session)
+  end
+
+  @doc """
+  Retrieve a session from the ETS table.
+
+  Returns `{:ok, session}` if found, `{:error, :not_found}` otherwise.
+  """
+  @impl Atex.OAuth.SessionStore
+  @spec get(String.t()) :: {:ok, Session.t()} | {:error, atom()}
+  def get(key) do
+    case :ets.lookup(@table, key) do
+      [{_key, session}] -> {:ok, session}
+      [] -> {:error, :not_found}
+    end
+  end
+
+  @doc """
+  Delete a session from the ETS table.
+
+  Returns `:ok` if deleted, `:noop` if the session didn't exist.
+  """
+  @impl Atex.OAuth.SessionStore
+  @spec delete(String.t()) :: :ok | :error | :noop
+  def delete(key) do
+    case get(key) do
+      {:ok, _session} ->
+        :ets.delete(@table, key)
+        :ok
+
+      {:error, :not_found} ->
+        :noop
+    end
+  end
+end

mix.exs

···
       {:jason, "~> 1.4"},
       {:jose, "~> 1.11"},
       {:bandit, "~> 1.0", only: [:dev, :test]},
-      {:con_cache, "~> 1.1"}
+      {:con_cache, "~> 1.1"},
+      {:mutex, "~> 3.0"}
     ]
   end
 

mix.lock

···
 %{
-  "bandit": {:hex, :bandit, "1.8.0", "c2e93d7e3c5c794272fa4623124f827c6f24b643acc822be64c826f9447d92fb", [:mix], [{:hpax, "~> 1.0", [hex: :hpax, repo: "hexpm", optional: false]}, {:plug, "~> 1.18", [hex: :plug, repo: "hexpm", optional: false]}, {:telemetry, "~> 0.4 or ~> 1.0", [hex: :telemetry, repo: "hexpm", optional: false]}, {:thousand_island, "~> 1.0", [hex: :thousand_island, repo: "hexpm", optional: false]}, {:websock, "~> 0.5", [hex: :websock, repo: "hexpm", optional: false]}], "hexpm", "8458ff4eed20ff2a2ea69d4854883a077c33ea42b51f6811b044ceee0fa15422"},
+  "bandit": {:hex, :bandit, "1.10.0", "f8293b4a4e6c06b31655ae10bd3462f59d8c5dbd1df59028a4984f10c5961147", [:mix], [{:hpax, "~> 1.0", [hex: :hpax, repo: "hexpm", optional: false]}, {:plug, "~> 1.18", [hex: :plug, repo: "hexpm", optional: false]}, {:telemetry, "~> 0.4 or ~> 1.0", [hex: :telemetry, repo: "hexpm", optional: false]}, {:thousand_island, "~> 1.0", [hex: :thousand_island, repo: "hexpm", optional: false]}, {:websock, "~> 0.5", [hex: :websock, repo: "hexpm", optional: false]}], "hexpm", "43ebceb7060a4d8273e47d83e703d01b112198624ba0826980caa3f5091243c4"},
   "bunt": {:hex, :bunt, "1.0.0", "081c2c665f086849e6d57900292b3a161727ab40431219529f13c4ddcf3e7a44", [:mix], [], "hexpm", "dc5f86aa08a5f6fa6b8096f0735c4e76d54ae5c9fa2c143e5a1fc7c1cd9bb6b5"},
-  "cldr_utils": {:hex, :cldr_utils, "2.28.3", "d0ac5ed25913349dfaca8b7fe14722d588d8ccfa3e335b0510c7cc3f3c54d4e6", [:mix], [{:castore, "~> 0.1 or ~> 1.0", [hex: :castore, repo: "hexpm", optional: true]}, {:certifi, "~> 2.5", [hex: :certifi, repo: "hexpm", optional: true]}, {:decimal, "~> 1.9 or ~> 2.0", [hex: :decimal, repo: "hexpm", optional: false]}], "hexpm", "40083cd9a5d187f12d675cfeeb39285f0d43e7b7f2143765161b72205d57ffb5"},
+  "cldr_utils": {:hex, :cldr_utils, "2.29.1", "11ff0a50a36a7e5f3bd9fc2fb8486a4c1bcca3081d9c080bf9e48fe0e6742e2d", [:mix], [{:castore, "~> 0.1 or ~> 1.0", [hex: :castore, repo: "hexpm", optional: true]}, {:certifi, "~> 2.5", [hex: :certifi, repo: "hexpm", optional: true]}, {:decimal, "~> 1.9 or ~> 2.0", [hex: :decimal, repo: "hexpm", optional: false]}], "hexpm", "3844a0a0ed7f42e6590ddd8bd37eb4b1556b112898f67dea3ba068c29aabd6c2"},
   "con_cache": {:hex, :con_cache, "1.1.1", "9f47a68dfef5ac3bbff8ce2c499869dbc5ba889dadde6ac4aff8eb78ddaf6d82", [:mix], [{:telemetry, "~> 1.0", [hex: :telemetry, repo: "hexpm", optional: false]}], "hexpm", "1def4d1bec296564c75b5bbc60a19f2b5649d81bfa345a2febcc6ae380e8ae15"},
-  "credo": {:hex, :credo, "1.7.12", "9e3c20463de4b5f3f23721527fcaf16722ec815e70ff6c60b86412c695d426c1", [:mix], [{:bunt, "~> 0.2.1 or ~> 1.0", [hex: :bunt, repo: "hexpm", optional: false]}, {:file_system, "~> 0.2 or ~> 1.0", [hex: :file_system, repo: "hexpm", optional: false]}, {:jason, "~> 1.0", [hex: :jason, repo: "hexpm", optional: false]}], "hexpm", "8493d45c656c5427d9c729235b99d498bd133421f3e0a683e5c1b561471291e5"},
+  "credo": {:hex, :credo, "1.7.15", "283da72eeb2fd3ccf7248f4941a0527efb97afa224bcdef30b4b580bc8258e1c", [:mix], [{:bunt, "~> 0.2.1 or ~> 1.0", [hex: :bunt, repo: "hexpm", optional: false]}, {:file_system, "~> 0.2 or ~> 1.0", [hex: :file_system, repo: "hexpm", optional: false]}, {:jason, "~> 1.0", [hex: :jason, repo: "hexpm", optional: false]}], "hexpm", "291e8645ea3fea7481829f1e1eb0881b8395db212821338e577a90bf225c5607"},
   "decimal": {:hex, :decimal, "2.3.0", "3ad6255aa77b4a3c4f818171b12d237500e63525c2fd056699967a3e7ea20f62", [:mix], [], "hexpm", "a4d66355cb29cb47c3cf30e71329e58361cfcb37c34235ef3bf1d7bf3773aeac"},
   "earmark_parser": {:hex, :earmark_parser, "1.4.44", "f20830dd6b5c77afe2b063777ddbbff09f9759396500cdbe7523efd58d7a339c", [:mix], [], "hexpm", "4778ac752b4701a5599215f7030989c989ffdc4f6df457c5f36938cc2d2a2750"},
-  "ex_cldr": {:hex, :ex_cldr, "2.43.0", "8700031e30a03501cf65f7ba7c8287bb67339d03559f3108f3c54fe86d926b19", [:mix], [{:cldr_utils, "~> 2.28", [hex: :cldr_utils, repo: "hexpm", optional: false]}, {:decimal, "~> 1.6 or ~> 2.0", [hex: :decimal, repo: "hexpm", optional: false]}, {:gettext, "~> 0.19", [hex: :gettext, repo: "hexpm", optional: true]}, {:jason, "~> 1.0", [hex: :jason, repo: "hexpm", optional: true]}, {:nimble_parsec, "~> 0.5 or ~> 1.0", [hex: :nimble_parsec, repo: "hexpm", optional: true]}], "hexpm", "1524eb01275b89473ee5f53fcc6169bae16e4a5267ef109229f37694799e0b20"},
+  "ex_cldr": {:hex, :ex_cldr, "2.44.1", "0d220b175874e1ce77a0f7213bdfe700b9be11aefbf35933a0e98837803ebdc5", [:mix], [{:cldr_utils, "~> 2.28", [hex: :cldr_utils, repo: "hexpm", optional: false]}, {:decimal, "~> 1.6 or ~> 2.0", [hex: :decimal, repo: "hexpm", optional: false]}, {:gettext, "~> 0.19 or ~> 1.0", [hex: :gettext, repo: "hexpm", optional: true]}, {:jason, "~> 1.0", [hex: :jason, repo: "hexpm", optional: true]}, {:nimble_parsec, "~> 0.5 or ~> 1.0", [hex: :nimble_parsec, repo: "hexpm", optional: true]}], "hexpm", "3880cd6137ea21c74250cd870d3330c4a9fdec07fabd5e37d1b239547929e29b"},
   "ex_doc": {:hex, :ex_doc, "0.39.3", "519c6bc7e84a2918b737aec7ef48b96aa4698342927d080437f61395d361dcee", [:mix], [{:earmark_parser, "~> 1.4.44", [hex: :earmark_parser, repo: "hexpm", optional: false]}, {:makeup_c, ">= 0.1.0", [hex: :makeup_c, repo: "hexpm", optional: true]}, {:makeup_elixir, "~> 0.14 or ~> 1.0", [hex: :makeup_elixir, repo: "hexpm", optional: false]}, {:makeup_erlang, "~> 0.1 or ~> 1.0", [hex: :makeup_erlang, repo: "hexpm", optional: false]}, {:makeup_html, ">= 0.1.0", [hex: :makeup_html, repo: "hexpm", optional: true]}], "hexpm", "0590955cf7ad3b625780ee1c1ea627c28a78948c6c0a9b0322bd976a079996e1"},
-  "file_system": {:hex, :file_system, "1.1.0", "08d232062284546c6c34426997dd7ef6ec9f8bbd090eb91780283c9016840e8f", [:mix], [], "hexpm", "bfcf81244f416871f2a2e15c1b515287faa5db9c6bcf290222206d120b3d43f6"},
+  "file_system": {:hex, :file_system, "1.1.1", "31864f4685b0148f25bd3fbef2b1228457c0c89024ad67f7a81a3ffbc0bbad3a", [:mix], [], "hexpm", "7a15ff97dfe526aeefb090a7a9d3d03aa907e100e262a0f8f7746b78f8f87a5d"},
   "finch": {:hex, :finch, "0.20.0", "5330aefb6b010f424dcbbc4615d914e9e3deae40095e73ab0c1bb0968933cadf", [:mix], [{:mime, "~> 1.0 or ~> 2.0", [hex: :mime, repo: "hexpm", optional: false]}, {:mint, "~> 1.6.2 or ~> 1.7", [hex: :mint, repo: "hexpm", optional: false]}, {:nimble_options, "~> 0.4 or ~> 1.0", [hex: :nimble_options, repo: "hexpm", optional: false]}, {:nimble_pool, "~> 1.1", [hex: :nimble_pool, repo: "hexpm", optional: false]}, {:telemetry, "~> 0.4 or ~> 1.0", [hex: :telemetry, repo: "hexpm", optional: false]}], "hexpm", "2658131a74d051aabfcba936093c903b8e89da9a1b63e430bee62045fa9b2ee2"},
   "hpax": {:hex, :hpax, "1.0.3", "ed67ef51ad4df91e75cc6a1494f851850c0bd98ebc0be6e81b026e765ee535aa", [:mix], [], "hexpm", "8eab6e1cfa8d5918c2ce4ba43588e894af35dbd8e91e6e55c817bca5847df34a"},
   "jason": {:hex, :jason, "1.4.4", "b9226785a9aa77b6857ca22832cffa5d5011a667207eb2a0ad56adb5db443b8a", [:mix], [{:decimal, "~> 1.0 or ~> 2.0", [hex: :decimal, repo: "hexpm", optional: true]}], "hexpm", "c5eb0cab91f094599f94d55bc63409236a8ec69a21a67814529e8d5f6cc90b3b"},
-  "jose": {:hex, :jose, "1.11.10", "a903f5227417bd2a08c8a00a0cbcc458118be84480955e8d251297a425723f83", [:mix, :rebar3], [], "hexpm", "0d6cd36ff8ba174db29148fc112b5842186b68a90ce9fc2b3ec3afe76593e614"},
+  "jose": {:hex, :jose, "1.11.12", "06e62b467b61d3726cbc19e9b5489f7549c37993de846dfb3ee8259f9ed208b3", [:mix, :rebar3], [], "hexpm", "31e92b653e9210b696765cdd885437457de1add2a9011d92f8cf63e4641bab7b"},
   "makeup": {:hex, :makeup, "1.2.1", "e90ac1c65589ef354378def3ba19d401e739ee7ee06fb47f94c687016e3713d1", [:mix], [{:nimble_parsec, "~> 1.4", [hex: :nimble_parsec, repo: "hexpm", optional: false]}], "hexpm", "d36484867b0bae0fea568d10131197a4c2e47056a6fbe84922bf6ba71c8d17ce"},
   "makeup_elixir": {:hex, :makeup_elixir, "1.0.1", "e928a4f984e795e41e3abd27bfc09f51db16ab8ba1aebdba2b3a575437efafc2", [:mix], [{:makeup, "~> 1.0", [hex: :makeup, repo: "hexpm", optional: false]}, {:nimble_parsec, "~> 1.2.3 or ~> 1.3", [hex: :nimble_parsec, repo: "hexpm", optional: false]}], "hexpm", "7284900d412a3e5cfd97fdaed4f5ed389b8f2b4cb49efc0eb3bd10e2febf9507"},
   "makeup_erlang": {:hex, :makeup_erlang, "1.0.2", "03e1804074b3aa64d5fad7aa64601ed0fb395337b982d9bcf04029d68d51b6a7", [:mix], [{:makeup, "~> 1.0", [hex: :makeup, repo: "hexpm", optional: false]}], "hexpm", "af33ff7ef368d5893e4a267933e7744e46ce3cf1f61e2dccf53a111ed3aa3727"},
   "mime": {:hex, :mime, "2.0.7", "b8d739037be7cd402aee1ba0306edfdef982687ee7e9859bee6198c1e7e2f128", [:mix], [], "hexpm", "6171188e399ee16023ffc5b76ce445eb6d9672e2e241d2df6050f3c771e80ccd"},
   "mint": {:hex, :mint, "1.7.1", "113fdb2b2f3b59e47c7955971854641c61f378549d73e829e1768de90fc1abf1", [:mix], [{:castore, "~> 0.1.0 or ~> 1.0", [hex: :castore, repo: "hexpm", optional: true]}, {:hpax, "~> 0.1.1 or ~> 0.2.0 or ~> 1.0", [hex: :hpax, repo: "hexpm", optional: false]}], "hexpm", "fceba0a4d0f24301ddee3024ae116df1c3f4bb7a563a731f45fdfeb9d39a231b"},
   "multiformats_ex": {:hex, :multiformats_ex, "0.2.0", "5b0a3faa1a770dc671aa8a89b6323cc20b0ecf67dc93dcd21312151fbea6b4ee", [:mix], [{:varint, "~> 1.4", [hex: :varint, repo: "hexpm", optional: false]}], "hexpm", "aa406d9addb06dc197e0e92212992486af6599158d357680f29f2d11e08d0423"},
+  "mutex": {:hex, :mutex, "3.0.2", "528877fd0dbc09fc93ad667e10ea0d35a2126fa85205822f9dca85e87d732245", [:mix], [], "hexpm", "0a8f2ed3618160dca6a1e3520b293dc3c2ae53116265e71b4a732d35d29aa3c6"},
   "nimble_options": {:hex, :nimble_options, "1.1.1", "e3a492d54d85fc3fd7c5baf411d9d2852922f66e69476317787a7b2bb000a61b", [:mix], [], "hexpm", "821b2470ca9442c4b6984882fe9bb0389371b8ddec4d45a9504f00a66f650b44"},
   "nimble_parsec": {:hex, :nimble_parsec, "1.4.2", "8efba0122db06df95bfaa78f791344a89352ba04baedd3849593bfce4d0dc1c6", [:mix], [], "hexpm", "4b21398942dda052b403bbe1da991ccd03a053668d147d53fb8c4e0efe09c973"},
   "nimble_pool": {:hex, :nimble_pool, "1.1.0", "bf9c29fbdcba3564a8b800d1eeb5a3c58f36e1e11d7b7fb2e084a643f645f06b", [:mix], [], "hexpm", "af2e4e6b34197db81f7aad230c1118eac993acc0dae6bc83bac0126d4ae0813a"},
-  "peri": {:hex, :peri, "0.6.1", "6a90ca728a27aef8fef37ce307444255d20364b0c8f8d39e52499d8d825cb514", [:mix], [{:ecto, "~> 3.12", [hex: :ecto, repo: "hexpm", optional: true]}, {:jason, "~> 1.0", [hex: :jason, repo: "hexpm", optional: true]}, {:stream_data, "~> 1.1", [hex: :stream_data, repo: "hexpm", optional: true]}], "hexpm", "e20ffc659967baf9c4f28799fe7302b656d6662a8b3db7646fdafd017e192743"},
-  "plug": {:hex, :plug, "1.18.1", "5067f26f7745b7e31bc3368bc1a2b818b9779faa959b49c934c17730efc911cf", [:mix], [{:mime, "~> 1.0 or ~> 2.0", [hex: :mime, repo: "hexpm", optional: false]}, {:plug_crypto, "~> 1.1.1 or ~> 1.2 or ~> 2.0", [hex: :plug_crypto, repo: "hexpm", optional: false]}, {:telemetry, "~> 0.4.3 or ~> 1.0", [hex: :telemetry, repo: "hexpm", optional: false]}], "hexpm", "57a57db70df2b422b564437d2d33cf8d33cd16339c1edb190cd11b1a3a546cc2"},
+  "peri": {:hex, :peri, "0.6.2", "3c043bfb6aa18eb1ea41d80981d19294c5e943937b1311e8e958da3581139061", [:mix], [{:ecto, "~> 3.12", [hex: :ecto, repo: "hexpm", optional: true]}, {:jason, "~> 1.0", [hex: :jason, repo: "hexpm", optional: true]}, {:stream_data, "~> 1.1", [hex: :stream_data, repo: "hexpm", optional: true]}], "hexpm", "5e0d8e0bd9de93d0f8e3ad6b9a5bd143f7349c025196ef4a3591af93ce6ecad9"},
+  "plug": {:hex, :plug, "1.19.1", "09bac17ae7a001a68ae393658aa23c7e38782be5c5c00c80be82901262c394c0", [:mix], [{:mime, "~> 1.0 or ~> 2.0", [hex: :mime, repo: "hexpm", optional: false]}, {:plug_crypto, "~> 1.1.1 or ~> 1.2 or ~> 2.0", [hex: :plug_crypto, repo: "hexpm", optional: false]}, {:telemetry, "~> 0.4.3 or ~> 1.0", [hex: :telemetry, repo: "hexpm", optional: false]}], "hexpm", "560a0017a8f6d5d30146916862aaf9300b7280063651dd7e532b8be168511e62"},
   "plug_crypto": {:hex, :plug_crypto, "2.1.1", "19bda8184399cb24afa10be734f84a16ea0a2bc65054e23a62bb10f06bc89491", [:mix], [], "hexpm", "6470bce6ffe41c8bd497612ffde1a7e4af67f36a15eea5f921af71cf3e11247c"},
-  "recase": {:hex, :recase, "0.9.0", "437982693fdfbec125f11c8868eb3b4d32e9aa6995d3a68ac8686f3e2bf5d8d1", [:mix], [], "hexpm", "efa7549ebd128988d1723037a6f6a61948055aec107db6288f1c52830cb6501c"},
-  "req": {:hex, :req, "0.5.15", "662020efb6ea60b9f0e0fac9be88cd7558b53fe51155a2d9899de594f9906ba9", [:mix], [{:brotli, "~> 0.3.1", [hex: :brotli, repo: "hexpm", optional: true]}, {:ezstd, "~> 1.0", [hex: :ezstd, repo: "hexpm", optional: true]}, {:finch, "~> 0.17", [hex: :finch, repo: "hexpm", optional: false]}, {:jason, "~> 1.0", [hex: :jason, repo: "hexpm", optional: false]}, {:mime, "~> 2.0.6 or ~> 2.1", [hex: :mime, repo: "hexpm", optional: false]}, {:nimble_csv, "~> 1.0", [hex: :nimble_csv, repo: "hexpm", optional: true]}, {:plug, "~> 1.0", [hex: :plug, repo: "hexpm", optional: true]}], "hexpm", "a6513a35fad65467893ced9785457e91693352c70b58bbc045b47e5eb2ef0c53"},
+  "recase": {:hex, :recase, "0.9.1", "82d2e2e2d4f9e92da1ce5db338ede2e4f15a50ac1141fc082b80050b9f49d96e", [:mix], [], "hexpm", "19ba03ceb811750e6bec4a015a9f9e45d16a8b9e09187f6d72c3798f454710f3"},
+  "req": {:hex, :req, "0.5.16", "99ba6a36b014458e52a8b9a0543bfa752cb0344b2a9d756651db1281d4ba4450", [:mix], [{:brotli, "~> 0.3.1", [hex: :brotli, repo: "hexpm", optional: true]}, {:ezstd, "~> 1.0", [hex: :ezstd, repo: "hexpm", optional: true]}, {:finch, "~> 0.17", [hex: :finch, repo: "hexpm", optional: false]}, {:jason, "~> 1.0", [hex: :jason, repo: "hexpm", optional: false]}, {:mime, "~> 2.0.6 or ~> 2.1", [hex: :mime, repo: "hexpm", optional: false]}, {:nimble_csv, "~> 1.0", [hex: :nimble_csv, repo: "hexpm", optional: true]}, {:plug, "~> 1.0", [hex: :plug, repo: "hexpm", optional: true]}], "hexpm", "974a7a27982b9b791df84e8f6687d21483795882a7840e8309abdbe08bb06f09"},
   "telemetry": {:hex, :telemetry, "1.3.0", "fedebbae410d715cf8e7062c96a1ef32ec22e764197f70cda73d82778d61e7a2", [:rebar3], [], "hexpm", "7015fc8919dbe63764f4b4b87a95b7c0996bd539e0d499be6ec9d7f3875b79e6"},
-  "thousand_island": {:hex, :thousand_island, "1.4.1", "8df065e627407e281f7935da5ad0f3842d10eb721afa92e760b720d71e2e37aa", [:mix], [{:telemetry, "~> 0.4 or ~> 1.0", [hex: :telemetry, repo: "hexpm", optional: false]}], "hexpm", "204a8640e5d2818589b87286ae66160978628d7edf6095181cbe0440765fb6c1"},
+  "thousand_island": {:hex, :thousand_island, "1.4.3", "2158209580f633be38d43ec4e3ce0a01079592b9657afff9080d5d8ca149a3af", [:mix], [{:telemetry, "~> 0.4 or ~> 1.0", [hex: :telemetry, repo: "hexpm", optional: false]}], "hexpm", "6e4ce09b0fd761a58594d02814d40f77daff460c48a7354a15ab353bb998ea0b"},
   "typedstruct": {:hex, :typedstruct, "0.5.4", "d1d33d58460a74f413e9c26d55e66fd633abd8ac0fb12639add9a11a60a0462a", [:make, :mix], [], "hexpm", "ffaef36d5dbaebdbf4ed07f7fb2ebd1037b2c1f757db6fb8e7bcbbfabbe608d8"},
   "varint": {:hex, :varint, "1.5.1", "17160c70d0428c3f8a7585e182468cac10bbf165c2360cf2328aaa39d3fb1795", [:mix], [], "hexpm", "24f3deb61e91cb988056de79d06f01161dd01be5e0acae61d8d936a552f1be73"},
   "websock": {:hex, :websock, "0.5.3", "2f69a6ebe810328555b6fe5c831a851f485e303a7c8ce6c5f675abeb20ebdadc", [:mix], [], "hexpm", "6105453d7fac22c712ad66fab1d45abdf049868f253cf719b625151460b8b453"},