tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 lib,
3 stdenv,
4 fetchFromGitHub,
5 inotify-tools,
6 openssh,
7 perl,
8 gnutar,
9 bash,
10 makeWrapper,
11}:
12
13stdenv.mkDerivation (finalAttrs: {
14 pname = "sshlatex";
15 version = "0.8";
16
17 src = fetchFromGitHub {
18 owner = "iblech";
19 repo = "sshlatex";
20 rev = finalAttrs.version;
21 sha256 = "0kaah8is74zba9373xccmsxmnnn6kh0isr4qpg21x3qhdzhlxl7q";
22 };
23
24 nativeBuildInputs = [ makeWrapper ];
25
26 installPhase =
27 let
28 binPath = lib.makeBinPath [
29 openssh
30 perl
31 gnutar
32 bash
33 inotify-tools
34 ];
35 in
36 ''
37 mkdir -p $out/bin
38 cp sshlatex $out/bin
39 wrapProgram $out/bin/sshlatex --prefix PATH : "${binPath}"
40 '';
41
42 meta = {
43 description = "Collection of hacks to efficiently run LaTeX via ssh";
44 longDescription = ''
45 sshlatex is a tool which uploads LaTeX source files to a remote, runs
46 LaTeX there, and streams the resulting PDF file to the local host.
47 Because sshlatex prestarts LaTeX with the previous run's preamble,
48 thereby preloading the required LaTeX packages, it is also useful in a
49 purely local setting.
50 '';
51 homepage = "https://github.com/iblech/sshlatex";
52 license = lib.licenses.gpl3Plus; # actually dual-licensed gpl3Plus | lppl13cplus
53 platforms = lib.platforms.all;
54 maintainers = [ lib.maintainers.iblech ];
55 mainProgram = "sshlatex";
56 };
57})