tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 fetchurl,
5 pkg-config,
6 libiconv,
7 openssl,
8 pcre,
9 pcre2,
10}:
11
12import ./versions.nix (
13 { version, hash, ... }:
14 stdenv.mkDerivation {
15 pname = "zabbix-agent";
16 inherit version;
17
18 src = fetchurl {
19 url = "https://cdn.zabbix.com/zabbix/sources/stable/${lib.versions.majorMinor version}/zabbix-${version}.tar.gz";
20 inherit hash;
21 };
22
23 enableParallelBuilding = true;
24
25 nativeBuildInputs = [ pkg-config ];
26 buildInputs = [
27 libiconv
28 openssl
29 (if (lib.versions.major version >= "7" && lib.versions.minor version >= "4") then pcre2 else pcre)
30 ];
31
32 configureFlags = [
33 "--enable-agent"
34 "--enable-ipv6"
35 "--with-iconv"
36 "--with-libpcre"
37 "--with-openssl=${openssl.dev}"
38 ];
39 makeFlags = [
40 "AR:=$(AR)"
41 "RANLIB:=$(RANLIB)"
42 ];
43
44 postInstall = ''
45 cp conf/zabbix_agentd/*.conf $out/etc/zabbix_agentd.conf.d/
46 '';
47
48 meta = {
49 description = "Enterprise-class open source distributed monitoring solution (client-side agent)";
50 homepage = "https://www.zabbix.com/";
51 license =
52 if (lib.versions.major version >= "7") then lib.licenses.agpl3Only else lib.licenses.gpl2Plus;
53 maintainers = with lib.maintainers; [
54 bstanderline
55 mmahut
56 psyanticy
57 ];
58 platforms = lib.platforms.unix;
59 };
60 }
61)