tjh.dev
1{ stdenv, fetchurl, cmake, alsaLib, atk, cairo, cups, dbus, expat, fontconfig
2, GConf, gdk_pixbuf, glib, gtk2, libX11, libxcb, libXcomposite, libXcursor
3, libXdamage, libXext, libXfixes, libXi, libXrandr, libXrender, libXScrnSaver
4, libXtst, nspr, nss, pango, libpulseaudio, systemd }:
5
6let
7 libPath =
8 stdenv.lib.makeLibraryPath [
9 alsaLib atk cairo cups dbus expat fontconfig GConf gdk_pixbuf glib gtk2
10 libX11 libxcb libXcomposite libXcursor libXdamage libXext libXfixes libXi
11 libXrandr libXrender libXScrnSaver libXtst nspr nss pango libpulseaudio
12 systemd
13 ];
14in
15stdenv.mkDerivation rec {
16 name = "cef-binary-${version}";
17 version = "3.3497.1833.g13f506f";
18 src = fetchurl {
19 url = "http://opensource.spotify.com/cefbuilds/cef_binary_${version}_linux64.tar.bz2";
20 sha256 = "02v22yx1ga2yxagjblzkfw0ax7zkrdpc959l1a15m8nah3y7xf9p";
21 };
22 nativeBuildInputs = [ cmake ];
23 makeFlags = "libcef_dll_wrapper";
24 dontStrip = true;
25 dontPatchELF = true;
26 installPhase = ''
27 mkdir -p $out/lib/ $out/share/cef/
28 cp libcef_dll_wrapper/libcef_dll_wrapper.a $out/lib/
29 cp ../Release/libcef.so $out/lib/
30 patchelf --set-rpath "${libPath}" $out/lib/libcef.so
31 cp ../Release/*.bin $out/share/cef/
32 cp -r ../Resources/* $out/share/cef/
33 cp -r ../include $out/
34 '';
35
36 meta = with stdenv.lib; {
37 description = "Simple framework for embedding Chromium-based browsers in other applications";
38 homepage = http://opensource.spotify.com/cefbuilds/index.html;
39 maintainers = with maintainers; [ puffnfresh ];
40 license = licenses.bsd3;
41 platforms = with platforms; linux;
42 };
43}