tjh.dev
Clone of https://github.com/NixOS/nixpkgs.git (to stress-test knotserver)
1############################################################################
2# This file mainly provides the `mathcomp` derivation, which is #
3# essentially a meta-package containing all core mathcomp libraries #
4# (ssreflect fingroup algebra solvable field character). They can be #
5# accessed individually through the passthrough attributes of mathcomp #
6# bearing the same names (mathcomp.ssreflect, etc). #
7############################################################################
8# Compiling a custom version of mathcomp using `mathcomp.override`. #
9# This is the replacement for the former `mathcomp_ config` function. #
10# See the documentation at doc/languages-frameworks/coq.section.md. #
11############################################################################
12
13{ lib, ncurses, graphviz, lua, fetchzip,
14 mkCoqDerivation, recurseIntoAttrs, withDoc ? false, single ? false,
15 coqPackages, coq, hierarchy-builder, version ? null }@args:
16with builtins // lib;
17let
18 repo = "math-comp";
19 owner = "math-comp";
20 withDoc = single && (args.withDoc or false);
21 defaultVersion = with versions; lib.switch coq.coq-version [
22 { case = isGe "8.15"; out = "1.17.0"; }
23 { case = range "8.16" "8.17"; out = "2.0.0"; }
24 { case = range "8.13" "8.17"; out = "1.16.0"; }
25 { case = range "8.14" "8.16"; out = "1.15.0"; }
26 { case = range "8.11" "8.15"; out = "1.14.0"; }
27 { case = range "8.11" "8.15"; out = "1.13.0"; }
28 { case = range "8.10" "8.13"; out = "1.12.0"; }
29 { case = range "8.7" "8.12"; out = "1.11.0"; }
30 { case = range "8.7" "8.11"; out = "1.10.0"; }
31 { case = range "8.7" "8.11"; out = "1.9.0"; }
32 { case = range "8.7" "8.9"; out = "1.8.0"; }
33 { case = range "8.6" "8.9"; out = "1.7.0"; }
34 { case = range "8.5" "8.7"; out = "1.6.4"; }
35 ] null;
36 release = {
37 "2.0.0".sha256 = "sha256-dpOmrHYUXBBS9kmmz7puzufxlbNpIZofpcTvJFLG5DI=";
38 "1.17.0".sha256 = "sha256-bUfoSTMiW/GzC1jKFay6DRqGzKPuLOSUsO6/wPSFwNg=";
39 "1.16.0".sha256 = "sha256-gXTKhRgSGeRBUnwdDezMsMKbOvxdffT+kViZ9e1gEz0=";
40 "1.15.0".sha256 = "1bp0jxl35ms54s0mdqky15w9af03f3i0n06qk12k4gw1xzvwqv21";
41 "1.14.0".sha256 = "07yamlp1c0g5nahkd2gpfhammcca74ga2s6qr7a3wm6y6j5pivk9";
42 "1.13.0".sha256 = "0j4cz2y1r1aw79snkcf1pmicgzf8swbaf9ippz0vg99a572zqzri";
43 "1.12.0".sha256 = "1ccfny1vwgmdl91kz5xlmhq4wz078xm4z5wpd0jy5rn890dx03wp";
44 "1.11.0".sha256 = "06a71d196wd5k4wg7khwqb7j7ifr7garhwkd54s86i0j7d6nhl3c";
45 "1.10.0".sha256 = "1b9m6pwxxyivw7rgx82gn5kmgv2mfv3h3y0mmjcjfypi8ydkrlbv";
46 "1.9.0".sha256 = "0lid9zaazdi3d38l8042lczb02pw5m9wq0yysiilx891hgq2p81r";
47 "1.8.0".sha256 = "07l40is389ih8bi525gpqs3qp4yb2kl11r9c8ynk1ifpjzpnabwp";
48 "1.7.0".sha256 = "0wnhj9nqpx2bw6n1l4i8jgrw3pjajvckvj3lr4vzjb3my2lbxdd1";
49 "1.6.4".sha256 = "09ww48qbjsvpjmy1g9yhm0rrkq800ffq21p6fjkbwd34qvd82raz";
50 "1.6.1".sha256 = "1ilw6vm4dlsdv9cd7kmf0vfrh2kkzr45wrqr8m37miy0byzr4p9i";
51 };
52 releaseRev = v: "mathcomp-${v}";
53
54 # list of core mathcomp packages sorted by dependency order
55 packages = [ "ssreflect" "fingroup" "algebra" "solvable" "field" "character" "all" ];
56
57 mathcomp_ = package: let
58 mathcomp-deps = if package == "single" then []
59 else map mathcomp_ (head (splitList (lib.pred.equal package) packages));
60 pkgpath = if package == "single" then "mathcomp" else "mathcomp/${package}";
61 pname = if package == "single" then "mathcomp" else "mathcomp-${package}";
62 pkgallMake = ''
63 echo "all.v" > Make
64 echo "-I ." >> Make
65 echo "-R . mathcomp.all" >> Make
66 '';
67 derivation = mkCoqDerivation ({
68 inherit version pname defaultVersion release releaseRev repo owner;
69
70 mlPlugin = versions.isLe "8.6" coq.coq-version;
71 nativeBuildInputs = optionals withDoc [ graphviz lua ];
72 buildInputs = [ ncurses ];
73 propagatedBuildInputs = mathcomp-deps;
74
75 buildFlags = optional withDoc "doc";
76
77 preBuild = ''
78 if [[ -f etc/utils/ssrcoqdep ]]
79 then patchShebangs etc/utils/ssrcoqdep
80 fi
81 if [[ -f etc/buildlibgraph ]]
82 then patchShebangs etc/buildlibgraph
83 fi
84 '' + ''
85 cd ${pkgpath}
86 '' + optionalString (package == "all") pkgallMake;
87
88 meta = {
89 homepage = "https://math-comp.github.io/";
90 license = licenses.cecill-b;
91 maintainers = with maintainers; [ vbgl jwiegley cohencyril ];
92 };
93 } // optionalAttrs (package != "single")
94 { passthru = genAttrs packages mathcomp_; }
95 // optionalAttrs withDoc {
96 htmldoc_template =
97 fetchzip {
98 url = "https://github.com/math-comp/math-comp.github.io/archive/doc-1.12.0.zip";
99 sha256 = "0y1352ha2yy6k2dl375sb1r68r1qi9dyyy7dyzj5lp9hxhhq69x8";
100 };
101 postBuild = ''
102 cp -rf _build_doc/* .
103 rm -r _build_doc
104 '';
105 postInstall =
106 let tgt = "$out/share/coq/${coq.coq-version}/"; in
107 optionalString withDoc ''
108 mkdir -p ${tgt}
109 cp -r htmldoc ${tgt}
110 cp -r $htmldoc_template/htmldoc_template/* ${tgt}/htmldoc/
111 '';
112 buildTargets = "doc";
113 extraInstallFlags = [ "-f Makefile.coq" ];
114 });
115 patched-derivation1 = derivation.overrideAttrs (o:
116 optionalAttrs (o.pname != null && o.pname == "mathcomp-all" &&
117 o.version != null && o.version != "dev" && versions.isLt "1.7" o.version)
118 { preBuild = ""; buildPhase = ""; installPhase = "echo doing nothing"; }
119 );
120 patched-derivation2 = patched-derivation1.overrideAttrs (o:
121 optionalAttrs (versions.isLe "8.7" coq.coq-version ||
122 (o.version != "dev" && versions.isLe "1.7" o.version))
123 {
124 installFlags = o.installFlags ++ [ "-f Makefile.coq" ];
125 }
126 );
127 patched-derivation = patched-derivation2.overrideAttrs (o:
128 optionalAttrs (o.version != null
129 && (o.version == "dev" || versions.isGe "2.0.0" o.version))
130 {
131 propagatedBuildInputs = o.propagatedBuildInputs ++ [ hierarchy-builder ];
132 }
133 );
134 in patched-derivation;
135in
136mathcomp_ (if single then "single" else "all")