tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 buildPythonPackage,
5 fetchFromGitHub,
6
7 # build-system
8 cython,
9 setuptools,
10
11 # tests
12 numpy,
13 psutil,
14 pytestCheckHook,
15 pytest-xdist,
16 pythonAtLeast,
17 trio,
18 untangle,
19}:
20
21buildPythonPackage (finalAttrs: {
22 pname = "pydevd";
23 version = "3.4.1";
24 pyproject = true;
25
26 src = fetchFromGitHub {
27 owner = "fabioz";
28 repo = "PyDev.Debugger";
29 tag = "pydev_debugger_${lib.replaceStrings [ "." ] [ "_" ] finalAttrs.version}";
30 hash = "sha256-srcYeN4IsnX/B0AWLynr62UC5o+DcjnUrGjcTpvHTCM=";
31 };
32
33 __darwinAllowLocalNetworking = true;
34
35 build-system = [
36 cython
37 setuptools
38 ];
39
40 nativeCheckInputs = [
41 numpy
42 psutil
43 pytest-xdist
44 pytestCheckHook
45 trio
46 untangle
47 ];
48
49 enabledTestPaths = [
50 "tests/"
51 ];
52
53 disabledTests = [
54 # Require network connection
55 "test_completion_sockets_and_messages"
56 "test_path_translation"
57 "test_attach_to_pid_no_threads"
58 "test_attach_to_pid_halted"
59 "test_remote_debugger_threads"
60 "test_path_translation_and_source_reference"
61 "test_attach_to_pid"
62 "test_terminate"
63 "test_gui_event_loop_custom"
64
65 # AssertionError: assert '/usr/bin/' == '/usr/bin'
66 # https://github.com/fabioz/PyDev.Debugger/issues/227
67 "test_to_server_and_to_client"
68
69 # Times out
70 "test_case_sys_exit_multiple_exception_attach"
71 ]
72 ++ lib.optionals (pythonAtLeast "3.12") [
73 # raise segmentation fault
74 # https://github.com/fabioz/PyDev.Debugger/issues/269
75 "test_evaluate_expression"
76 ]
77 ++ lib.optionals (pythonAtLeast "3.14") [
78 # AssertionError (strings do not match)
79 "test_build_tuple"
80 "test_collect_try_except_info"
81 "test_collect_try_except_info2"
82 "test_collect_try_except_info3"
83 "test_collect_try_except_info4"
84 "test_collect_try_except_info4a"
85 "test_collect_try_except_info_in_single_line_1"
86 "test_collect_try_except_info_in_single_line_2"
87 "test_collect_try_except_info_multiple_except"
88 "test_collect_try_except_info_raise_unhandled10"
89 "test_collect_try_except_info_raise_unhandled7"
90 "test_collect_try_except_info_return_on_except"
91 "test_collect_try_except_info_with"
92 "test_separate_future_import"
93 "test_simple_code_to_bytecode_cls_method"
94 "test_simple_code_to_bytecode_repr_return_tuple"
95 "test_simple_code_to_bytecode_repr_return_tuple_with_call"
96 "test_simple_code_to_bytecode_repr_simple_method_calls"
97 "test_simple_code_to_bytecode_repr_tuple"
98 "test_smart_step_into_bytecode_info_023a"
99
100 # AssertionError: False is not true
101 "test_if_code_obj_equals"
102
103 # AssertionError: TimeoutError (note: error trying to dump threads on timeout: [Errno 9] Bad file descriptor).
104 "test_m_switch"
105 "test_module_entry_point"
106 "test_multiprocessing_simple"
107 "test_stop_on_start_entry_point"
108 "test_stop_on_start_m_switch"
109
110 # Failed: remains unmatched: 'Worked'
111 "test_run"
112 # Failed: remains unmatched: 'WorkedLocalFoo'
113 "test_run_on_local_module_without_adding_to_pythonpath"
114 ]
115 ++ lib.optionals stdenv.hostPlatform.isDarwin [
116 "test_multiprocessing_simple"
117 "test_evaluate_exception_trace"
118 ];
119
120 pythonImportsCheck = [ "pydevd" ];
121
122 meta = {
123 description = "PyDev.Debugger (used in PyDev, PyCharm and VSCode Python)";
124 homepage = "https://github.com/fabioz/PyDev.Debugger";
125 license = lib.licenses.epl10;
126 maintainers = with lib.maintainers; [ onny ];
127 mainProgram = "pydevd";
128 };
129})