{
  description = "LightControl Fullstack (Backend + Frontend)";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-26.05";
  };

  outputs =
    { self, nixpkgs }:
    let
      system = "x86_64-linux";
      pnpm = pkgs.pnpm_11;
      pkgs = import nixpkgs { inherit system; };
    in
    {
      packages.${system} = {
        frontend = pkgs.stdenv.mkDerivation (finalAttrs: {
          pname = "lightcontrol-frontend";
          version = "0.1.0";

          src = ./frontend;

          nativeBuildInputs = [
            pkgs.nodejs
            pkgs.pnpmConfigHook
            pkgs.pnpm
          ];

          pnpmDeps = pkgs.fetchPnpmDeps {
            inherit (finalAttrs) pname version src;
            inherit pnpm;
            fetcherVersion = 4;
            hash = "sha256-A1dHpsdnFfyBtHD/ISi4eIrGBUOaEHNdr6woilv7wRI=";
          };

          buildPhase = ''
            runHook preBuild
            pnpm build
            runHook postBuild
          '';

          installPhase = ''
            runHook preInstall
            mkdir -p $out
            cp -r dist/* $out/
            runHook postInstall
          '';
        });

        backend = pkgs.rustPlatform.buildRustPackage {
          pname = "lightcontrol-backend";
          version = "0.1.0";

          src = ./.;
          cargoRoot = "backend";
          buildAndTestSubdir = "backend";

          cargoHash = "sha256-awHuxbv9Qlhh79hxxgsT8yJcNcBRcmF/aa/GyHoKS1g=";
        };
      };
    };
}