tjh.dev
Clone of https://github.com/NixOS/nixpkgs.git (to stress-test knotserver)
1# Used in the generation of package search database.
2{
3 # Ensures no aliases are in the results.
4 allowAliases = false;
5
6 # Enable recursion into attribute sets that nix-env normally doesn't look into
7 # so that we can get a more complete picture of the available packages for the
8 # purposes of the index.
9 packageOverrides =
10 super:
11 with super;
12 lib.mapAttrs (_: set: recurseIntoAttrs set) {
13 inherit (super)
14 agdaPackages
15 apacheHttpdPackages
16 fusePackages
17 gns3Packages
18 haskellPackages
19 idrisPackages
20 nodePackages
21 nodePackages_latest
22 platformioPackages
23 rPackages
24 roundcubePlugins
25 sourceHanPackages
26 zabbix60
27 windows
28 ;
29
30 # Make sure haskell.compiler is included, so alternative GHC versions show up,
31 # but don't add haskell.packages.* since they contain the same packages (at
32 # least by name) as haskellPackages.
33 haskell = super.haskell // {
34 compiler = recurseIntoAttrs super.haskell.compiler;
35 };
36
37 # emacsPackages is an alias for emacs.pkgs
38 # Re-introduce emacsPackages here so that emacs.pkgs can be searched.
39 emacsPackages = emacs.pkgs;
40
41 # minimal-bootstrap packages aren't used for anything but bootstrapping our
42 # stdenv. They should not be used for any other purpose and therefore not
43 # show up in search results or repository tracking services that consume our
44 # packages.json https://github.com/NixOS/nixpkgs/issues/244966
45 minimal-bootstrap = { };
46
47 # This makes it so that tests are not appering on search.nixos.org
48 tests = { };
49 };
50}