tjh.dev
1{ majorVersion
2, minorVersion
3, maintenanceVersion
4, src_sha256
5# source deps
6, libuvVersion
7, libuvSha256
8}:
9{ stdenv, fetchurl, fetchzip
10# build tools
11, gfortran, m4, makeWrapper, patchelf, perl, which, python2
12, llvm, cmake
13# libjulia dependencies
14, libunwind, readline, utf8proc, zlib
15# standard library dependencies
16, curl, fftwSinglePrec, fftw, gmp, libgit2, mpfr, openlibm, openspecfun, pcre2
17# linear algebra
18, openblas, arpack
19# Darwin frameworks
20, CoreServices, ApplicationServices
21}:
22
23with stdenv.lib;
24
25# All dependencies must use the same OpenBLAS.
26let
27 arpack_ = arpack;
28in
29let
30 arpack = arpack_.override { inherit openblas; };
31in
32
33let
34 dsfmtVersion = "2.2.3";
35 dsfmt = fetchurl {
36 url = "http://www.math.sci.hiroshima-u.ac.jp/~m-mat/MT/SFMT/dSFMT-src-${dsfmtVersion}.tar.gz";
37 sha256 = "03kaqbjbi6viz0n33dk5jlf6ayxqlsq4804n7kwkndiga9s4hd42";
38 };
39
40 libuv = fetchurl {
41 url = "https://api.github.com/repos/JuliaLang/libuv/tarball/${libuvVersion}";
42 sha256 = libuvSha256;
43 };
44
45 rmathVersion = "0.1";
46 rmath-julia = fetchurl {
47 url = "https://api.github.com/repos/JuliaLang/Rmath-julia/tarball/v${rmathVersion}";
48 sha256 = "1qyps217175qhid46l8f5i1v8i82slgp23ia63x2hzxwfmx8617p";
49 };
50
51 virtualenvVersion = "15.0.0";
52 virtualenv = fetchurl {
53 url = "mirror://pypi/v/virtualenv/virtualenv-${virtualenvVersion}.tar.gz";
54 sha256 = "06fw4liazpx5vf3am45q2pdiwrv0id7ckv7n6zmpml29x6vkzmkh";
55 };
56
57 libwhichVersion = "81e9723c0273d78493dc8c8ed570f68d9ce7e89e";
58 libwhich = fetchurl {
59 url = "https://api.github.com/repos/vtjnash/libwhich/tarball/${libwhichVersion}";
60 sha256 = "1p7zg31kpmpbmh1znrk1xrbd074agx13b9q4dcw8n2zrwwdlbz3b";
61 };
62
63 llvmVersion = "6.0.0";
64 llvm = fetchurl {
65 url = "http://releases.llvm.org/6.0.0/llvm-${llvmVersion}.src.tar.xz";
66 sha256 = "0224xvfg6h40y5lrbnb9qaq3grmdc5rg00xq03s1wxjfbf8krx8z";
67 };
68
69 suitesparseVersion = "4.4.5";
70 suitesparse = fetchurl {
71 url = "http://faculty.cse.tamu.edu/davis/SuiteSparse/SuiteSparse-${suitesparseVersion}.tar.gz";
72 sha256 = "1jcbxb8jx5wlcixzf6n5dca2rcfx6mlcms1k2rl5gp67ay3bix43";
73 };
74 version = "${majorVersion}.${minorVersion}.${maintenanceVersion}";
75in
76
77stdenv.mkDerivation rec {
78 pname = "julia";
79 inherit version;
80 name = "${pname}-${version}";
81
82 src = fetchzip {
83 url = "https://github.com/JuliaLang/${pname}/releases/download/v${version}/${name}.tar.gz";
84 sha256 = src_sha256;
85 };
86 prePatch = ''
87 export PATH=$PATH:${cmake}/bin
88 mkdir deps/srccache
89 cp "${dsfmt}" "./deps/srccache/dsfmt-${dsfmtVersion}.tar.gz"
90 cp "${rmath-julia}" "./deps/srccache/Rmath-julia-${rmathVersion}.tar.gz"
91 cp "${libuv}" "./deps/srccache/libuv-${libuvVersion}.tar.gz"
92 cp "${virtualenv}" "./deps/srccache/virtualenv-${virtualenvVersion}.tar.gz"
93 cp "${libwhich}" "./deps/srccache/libwhich-${libwhichVersion}.tar.gz"
94 cp "${llvm}" "./deps/srccache/llvm-${llvmVersion}.src.tar.xz"
95 cp "${suitesparse}" "./deps/srccache/SuiteSparse-${suitesparseVersion}.tar.gz"
96 '';
97
98 patches = [
99 ./0001.1-use-system-utf8proc.patch
100 ];
101
102 postPatch = ''
103 patchShebangs . contrib
104 for i in backtrace cmdlineargs; do
105 mv test/$i.jl{,.off}
106 touch test/$i.jl
107 done
108 rm stdlib/Sockets/test/runtests.jl && touch stdlib/Sockets/test/runtests.jl
109 rm stdlib/Distributed/test/runtests.jl && touch stdlib/Distributed/test/runtests.jl
110 sed -e 's/Invalid Content-Type:/invalid Content-Type:/g' -i ./stdlib/LibGit2/test/libgit2.jl
111 sed -e 's/Failed to resolve /failed to resolve /g' -i ./stdlib/LibGit2/test/libgit2.jl
112 '';
113
114 buildInputs = [
115 arpack fftw fftwSinglePrec gmp libgit2 libunwind mpfr
116 pcre2.dev openblas openlibm openspecfun readline utf8proc
117 zlib
118 ]
119 ++ stdenv.lib.optionals stdenv.isDarwin [CoreServices ApplicationServices]
120 ;
121
122 nativeBuildInputs = [ curl gfortran m4 makeWrapper patchelf perl python2 which ];
123
124 makeFlags =
125 let
126 arch = head (splitString "-" stdenv.system);
127 march = { "x86_64" = "x86-64"; "i686" = "pentium4"; }."${arch}"
128 or (throw "unsupported architecture: ${arch}");
129 # Julia requires Pentium 4 (SSE2) or better
130 cpuTarget = { "x86_64" = "x86-64"; "i686" = "pentium4"; }."${arch}"
131 or (throw "unsupported architecture: ${arch}");
132 in [
133 "ARCH=${arch}"
134 "MARCH=${march}"
135 "JULIA_CPU_TARGET=${cpuTarget}"
136 "PREFIX=$(out)"
137 "prefix=$(out)"
138 "SHELL=${stdenv.shell}"
139
140 "USE_SYSTEM_BLAS=1"
141 "USE_BLAS64=${if openblas.blas64 then "1" else "0"}"
142 "LIBBLAS=-lopenblas"
143 "LIBBLASNAME=libopenblas"
144
145 "USE_SYSTEM_LAPACK=1"
146 "LIBLAPACK=-lopenblas"
147 "LIBLAPACKNAME=libopenblas"
148
149 "USE_SYSTEM_ARPACK=1"
150 "USE_SYSTEM_FFTW=1"
151 "USE_SYSTEM_GMP=1"
152 "USE_SYSTEM_LIBGIT2=1"
153 "USE_SYSTEM_LIBUNWIND=1"
154
155 #"USE_SYSTEM_LLVM=1"
156 "LLVM_VER=6.0.0"
157
158 "USE_SYSTEM_MPFR=1"
159 "USE_SYSTEM_OPENLIBM=1"
160 "USE_SYSTEM_OPENSPECFUN=1"
161 "USE_SYSTEM_PATCHELF=1"
162 "USE_SYSTEM_PCRE=1"
163 "PCRE_CONFIG=${pcre2.dev}/bin/pcre2-config"
164 "PCRE_INCL_PATH=${pcre2.dev}/include/pcre2.h"
165 "USE_SYSTEM_READLINE=1"
166 "USE_SYSTEM_UTF8PROC=1"
167 "USE_SYSTEM_ZLIB=1"
168 ];
169
170 NIX_CFLAGS_COMPILE = [ "-fPIC" ];
171
172 LD_LIBRARY_PATH = makeLibraryPath [
173 arpack fftw fftwSinglePrec gmp libgit2 mpfr openblas openlibm
174 openspecfun pcre2
175 ];
176
177 dontStrip = true;
178 dontPatchELF = true;
179
180 enableParallelBuilding = true;
181
182 doCheck = !stdenv.isDarwin;
183 checkTarget = "testall";
184 # Julia's tests require read/write access to $HOME
185 preCheck = ''
186 export HOME="$NIX_BUILD_TOP"
187 '';
188
189 preBuild = ''
190 sed -e '/^install:/s@[^ ]*/doc/[^ ]*@@' -i Makefile
191 sed -e '/[$](DESTDIR)[$](docdir)/d' -i Makefile
192 export LD_LIBRARY_PATH=${LD_LIBRARY_PATH}
193 '';
194
195 postInstall = ''
196 # Symlink shared libraries from LD_LIBRARY_PATH into lib/julia,
197 # as using a wrapper with LD_LIBRARY_PATH causes segmentation
198 # faults when program returns an error:
199 # $ julia -e 'throw(Error())'
200 find $(echo $LD_LIBRARY_PATH | sed 's|:| |g') -maxdepth 1 -name '*.${if stdenv.isDarwin then "dylib" else "so"}*' | while read lib; do
201 if [[ ! -e $out/lib/julia/$(basename $lib) ]]; then
202 ln -sv $lib $out/lib/julia/$(basename $lib)
203 fi
204 done
205 '';
206
207 passthru = {
208 inherit majorVersion minorVersion maintenanceVersion;
209 site = "share/julia/site/v${majorVersion}.${minorVersion}";
210 };
211
212 meta = {
213 description = "High-level performance-oriented dynamical language for technical computing";
214 homepage = https://julialang.org/;
215 license = stdenv.lib.licenses.mit;
216 maintainers = with stdenv.lib.maintainers; [ raskin rob garrison ];
217 platforms = [ "i686-linux" "x86_64-linux" "x86_64-darwin" ];
218 broken = stdenv.isi686;
219 };
220}