tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 buildPythonPackage,
4 fetchFromGitHub,
5 isPyPy,
6
7 # build-system
8 setuptools,
9
10 # propagates
11 markupsafe,
12
13 # optional-dependencies
14 babel,
15 lingua,
16
17 # tests
18 chameleon,
19 mock,
20 pytestCheckHook,
21}:
22
23buildPythonPackage rec {
24 pname = "mako";
25 version = "1.3.10";
26 pyproject = true;
27
28 src = fetchFromGitHub {
29 owner = "sqlalchemy";
30 repo = "mako";
31 tag = "rel_${lib.replaceStrings [ "." ] [ "_" ] version}";
32 hash = "sha256-lxGlYyKbrDpr2LHcsqTow+s2l8+g+63M5j8xJt++tGo=";
33 };
34
35 build-system = [ setuptools ];
36
37 dependencies = [ markupsafe ];
38
39 optional-dependencies = {
40 babel = [ babel ];
41 lingua = [ lingua ];
42 };
43
44 nativeCheckInputs = [
45 chameleon
46 mock
47 pytestCheckHook
48 ]
49 ++ lib.concatAttrValues optional-dependencies;
50
51 disabledTests = lib.optionals isPyPy [
52 # https://github.com/sqlalchemy/mako/issues/315
53 "test_alternating_file_names"
54 # https://github.com/sqlalchemy/mako/issues/238
55 "test_file_success"
56 "test_stdin_success"
57 # fails on pypy2.7
58 "test_bytestring_passthru"
59 ];
60
61 meta = {
62 description = "Super-fast templating language";
63 mainProgram = "mako-render";
64 homepage = "https://www.makotemplates.org/";
65 changelog = "https://docs.makotemplates.org/en/latest/changelog.html";
66 license = lib.licenses.mit;
67 platforms = lib.platforms.unix;
68 maintainers = [ ];
69 };
70}