tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 autoreconfHook,
3 buildPythonPackage,
4 fetchurl,
5 gnupg,
6 gpgme,
7 lib,
8 libgpg-error,
9 setuptools,
10 swig,
11}:
12
13buildPythonPackage rec {
14 pname = "gpgme";
15 version = "2.0.0";
16 pyproject = true;
17
18 src = fetchurl {
19 url = "mirror://gnupg/gpgmepy/gpgmepy-${version}.tar.bz2";
20 hash = "sha256-B+EmVkj/UdojjJr3oYs/HcewxmtPIacvJ8dLOWzTM20=";
21 };
22
23 postPatch = ''
24 substituteInPlace pyproject.toml \
25 --replace-fail ', "swig"' ""
26
27 # prevent `packaging.version.InvalidVersion: Invalid version: '2.0.0-unknown'`
28 substituteInPlace autogen.sh \
29 --replace-fail 'tmp="-unknown"' 'tmp=""'
30 '';
31
32 build-system = [ setuptools ];
33
34 nativeBuildInputs = [
35 autoreconfHook
36 gpgme # for gpgme-config
37 libgpg-error # for gpg-error-config
38 swig
39 ];
40
41 preBuild = ''
42 # prevent `error: package directory 'gpg' does not exist`
43 mv src gpg
44 '';
45
46 buildInputs = [
47 gpgme
48 libgpg-error
49 ];
50
51 pythonImportsCheck = [ "gpg" ];
52
53 nativeCheckInputs = [
54 gnupg
55 ];
56
57 checkPhase = ''
58 runHook preCheck
59
60 make -C tests
61
62 runHook postCheck
63 '';
64
65 meta = {
66 changelog = "https://dev.gnupg.org/source/gpgmepy/browse/master/NEWS;gpgmepy-${version}?as=remarkup";
67 description = "Python bindings to the GPGME API of the GnuPG cryptography library";
68 homepage = "https://dev.gnupg.org/source/gpgmepy/";
69 license = lib.licenses.lgpl21Plus;
70 maintainers = [ lib.maintainers.dotlambda ];
71 };
72}