tjh.dev
nixpkgs mirror (for testing)
github.com/NixOS/nixpkgs
nix
1{
2 boost,
3 cairo,
4 cmake,
5 cups,
6 fetchurl,
7 fontconfig,
8 freetype,
9 graphicsmagick,
10 gsettings-desktop-schemas,
11 gtk3,
12 harfbuzzFull,
13 hunspell,
14 lcms2,
15 lib,
16 libcdr,
17 libfreehand,
18 libjpeg,
19 libjxl,
20 libmspub,
21 libpagemaker,
22 libqxp,
23 librevenge,
24 libsysprof-capture,
25 libtiff,
26 libvisio,
27 libwpg,
28 libxml2,
29 libzmf,
30 pixman,
31 pkg-config,
32 podofo_0_10,
33 poppler,
34 poppler_data,
35 python3,
36 qt6,
37 stdenv,
38}:
39stdenv.mkDerivation (finalAttrs: {
40 pname = "scribus";
41
42 version = "1.7.2";
43
44 src = fetchurl {
45 url = "mirror://sourceforge/scribus/scribus-devel/scribus-${finalAttrs.version}.tar.xz";
46 hash = "sha256-nY4RzGusLNlsVTnvvXGSIv9/cOHBhZcogNn7MFHhONA=";
47 };
48
49 nativeBuildInputs = [
50 cmake
51 pkg-config
52 qt6.wrapQtAppsHook
53 ];
54
55 buildInputs = [
56 boost
57 cairo
58 cups
59 fontconfig
60 freetype
61 graphicsmagick
62 harfbuzzFull
63 hunspell
64 lcms2
65 libcdr
66 libfreehand
67 libjpeg
68 libjxl
69 libpagemaker
70 libqxp
71 librevenge
72 libsysprof-capture
73 libtiff
74 libvisio
75 libwpg
76 libxml2
77 libzmf
78 pixman
79 podofo_0_10
80 poppler
81 poppler_data
82 (python3.withPackages (
83 ps: with ps; [
84 pillow
85 tkinter
86 ]
87 ))
88 qt6.qt5compat
89 qt6.qtbase
90 qt6.qtdeclarative
91 qt6.qtimageformats
92 qt6.qtsvg
93 qt6.qttools
94 ]
95 ++ lib.optionals libmspub.meta.available [ libmspub ];
96
97 cmakeFlags = [ (lib.cmakeBool "WANT_GRAPHICSMAGICK" true) ];
98
99 preFixup = ''
100 qtWrapperArgs+=(
101 --prefix XDG_DATA_DIRS : "${gsettings-desktop-schemas}/share/gsettings-schemas/${gsettings-desktop-schemas.name}"
102 --prefix XDG_DATA_DIRS : "${gtk3}/share/gsettings-schemas/${gtk3.name}"
103 )
104 '';
105
106 meta = {
107 maintainers = with lib.maintainers; [ arthsmn ];
108 description = "Desktop Publishing (DTP) and Layout program";
109 mainProgram = "scribus";
110 homepage = "https://www.scribus.net";
111 # There are a lot of licenses...
112 # https://github.com/scribusproject/scribus/blob/20508d69ca4fc7030477db8dee79fd1e012b52d2/COPYING#L15-L19
113 license = with lib.licenses; [
114 bsd3
115 gpl2Plus
116 mit
117 publicDomain
118 ];
119 platforms = lib.platforms.all;
120 broken = stdenv.hostPlatform.isDarwin;
121 };
122})