tjh.dev
1{ stdenv, fetchurl, fetchpatch, flex, bison }:
2
3stdenv.mkDerivation rec {
4 name = "libpcap-1.8.1";
5
6 src = fetchurl {
7 url = "http://www.tcpdump.org/release/${name}.tar.gz";
8 sha256 = "07jlhc66z76dipj4j5v3dig8x6h3k6cb36kmnmpsixf3zmlvqgb7";
9 };
10
11 nativeBuildInputs = [ flex bison ];
12
13 # We need to force the autodetection because detection doesn't
14 # work in pure build enviroments.
15 configureFlags =
16 if stdenv.isLinux then [ "--with-pcap=linux" ]
17 else if stdenv.isDarwin then [ "--with-pcap=bpf" ]
18 else [];
19
20 prePatch = stdenv.lib.optionalString stdenv.isDarwin ''
21 substituteInPlace configure --replace " -arch i386" ""
22 '';
23
24 patches = [
25 (fetchpatch {
26 url = "https://sources.debian.net/data/main/libp/libpcap/1.8.1-3/debian/patches/disable-remote.diff";
27 sha256 = "0dvjax9c0spvq8cdjnkbnm65wlzaml259yragf95kzg611vszfmj";
28 })
29 # See https://github.com/wjt/bustle/commit/f62cf6bfa662af4ae39effbbd4891bc619e3b4e9
30 (fetchpatch {
31 url = "https://github.com/the-tcpdump-group/libpcap/commit/2be9c29d45fb1fab8e9549342a30c160b7dea3e1.patch";
32 sha256 = "1g8mh942vr0abn48g0bdvi4gmhq1bz0l80276603y7064qhy3wq5";
33 })
34 (fetchpatch {
35 url = "https://github.com/the-tcpdump-group/libpcap/commit/1a6b088a88886eac782008f37a7219a32b86da45.patch";
36 sha256 = "1n5ylm7ch3i1lh4y2q16b0vabgym8g8mqiqxpqcdkjdn05c1wflr";
37 })
38 ];
39
40 preInstall = ''mkdir -p $out/bin'';
41
42 crossAttrs = {
43 # Stripping hurts in static libraries
44 dontStrip = true;
45 configureFlags = configureFlags ++ [ "ac_cv_linux_vers=2" ];
46 };
47
48 meta = with stdenv.lib; {
49 homepage = http://www.tcpdump.org;
50 description = "Packet Capture Library";
51 platforms = platforms.unix;
52 maintainers = with maintainers; [ fpletz ];
53 };
54}