tjh.dev
1# To enable specific database drivers, override this derivation and pass the
2# driver packages in the drivers argument (e.g. mysql_jdbc, postgresql_jdbc).
3{ stdenv, fetchurl, makeDesktopItem, makeWrapper, unzip
4, jre
5, drivers ? []
6}:
7let
8 version = "3.9.0";
9in stdenv.mkDerivation rec {
10 name = "squirrel-sql-${version}";
11
12 src = fetchurl {
13 url = "mirror://sourceforge/project/squirrel-sql/1-stable/${version}-plainzip/squirrelsql-${version}-standard.zip";
14 sha256 = "0b16l7p7klagxnwkx2az4mbyd35kv4aj8xxbwm27pp3spz9dk8m0";
15 };
16
17 nativeBuildInputs = [ makeWrapper unzip ];
18 buildInputs = [ jre ];
19
20 unpackPhase = ''
21 runHook preUnpack
22 unzip ${src}
23 runHook postUnpack
24 '';
25
26 buildPhase = ''
27 runHook preBuild
28 cd squirrelsql-${version}-standard
29 chmod +x squirrel-sql.sh
30 runHook postBuild
31 '';
32
33 installPhase = ''
34 runHook preInstall
35
36 mkdir -p $out/share/squirrel-sql
37 cp -r . $out/share/squirrel-sql
38
39 mkdir -p $out/bin
40 cp=""
41 for pkg in ${builtins.concatStringsSep " " drivers}; do
42 if test -n "$cp"; then
43 cp="$cp:"
44 fi
45 cp="$cp"$(echo $pkg/share/java/*.jar | tr ' ' :)
46 done
47 makeWrapper $out/share/squirrel-sql/squirrel-sql.sh $out/bin/squirrel-sql \
48 --set CLASSPATH "$cp" \
49 --set JAVA_HOME "${jre}"
50
51 mkdir -p $out/share/icons/hicolor/32x32/apps
52 ln -s $out/share/squirrel-sql/icons/acorn.png \
53 $out/share/icons/hicolor/32x32/apps/squirrel-sql.png
54 ln -s ${desktopItem}/share/applications $out/share
55
56 runHook postInstall
57 '';
58
59 desktopItem = makeDesktopItem {
60 name = "squirrel-sql";
61 exec = "squirrel-sql";
62 comment = meta.description;
63 desktopName = "SQuirreL SQL";
64 genericName = "SQL Client";
65 categories = "Development;";
66 icon = "squirrel-sql";
67 };
68
69 meta = with stdenv.lib; {
70 description = "Universal SQL Client";
71 homepage = http://squirrel-sql.sourceforge.net/;
72 license = licenses.lgpl21;
73 platforms = platforms.linux;
74 maintainers = with maintainers; [ khumba ];
75 };
76}