tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 buildGoModule,
3 fetchFromGitHub,
4 lib,
5}:
6
7let
8 generic =
9 {
10 subPackages,
11 pname,
12 postInstall ? "",
13 mainProgram,
14 }:
15 buildGoModule rec {
16 inherit pname;
17 version = "6.13.1";
18 shortRev = "591ed6e"; # for internal version info
19
20 src = fetchFromGitHub {
21 owner = "sensu";
22 repo = "sensu-go";
23 rev = "v${version}";
24 sha256 = "sha256-VYdm1aNz1IXvDezrJB5yyViIWPl4zf4/xmkw2pm8gyk=";
25 };
26
27 inherit subPackages postInstall;
28
29 vendorHash = "sha256-32jz5CI94BZxMDo6Crc05DDvlXxMsldJpWvhfHLS37o=";
30
31 doCheck = false;
32
33 ldflags =
34 let
35 versionPkg = "github.com/sensu/sensu-go/version";
36 in
37 [
38 "-X ${versionPkg}.Version=${version}"
39 "-X ${versionPkg}.BuildSHA=${shortRev}"
40 ];
41
42 meta = {
43 inherit mainProgram;
44 homepage = "https://sensu.io";
45 description = "Open source monitoring tool for ephemeral infrastructure & distributed applications";
46 license = lib.licenses.mit;
47 maintainers = with lib.maintainers; [
48 thefloweringash
49 teutat3s
50 ];
51 };
52 };
53in
54{
55 sensu-go-cli = generic {
56 pname = "sensu-go-cli";
57 subPackages = [ "cmd/sensuctl" ];
58 postInstall = ''
59 mkdir -p \
60 "''${!outputBin}/share/bash-completion/completions" \
61 "''${!outputBin}/share/zsh/site-functions"
62
63 ''${!outputBin}/bin/sensuctl completion bash > ''${!outputBin}/share/bash-completion/completions/sensuctl
64
65 # https://github.com/sensu/sensu-go/issues/3132
66 (
67 echo "#compdef sensuctl"
68 ''${!outputBin}/bin/sensuctl completion zsh
69 echo '_complete sensuctl 2>/dev/null'
70 ) > ''${!outputBin}/share/zsh/site-functions/_sensuctl
71
72 '';
73 mainProgram = "sensuctl";
74 };
75
76 sensu-go-backend = generic {
77 pname = "sensu-go-backend";
78 subPackages = [ "cmd/sensu-backend" ];
79 mainProgram = "sensu-backend";
80 };
81
82 sensu-go-agent = generic {
83 pname = "sensu-go-agent";
84 subPackages = [ "cmd/sensu-agent" ];
85 mainProgram = "sensu-agent";
86 };
87}