tjh.dev
1{ lib
2, python
3}:
4
5let
6 py = python.override {
7 packageOverrides = self: super: {
8 click = super.click.overridePythonAttrs (oldAttrs: rec {
9 version = "6.7";
10 src = oldAttrs.src.override {
11 inherit version;
12 sha256 = "f15516df478d5a56180fbf80e68f206010e6d160fc39fa508b65e035fd75130b";
13 };
14 });
15
16 requests = super.requests.overridePythonAttrs (oldAttrs: rec {
17 version = "2.20.1";
18 src = oldAttrs.src.override {
19 inherit version;
20 sha256 = "ea881206e59f41dbd0bd445437d792e43906703fff75ca8ff43ccdb11f33f263";
21 };
22 });
23
24 idna = super.idna.overridePythonAttrs (oldAttrs: rec {
25 version = "2.7";
26 src = oldAttrs.src.override {
27 inherit version;
28 sha256 = "684a38a6f903c1d71d6d5fac066b58d7768af4de2b832e426ec79c30daa94a16";
29 };
30 });
31
32 six = super.six.overridePythonAttrs (oldAttrs: rec {
33 version = "1.11";
34 src = oldAttrs.src.override {
35 inherit version;
36 sha256 = "70e8a77beed4562e7f14fe23a786b54f6296e34344c23bc42f07b15018ff98e9";
37 };
38 });
39 };
40 };
41
42in
43
44with py.pkgs;
45
46buildPythonApplication rec {
47 pname = "aws-sam-cli";
48 version = "0.14.2";
49
50 src = fetchPypi {
51 inherit pname version;
52 sha256 = "b7f80838d57c1096a9a03ed703a91a8a5775a6ead33df8f31765ecf39b3a956f";
53 };
54
55 # Tests are not included in the PyPI package
56 doCheck = false;
57
58 propagatedBuildInputs = [
59 aws-lambda-builders
60 aws-sam-translator
61 chevron
62 click
63 cookiecutter
64 dateparser
65 docker
66 flask
67 idna
68 pathlib2
69 requests
70 serverlessrepo
71 six
72 ];
73
74 meta = with lib; {
75 homepage = https://github.com/awslabs/aws-sam-cli;
76 description = "CLI tool for local development and testing of Serverless applications";
77 license = licenses.asl20;
78 maintainers = with maintainers; [ andreabedini dhkl ];
79 };
80}