tjh.dev
1{ stdenv, fetchurl
2, bzip2
3, expat
4, libffi
5, gdbm
6, lzma
7, ncurses
8, openssl
9, readline
10, sqlite
11, tcl ? null, tk ? null, tix ? null, libX11 ? null, xproto ? null, x11Support ? false
12, zlib
13, callPackage
14, self
15, CF, configd
16, python-setup-hook
17# For the Python package set
18, pkgs, packageOverrides ? (self: super: {})
19}:
20
21assert x11Support -> tcl != null
22 && tk != null
23 && xproto != null
24 && libX11 != null;
25
26with stdenv.lib;
27
28let
29 majorVersion = "3.4";
30 minorVersion = "9";
31 minorVersionSuffix = "";
32 pythonVersion = majorVersion;
33 version = "${majorVersion}.${minorVersion}${minorVersionSuffix}";
34 libPrefix = "python${majorVersion}";
35 sitePackages = "lib/${libPrefix}/site-packages";
36
37 buildInputs = filter (p: p != null) [
38 zlib bzip2 expat lzma libffi gdbm sqlite readline ncurses openssl ]
39 ++ optionals x11Support [ tcl tk libX11 xproto ]
40 ++ optionals stdenv.isDarwin [ CF configd ];
41
42in stdenv.mkDerivation {
43 name = "python3-${version}";
44 pythonVersion = majorVersion;
45 inherit majorVersion version;
46
47 inherit buildInputs;
48
49 src = fetchurl {
50 url = "http://www.python.org/ftp/python/${version}/Python-${version}.tar.xz";
51 sha256 = "1n9b1kavmw8b7rc3gkrka4fjzrbfq9iqy791yncaf09bp9v9cqjr";
52 };
53
54 NIX_LDFLAGS = optionalString stdenv.isLinux "-lgcc_s";
55
56 # Determinism: The interpreter is patched to write null timestamps when compiling python files.
57 # This way python doesn't try to update them when we freeze timestamps in nix store.
58 DETERMINISTIC_BUILD=1;
59 # Determinism: We fix the hashes of str, bytes and datetime objects.
60 PYTHONHASHSEED=0;
61
62 prePatch = optionalString stdenv.isDarwin ''
63 substituteInPlace configure --replace '`/usr/bin/arch`' '"i386"'
64 substituteInPlace configure --replace '-Wl,-stack_size,1000000' ' '
65 '';
66
67 patches = [
68 ./no-ldconfig.patch
69 ./ld_library_path.patch
70 ] ++ optionals (x11Support && stdenv.isDarwin) [
71 ./use-correct-tcl-tk-on-darwin.patch
72 ];
73
74 postPatch = ''
75 # Determinism
76 substituteInPlace "Lib/py_compile.py" --replace "source_stats['mtime']" "(1 if 'DETERMINISTIC_BUILD' in os.environ else source_stats['mtime'])"
77 # Determinism. This is done unconditionally
78 substituteInPlace "Lib/importlib/_bootstrap.py" --replace "source_mtime = int(source_stats['mtime'])" "source_mtime = 1"
79 '' + optionalString (x11Support && (tix != null)) ''
80 substituteInPlace "Lib/tkinter/tix.py" --replace "os.environ.get('TIX_LIBRARY')" "os.environ.get('TIX_LIBRARY') or '${tix}/lib'"
81 ''
82 # Avoid picking up getentropy() from glibc >= 2.25, as that would break
83 # on older kernels. http://bugs.python.org/issue29157
84 + optionalString stdenv.isLinux ''
85 substituteInPlace Python/random.c --replace 'defined(HAVE_GETENTROPY)' '0'
86 cat Python/random.c
87 '';
88
89 CPPFLAGS="${concatStringsSep " " (map (p: "-I${getDev p}/include") buildInputs)}";
90 LDFLAGS="${concatStringsSep " " (map (p: "-L${getLib p}/lib") buildInputs)}";
91 LIBS="${optionalString (!stdenv.isDarwin) "-lcrypt"} ${optionalString (ncurses != null) "-lncurses"}";
92
93 configureFlags = [
94 "--enable-shared"
95 "--with-threads"
96 "--without-ensurepip"
97 "--with-system-expat"
98 "--with-system-ffi"
99 ];
100
101 preConfigure = ''
102 for i in /usr /sw /opt /pkg; do # improve purity
103 substituteInPlace ./setup.py --replace $i /no-such-path
104 done
105 ${optionalString stdenv.isDarwin ''
106 export NIX_CFLAGS_COMPILE="$NIX_CFLAGS_COMPILE -msse2"
107 export MACOSX_DEPLOYMENT_TARGET=10.6
108 ''
109 + optionalString stdenv.hostPlatform.isMusl ''
110 export NIX_CFLAGS_COMPILE+=" -DTHREAD_STACK_SIZE=0x100000"
111 ''}
112 '';
113
114 setupHook = python-setup-hook sitePackages;
115
116 postInstall = ''
117 # needed for some packages, especially packages that backport functionality
118 # to 2.x from 3.x
119 for item in $out/lib/python${majorVersion}/test/*; do
120 if [[ "$item" != */test_support.py*
121 && "$item" != */test/support
122 && "$item" != */test/libregrtest
123 && "$item" != */test/regrtest.py* ]]; then
124 rm -rf "$item"
125 else
126 echo $item
127 fi
128 done
129 touch $out/lib/python${majorVersion}/test/__init__.py
130
131 ln -s "$out/include/python${majorVersion}m" "$out/include/python${majorVersion}"
132 paxmark E $out/bin/python${majorVersion}
133
134 # Python on Nix is not manylinux1 compatible. https://github.com/NixOS/nixpkgs/issues/18484
135 echo "manylinux1_compatible=False" >> $out/lib/${libPrefix}/_manylinux.py
136
137 # Determinism: Windows installers were not deterministic.
138 # We're also not interested in building Windows installers.
139 find "$out" -name 'wininst*.exe' | xargs -r rm -f
140
141 # Use Python3 as default python
142 ln -s "$out/bin/idle3" "$out/bin/idle"
143 ln -s "$out/bin/pydoc3" "$out/bin/pydoc"
144 ln -s "$out/bin/python3" "$out/bin/python"
145 ln -s "$out/bin/python3-config" "$out/bin/python-config"
146 ln -s "$out/lib/pkgconfig/python3.pc" "$out/lib/pkgconfig/python.pc"
147
148 # Get rid of retained dependencies on -dev packages, and remove
149 # some $TMPDIR references to improve binary reproducibility.
150 # Note that the .pyc file of _sysconfigdata.py should be regenerated!
151 for i in $out/lib/python${majorVersion}/_sysconfigdata.py $out/lib/python${majorVersion}/config-${majorVersion}m/Makefile; do
152 sed -i $i -e "s|-I/nix/store/[^ ']*||g" -e "s|-L/nix/store/[^ ']*||g" -e "s|$TMPDIR|/no-such-path|g"
153 done
154
155 # Determinism: rebuild all bytecode
156 # We exclude lib2to3 because that's Python 2 code which fails
157 # We rebuild three times, once for each optimization level
158 find $out -name "*.py" | $out/bin/python -m compileall -q -f -x "lib2to3" -i -
159 find $out -name "*.py" | $out/bin/python -O -m compileall -q -f -x "lib2to3" -i -
160 find $out -name "*.py" | $out/bin/python -OO -m compileall -q -f -x "lib2to3" -i -
161 '';
162
163 passthru = let
164 pythonPackages = callPackage ../../../../../top-level/python-packages.nix {python=self; overrides=packageOverrides;};
165 in rec {
166 inherit libPrefix sitePackages x11Support;
167 executable = "${libPrefix}m";
168 buildEnv = callPackage ../../wrapper.nix { python = self; inherit (pythonPackages) requiredPythonModules; };
169 withPackages = import ../../with-packages.nix { inherit buildEnv pythonPackages;};
170 pkgs = pythonPackages;
171 isPy3 = true;
172 isPy34 = true;
173 is_py3k = true; # deprecated
174 interpreter = "${self}/bin/${executable}";
175 };
176
177 enableParallelBuilding = true;
178
179 meta = {
180 homepage = http://python.org;
181 description = "A high-level dynamically-typed programming language";
182 longDescription = ''
183 Python is a remarkably powerful dynamic programming language that
184 is used in a wide variety of application domains. Some of its key
185 distinguishing features include: clear, readable syntax; strong
186 introspection capabilities; intuitive object orientation; natural
187 expression of procedural code; full modularity, supporting
188 hierarchical packages; exception-based error handling; and very
189 high level dynamic data types.
190 '';
191 license = licenses.psfl;
192 platforms = with platforms; linux ++ darwin;
193 maintainers = with maintainers; [ fridh ];
194 };
195}