tjh.dev
1# Experimental flake interface to Nixpkgs.
2# See https://github.com/NixOS/rfcs/pull/49 for details.
3{
4 description = "A collection of packages for the Nix package manager";
5
6 outputs = { self }:
7 let
8
9 jobs = import ./pkgs/top-level/release.nix {
10 nixpkgs = self;
11 };
12
13 lib = import ./lib;
14
15 systems = [ "x86_64-linux" "i686-linux" "x86_64-darwin" "aarch64-linux" ];
16
17 forAllSystems = f: lib.genAttrs systems (system: f system);
18
19 in
20 {
21 lib = lib // {
22 nixosSystem = { modules, ... } @ args:
23 import ./nixos/lib/eval-config.nix (args // {
24 modules = modules ++
25 [ { system.nixos.versionSuffix =
26 ".${lib.substring 0 8 (self.lastModifiedDate or self.lastModified)}.${self.shortRev or "dirty"}";
27 system.nixos.revision = lib.mkIf (self ? rev) self.rev;
28 }
29 ];
30 });
31 };
32
33 checks.x86_64-linux.tarball = jobs.tarball;
34
35 htmlDocs = {
36 nixpkgsManual = jobs.manual;
37 nixosManual = (import ./nixos/release-small.nix {
38 nixpkgs = self;
39 }).nixos.manual.x86_64-linux;
40 };
41
42 legacyPackages = forAllSystems (system: import ./. { inherit system; });
43
44 nixosModules = {
45 notDetected = import ./nixos/modules/installer/scan/not-detected.nix;
46 };
47 };
48}